Foro - Perl en Español

[situ]

Los molesto porque en este caso tengo un script en bash el cual me da como resultado los usuarios de mi sistema asociados a los grupos creados en el mismo, me gustaría migrarlo a Perl.
¿Alguien me puede ayudar? o tienen alguna web donde pueda leer sobre esto.

Mi script:
http://pastebin.com/m4088c7ff

Saludos

[explorer]

En Perl no te hace falta diseccionar el fichero passwd.

Te vale con usar las funciones get*.

Por ejemplo:

Código: Seleccionar todo

perl -le 'print scalar getgrgid(100);'
users

[situ]

Gracias,
Capaz que suena medio vago de mi parte, pero no tenés algún ejemplo o no sabes dónde puedo conseguir alguno sobre lo que hago buscado.
Saludosl

[explorer]

Aquí tienes uno:

Sintáxis: [ Descargar ] [ Ocultar ]

Sintáxis: [ Descargar ] [ Mostrar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use strict;
use warnings;
use diagnostics;

### Leemos todos los usuarios
my %usuarios;
setpwent();                                                 ## Inicio de acceso al fichero passwd
while ( my($nombre,$passwd,$uid,$gid) = getpwent() ) {      ## Bucle por todos los usuarios
    $usuarios{$uid} = [ $nombre, $passwd, $gid ];
}
endpwent();                                                 ## Fin de acceso al fichero passwd

### Leemos todos los grupos
my %grupos;
setgrent();                                                 ## Inicio de acceso al fichero /etc/group
while ( my($nombre,$passwd,$gid,$miembros) = getgrent() ) { ## Bucle para todos los grupos
    $grupos{$gid} = [ $nombre, $passwd, $miembros ];
}
endgrent();                                                 ## Fin de acceso al fichero /etc/group

## Los usuarios pertenecen a un grupo (el grupo por defecto). La relación con ese grupo no
## suele estar reflejada en el fichero /etc/group.
## Aquí añadimos el usuario al conjunto de usuarios de su grupo por defecto.
## El efecto es igual que llamar al programa 'groups', que devuelve todos los grupos a los que
## pertenece el usuario
for my $uid ( keys %usuarios ) {
    my $gid = $usuarios{$uid}->[2];
    my $miembros_del_grupo = $grupos{$gid}->[2];
    if (!$miembros_del_grupo) {
        $grupos{$gid}->[2] = $usuarios{$uid}->[0];
    }
    elsif ($gid !~ /\b$miembros_del_grupo\b/) {
        $grupos{$gid}->[2] = join " ", $miembros_del_grupo, $usuarios{$uid}->[0];
    }
}

#use Data::Dumper;
#print Dumper \%usuarios;
#print Dumper \%grupos;

## Para cada usuario
for my $uid ( keys %usuarios ) {
    my $nombre = $usuarios{$uid}->[0];
    #print "Usuario: $nombre\n";

    ## Para todos los grupos de ese usuario
    for my $gid ( keys %grupos ) {
        next if $grupos{$gid}->[2] !~ /\b$nombre\b/;
        #print "\tGrupo: $gid, $grupos{$gid}->[0]\n";

        if ($gid < 500) {
            print "$nombre pertenece al grupo $grupos{$gid}->[0] ($gid)\n";
        }
    }
}

__END__

Coloreado en 0.004 segundos, usando GeSHi 1.0.8.4

[situ]

Como siempre un lujo pertenecer al foro y que halla gente como explorer.
Gracias.