Foro - Perl en Español

por **pablgonz** » 2013-11-15 23:22 @015

Hola, amigos del foro, estoy trabajando en un pequeño script... y tengo algunas dudas con las expresiones regulares que estoy usando. Va así:

Tengo ficheros de entrada de las siguiente formas (LaTeX)

Sintáxis: [ Descargar ] [ Ocultar ]

Using latex Syntax Highlighting

\documentclass{article}
\usepackage{pstricks-add}
\newenvironment{postscript}{}{}
\begin{document}
Los entornos pstricks se inician \verb|\pspicture(argumento) o \pspicture*(argumento)| para plain TeX
y \verb+\begin{pspicture} o \begin{pspicture*}+ para LaTeX, antes o después de cada entorno, es necesario
definir \verb'\psset{opciones}' por ejemplo:
\verb+\psset{opciones}\begin{pspicture}+ o \verb-\begin{pspicture}\psset{opciones}- y para cerrar los entornos usamos
(dependiendo) \verb*'\endpspicture' para plain TeX y \verb*#\end{pspicture} o \end{pspicture*}# para LaTeX.
Algunas ocasiones es necesario definir un nuevo entorno para incluir nuestras definiciones dentro de el, por
ejemplo \verb<\newenvironment{postscript}{}{}< e incluir nuestros entornos dentro de el, es decir, las lineas deben ser
\verb|\begin{postscript} \psset{opciones} \begin{pspicture}| o \verb|\begin{postscript} \begin{pspicture} \psset{opciones}|
pero no \verb|\psset{opciones}\begin{postscript}\begin{pspicture}| o \verb|\psset{opciones}\begin{pspicture}\begin{postscript}|
y para cerrar el entorno usamos \verb&\end{postscript}&. Para comentar una linea puedes usar \verb|%| antes de cada linea
por ejemplo \verb|% \pspicture*(argumento) o %\pspicture*(argumento) o %%%%\pspicture*(argumento)|. Veamos algunos ejemplos:
 
%\begin{postscript}
\begin{postscript}
\psset{unit=1.0cm}
\begin{pspicture}[showgrid=true](4,2)
  \psscaleboxto(8,2){foo bar baz}
\end{pspicture}
\end{postscript}
 
\begin{pspicture*}(4,2)(8,1)
\psset{unit=1.0cm}
\psscaleboxto(8,2){foo bar baz}
\end{pspicture*}
 
%%% \pspicture*(4,2)(8,1) o \begin{pspicture*}(4,2)(8,1)
\pspicture*(4,2)(8,1)
\psset{unit=1.0cm}
\psscaleboxto(8,2){foo bar baz}
\endpspicture
% se puede \endpspicture o \end{pspicture*}
% \pspicture(4,2)(8,1) o \begin{pspicture}(4,2)(8,1)
\pspicture(4,2)(8,1)
\psset{unit=1.0cm}
\psscaleboxto(8,2){foo bar baz}
\endpspicture
%\endpspicture o \end{pspicture}
\end{document}
 
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

Quiero los siguientes cambios, cuando este dentro de \verb, verb* o despues de %

Sintáxis: [ Descargar ] [ Ocultar ]

pspicture por TRICKS
pspicture* por TRICKS*
postscript por POSTRICKS
endpspicture por ENDTRICKS

Pero, que no modifique, las lineas que están fuera de \verb,verb* o % en el documento, específicamente, que no cambie:

Sintáxis: [ Descargar ] [ Ocultar ]

\pspicture(algo) o \endpspicture
\pspicture*(algo) o \endpspicture
\begin{pspicture} o \end{pspicture}
\begin{pspicture*} o \end{pspicture*}
\begin{postscript} o \end{postscript}

El script que utilizo es el siguiente:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl -w
use v5.16;
use autodie;
use strict;
 
my $entrada = $ARGV[0];                # el fichero como primer argumento
my $salida  = 'salida.tex';            # fichero de salida
 
open( AE, '<', $entrada );             # leemos el archivo Entrada
undef $/;                              # modo 'slurp'
my ( $uno, $dos ) = split( /\\begin\{document\}/, <AE>, 2 );
close AE;
 
my @coment = split /\n/, $dos;
my @preamb;
 
foreach my $line (@coment) {           # modificamos las líneas
    chomp($line);
 
    # Apertura de entornos ps
    # Cambiamos \pspicture,\pspicture*,\begin{pspicture},\begin{postscript} por TRICKS y POSTRICKS
    $line =~ s/(\\[V|v]erb[\*]?[[:punct:]]{1}.+?)\\pspicture/$1\\TRICKS/g;                          # cambiamos \pstricks[*] por \TRICKS[*]
    $line =~ s/(\\[V|v]erb[\*]?[[:punct:]]{1}.+?)\\begin\{pspicture/$1\\begin\{TRICKS/g;            # cambiamos
    $line =~ s/(\\[V|v]erb[\*]?[[:punct:]]{1}.+?)\\begin\{postscript\}/$1\\begin\{POSTRICKS\}/g;    # cambiamos
 
    # Cambiamos los comentarios en TeX cuando comienzen con %
    $line =~ s/(\%.+?)\\pspicture/$1\\TRICKS/g;                        # cambiamos
    $line =~ s/(\%.+?)\\begin\{pspicture/$1\\begin\{TRICKS/g;          # cambiamos
    $line =~ s/(\%.+?)\\begin\{postscript\}/$1\\begin\{POSTRICKS\}/g;  # cambiamos
 
    # Cierre entornos pspicture
    $line =~ s/(\\[V|v]erb[\*]?[[:punct:]]{1}.+?)\\endpspicture/$1\\ENDTRICKS/g;               # cambiamos \pstricks[*] por \TRICKS[*]
    $line =~ s/(\\[V|v]erb[\*]?[[:punct:]]{1}.+?)\\end\{pspicture/$1\\end\{TRICKS/g;           # cambiamos
    $line =~ s/(\\[V|v]erb[\*]?[[:punct:]]{1}.+?)\\end\{postscript\}/$1\\end\{POSTRICKS\}/g;   # cambiamos
 
    # Cambiamos los comentarios en TeX cuando comienzen con %
    $line =~ s/(\%.+?)\\endpspicture/$1\\ENDTRICKS/g;                    # cambiamos
    $line =~ s/(\%.+?)\\begin\{pspicture/$1\\begin\{TRICKS/g;            # cambiamos
    $line =~ s/(\%.+?)\\begin\{postscript\}/$1\\begin\{POSTRICKS\}/g;    # cambiamos
 
    push( @preamb, $line );            # las unimos
}
 
# Aquí tengo un problema, agrega una línea en blanco extra luego de unir los ficheros
 
my $modificado = join( "\n", $uno . '\begin{document}', @preamb );       #pegamos
 
open( AS, ">", $salida );              # creo el Archivo Salida
print AS $modificado;                  # imprimo uno modificado
close AS;                              # cierro
exit;                                  # terminamos
 
 
Coloreado en 0.003 segundos,  usando GeSHi 1.0.8.4

Y Ahora viene mis consultas:

La expresión regular $line =~ s/(\\[V|v]erb[\*]?[[:punct:]]{1}.+?)\\pspicture/$1\\TRICKS/g; no funciona bien, no es del todo correcta: si encuentra la expresión más de una vez solo cambia la primera (a veces), por ejemplo, con esta línea falla:
Sintáxis: [ Descargar ] [ Ocultar ]
Sintáxis: [ Descargar ] [ Mostrar ]
Using latex Syntax Highlighting
1. texto \verb*|\pspicture(algo)| \verb*|\pspicture*(algo)|resto linea
Coloreado en 0.000 segundos, usando GeSHi 1.0.8.4
Hice algunos intentos pero fallaba si se presentaba este caso:
Sintáxis: [ Descargar ] [ Ocultar ]
Sintáxis: [ Descargar ] [ Mostrar ]
Using latex Syntax Highlighting
1. texto \verb*|algo ...\pspicture(algo)...\pspicture(algo)...algo| texto \pstricks(algo)
Coloreado en 0.000 segundos, usando GeSHi 1.0.8.4
puesto que cambiaba todo lo que estuviera en esa línea. Sé que las expresiones que busco tienen siempre la forma:
Sintáxis: [ Descargar ] [ Ocultar ]
Sintáxis: [ Descargar ] [ Mostrar ]
1. \verb*(carácter)...código...\pstricks(algo) (una más veces) ...código(carácter)
2. o
3. \verb(carácter)...código...\pspicture(algo) (una más veces) ...código(carácter)
donde (carácter) es un único (|,+,!,",',etc) y aparece al principio, inmediatamente después de \verb o \verb* y al final de la cadena, sin repetirce dentro de ésta. Y aquí va mi primera pregunta:
¿Cómo modifico la expresión para que cambie lo que quiero (las veces que aparezca) pero sólo dentro de éstos caracteres únicos?
(aclaro que el que se dé este caso es muy extraño, pero posible).
La expresión regular $line =~ s/(\%.+?)\\pspicture/$1\\TRICKS/g; falla si no va un espacio después de "%" y aparece más de una vez en la misma línea. En este caso "SÍ" deseo que cambie todas las ocurrencias en la línea que encuentre la expresión (de principio a fin) y la pregunta de rigor: ¿Cómo modifico la expresión para que cambie lo que quiero con o sin espacios de principio a fin de línea? o mejor dicho ¿están correctas esas expresiones? es decir, ¿capturan lo que yo creo... o solo es mi imaginación?

Agradecido de antemano:

Pablo

En ese caso, tu programa fallará.

No me queda claro el tratamiento a dar a los comentarios. Supongo que se refiere a las partes que comienzan por '%' pero que siguen estando dentro de un '\verb ...'. O sea: no hay que modificar los comentarios de ninguna manera (las líneas que comienzan por '%').

por **pablgonz** » 2013-11-17 12:54 @579

explorer escribiste:¿podría darse el caso de que una parte '\verb ....' abarcara más de una línea?

La verdad no... el archivo es (La)TeX y eso no está permitido, \verb es solo para códigos en una misma línea.

explorer escribiste:No me queda claro el tratamiento a dar a los comentarios. Supongo que se refiere a las partes que comienzan por '%' pero que siguen estando dentro de un '\verb ...'. O sea: no hay que modificar los comentarios de ninguna manera (las líneas que comienzan por '%').

El signo % se comporta en (La)TeX de la misma forma que # en Perl.

Por ejemplo:

Sintáxis: [ Descargar ] [ Ocultar ]

Using latex Syntax Highlighting

%\pspicture o \begin{pspicture}Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

deseo que lo convierta a:

Sintáxis: [ Descargar ] [ Ocultar ]

Using latex Syntax Highlighting

%\TRICKS o \begin{TRICKS}Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

no importando los caracteres o espacios que van después de %.

Ahora, si se diera este caso:

Sintáxis: [ Descargar ] [ Ocultar ]

Using latex Syntax Highlighting

\verb+%\pspicture o \begin{pspicture}+Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

solo debería cambiar:

Sintáxis: [ Descargar ] [ Ocultar ]

Using latex Syntax Highlighting

\verb+%\TRICKS o \begin{TRICKS}+Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

Espero que esta aclaración sea útil.
Agradecido,
Pablo

por **explorer** » 2013-11-17 13:18 @595

Disculpa. Dices que no quieres que haya modificación cuando se está dentro de \verb, pero el caso es que sí lo has hecho en el último ejemplo... ¿O acaso te refieres a un caso muy específico? Entonces, ¿qué distingue a ese caso específico de la regla general de no hacer modificaciones con % dentro de \verb?

por **pablgonz** » 2013-11-17 13:29 @603

Tienes razón, borré el error de redacción que tenía más arriba. Con el ejemplo espero que se entienda la idea... en mi mente va así:

Primero:
1. Busco \verb (o verb*) seguido de un solo carácter (+, /, !, etc.)
2. Seguido de (+, /, !, etc.) busco todas las apariciones y las cambio hasta llegar a (+, /, !, etc.)
3. Repito esto dentro de la misma línea por si existe más de un \verb

Segundo:
1. Busco todas la líneas que comienzan por % y veo si contienen lo que deseo y lo cambio

Acorde a mi lógica, si se ejecuta "Primero" y luego "Segundo" no tendría problemas dentro de \verb, ya estaría cambiado por "Primero".

Espero y sea de ayuda.
Pablo

por **explorer** » 2013-11-17 13:51 @619

Creo que he encontrado una solución:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use v5.16;
use autodie;
 
@ARGV == 1 or die "Uso: $0 <archivo LaTeX a procesar\n";
 
my $nombre_archivo_entrada = shift;
my $nombre_archivo_salida  = $nombre_archivo_entrada . '.tex';
 
-f $nombre_archivo_entrada or die "ERROR: No encuentro $nombre_archivo_entrada\n";
 
 
## Lectura del archivo
open my $ENTRADA, '<', $nombre_archivo_entrada;
undef $/;                                                       # modo 'slurp'
my $archivo_entrada = <$ENTRADA>;
close   $ENTRADA;
 
 
## Partición del documento
my($cabeza,$cuerpo,$final) = $archivo_entrada =~ m/\A (.+? ^\\begin{document}) \s* (.+?) \s* (^ \\end{document}) \s* \z/msx;
 
 
## Cambios a realizar
my %cambios = (
    '\pspicture'                => '\TRICKS',
    '\endpspicture'             => '\ENDTRICKS',
 
    '\begin{pspicture'          => '\begin{TRICKS',
    '\end{pspicture'            => '\end{TRICKS',
 
    '\postscript'               => '\POSTRICKS',
 
    '\begin{postscript}'        => '\begin{POSTRICKS}',
    '\end{postscript}'          => '\end{POSTRICKS}',
);
 
 
## Cambiar
while ($cuerpo =~ m/\\verb \*? ([[:punct:]]) (.+?) \1 | ^ \s* (\%) (.+?) $/gimsx) {     # buscamos un verbo o un comentario
 
    my($pos_inicial, $pos_final) = ($-[0], $+[0]);                      # posiciones
    my $verbo = ${^MATCH};                                              # el verbo encontrado
 
#    my $interior = $2;
#    next if $interior =~ m/^ \s* \%/x;                                 # no hacemos modificaciones si es un comentario dentro de \verb
 
    while (my($busco, $cambio) = each %cambios) {                       # buscar y cambiar
    
        $verbo =~ s/\Q$busco\E/$cambio/g;                               # es necesario escapar $busco, ya que contiene
                                                                        # caracteres extraños
    }
 
    substr $cuerpo, $pos_inicial, $pos_final-$pos_inicial, $verbo;      # insertamos los nuevos cambios
    
    pos($cuerpo)= $pos_inicial + 4;                                     # reposicionamos la búsqueda del siguiente verbo
                                                                        # empezando en donde lo encontramos, pero un poco más allá
}
 
 
## Escritura del resultado
open my $SALIDA, '>', $nombre_archivo_salida;
print   $SALIDA "$cabeza\n$cuerpo\n$final\n";
close   $SALIDA;
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

El resultado es:

Sintáxis: [ Descargar ] [ Ocultar ]

Using latex Syntax Highlighting

\documentclass{article}
\usepackage{pstricks-add}
\newenvironment{postscript}{}{}
\begin{document}
Los entornos pstricks se inician \verb|\TRICKS(argumento) o \TRICKS*(argumento)| para plain TeX
y \verb+\begin{TRICKS} o \begin{TRICKS*}+ para LaTeX, antes o después de cada entorno, es necesario
definir \verb'\psset{opciones}' por ejemplo:
\verb+\psset{opciones}\begin{TRICKS}+ o \verb-\begin{TRICKS}\psset{opciones}- y para cerrar los entornos usamos
(dependiendo) \verb*'\ENDTRICKS' para plain TeX y \verb*#\end{TRICKS} o \end{TRICKS*}# para LaTeX.
Algunas ocasiones es necesario definir un nuevo entorno para incluir nuestras definiciones dentro de el, por
ejemplo \verb<\newenvironment{postscript}{}{}< e incluir nuestros entornos dentro de el, es decir, las lineas deben ser
\verb|\begin{POSTRICKS} \psset{opciones} \begin{TRICKS}| o \verb|\begin{POSTRICKS} \begin{TRICKS} \psset{opciones}|
pero no \verb|\psset{opciones}\begin{POSTRICKS}\begin{TRICKS}| o \verb|\psset{opciones}\begin{TRICKS}\begin{POSTRICKS}|
y para cerrar el entorno usamos \verb&\end{POSTRICKS}&. Para comentar una linea puedes usar \verb|%| antes de cada linea
por ejemplo \verb|% \TRICKS*(argumento) o %\TRICKS*(argumento) o %%%%\TRICKS*(argumento)|. Veamos algunos ejemplos:
 
%\begin{POSTRICKS}
\begin{postscript}
\psset{unit=1.0cm}
\begin{pspicture}[showgrid=true](4,2)
  \psscaleboxto(8,2){foo bar baz}
\end{pspicture}
\end{postscript}
 
\begin{pspicture*}(4,2)(8,1)
\psset{unit=1.0cm}
\psscaleboxto(8,2){foo bar baz}
\end{pspicture*}
 
%%% \TRICKS*(4,2)(8,1) o \begin{TRICKS*}(4,2)(8,1)
\pspicture*(4,2)(8,1)
\psset{unit=1.0cm}
\psscaleboxto(8,2){foo bar baz}
\endpspicture
% se puede \ENDTRICKS o \end{TRICKS*}
% \TRICKS(4,2)(8,1) o \begin{TRICKS}(4,2)(8,1)
\pspicture(4,2)(8,1)
\psset{unit=1.0cm}
\psscaleboxto(8,2){foo bar baz}
\endpspicture
%\ENDTRICKS o \end{TRICKS}
\end{document}
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

La idea es localizar las partes del documento con un '\verb ...', extraerlas, modificarlas con los cambios que queremos, y finalmente, colocar los nuevos cambios en el documento.

Con más detalle...

[2] gracias a que estamos en un Perl v5.16, no necesitamos activar los warnings y el modo estricto, porque quedan activado por defecto
[14-17] leemos todo el archivo a memoria
[21] partimos el documento en las tres partes principales, usando una expresión regular
[25-36] definimos lo que queremos cambiar. En este caso son literales por literales
[40-58] bucle que realiza los cambios mientras encontremos '\verb ...'
[42-43] extraemos los datos de posición y la propia cadena del '\verb ...' encontrado
[48-52] aplicamos todos los cambios definidos antes
[50] con un operador de sustitución. Aquí ponemos '\Q...\E' para pedirle a Perl que "escape" los caracteres peligrosos que pudieran existir en lo que $busco. Y esa sustitución se hace a lo largo de todo el $verbo
[54] insertamos en $cuerpo, en la $pos_inicial, el nuevo $verbo cambiado, sustituyendo a lo que había antes
[56] reanudamos la búsqueda, en la misma posición donde encontramos '\verb ...', pero un poco más allá (a continuación de '\verb')
[62-64] grabamos el resultado

La clave está, primero, en hacer una operación de sustitución sólo en la cadena que nos interesa, y segundo, usar la facultad de substr() de cambiar un conjunto de caracteres por otro. En la línea 51 indicamos la posición inicial y el largo de la cadena a sustituir (el $verbo encontrado antes), y le pasamos un cuarto argumento más, que es la nueva cadena de caracteres. substr() se encargará de recortar o hacer el sitio suficiente para acomodar los cambios.

por **pablgonz** » 2013-11-17 14:52 @661

Como dicen en argentina... SOS UN MONSTRUO. Esta solución está más allá de mis capacidades actuales. Pensé que podría lograrlo yo mismo usando solo expresiones regulares (y extendidas) pero, claramente no pude.

Y como de costumbre, un par de interrogantes:
1. Si deseo que busque en otras expresión, distinta de \verb, por ejemplo \lst, pero, que cumple con las mismas condiciones, ¿debo definir un nuevo bucle? ¿O solo copio la línea cambiando \verb por \lst?

2. (Creo que esto no es posible) Supongamos que el archivo de entrada cumple con las condiciones anteriores y se agrega esto:

Sintáxis: [ Descargar ] [ Ocultar ]

Using latex Syntax Highlighting

\documentclass{article}
\usepackage{pstricks-add}
\usepackage{fancyvrb}
\newenvironment{postscript}{}{}
\begin{document}
Los entornos pstricks se inician \verb|\pspicture(argumento) o \pspicture*(argumento)| para plain TeX
y \verb+\begin{pspicture} o \begin{pspicture*}+ para LaTeX, antes o después de cada entorno, es necesario
definir \verb'\psset{opciones}' por ejemplo:
\DefineShortVerb[]{\|}
Usamos el delimitador barra |\begin{pspicture} o \begin{pspicture*}| ...
ahora lo cambiamos indefinimos 
\UndefineShortVerb{\|}
y ahora definimos el (mas)+
\DefineShortVerb[]{\+}
Usamos el delimitador mas +\begin{pspicture} o \begin{pspicture*}+ ...
\UndefineShortVerb{\+}
y ahora definimos el (almoadilla) 
\DefineShortVerb[]{\#}
Usamos el delimitador almoadilla #\begin{pspicture} o \begin{pspicture*}# ...
%%% \pspicture*(4,2)(8,1) o \begin{pspicture*}(4,2)(8,1)
\pspicture*(4,2)(8,1)
\psset{unit=1.0cm}
\psscaleboxto(8,2){foo bar baz}
\endpspicture
% se puede \endpspicture o \end{pspicture*}
% \pspicture(4,2)(8,1) o \begin{pspicture}(4,2)(8,1)
\pspicture(4,2)(8,1)
\psset{unit=1.0cm}
\psscaleboxto(8,2){foo bar baz}
\endpspicture
%\endpspicture o \end{pspicture}
\end{document}
 
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Es decir, al final de la línea \DefineShortVerb[]{\|} (justo antes de }) define el carácter de inicio y fin de donde debo buscar para cambiar, donde los corchetes [] son opcionales, pero, ahora sin \verb y la línea \UndefineShortVerb{\|} si es que está presente me permite cambiar el delimitador a uno nuevo. Las expresiones dentro de los delimitadores se comportan de igual manera que en \verb, pero, el delimitador puede ir cambiando dentro del archivo.

En mi mente sería algo así:

1. Primero recorro todas las líneas con el script que me dejaste arriba.
2. Recorro nuevamente el archivo de la siguiente manera
2.a. Busco \DefineShortVerb[]{\|} y me quedo con lo que esté justo atrás de la llave de cierre, en este caso "|"
2.b. Efectuó un reemplazo idéntico a lo que hacía en \verb, como verb|...| ya está cambiado no le pasara nada, hasta que encuentre la línea \UndefineShortVerb{\|}. Si es que está presente sigo en 3, si no, termino
3. Vuelvo a iniciar el proceso desde la línea en que se encontraba \UndefineShortVerb{\|} (si es que estaba) busco la siguiente aparición de \DefineShortVerb[]{\+} y repito esto hasta el final del documento

¿Es esto posible? Sería el ideal... para lo que busco.

Agradecido por la solución y la explicación (ese es el plus de tus respuestas).

Pablo

por **explorer** » 2013-11-17 19:10 @840

Debido a que estamos usando una expresión regular para ir analizando el $cuerpo, si podemos ampliarla, podemos seguir usándola para analizar el texto poco a poco.

Con la siguiente solución se contempla el caso de definir delimitadores en donde miraremos para hacer los cambios:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use v5.16;
use autodie;
 
@ARGV == 1 or die "Uso: $0 <archivo LaTeX a procesar\n";
 
my $nombre_archivo_entrada = shift;
my $nombre_archivo_salida  = $nombre_archivo_entrada . '.tex';
 
-f $nombre_archivo_entrada or die "ERROR: No encuentro $nombre_archivo_entrada\n";
 
 
## Lectura del archivo
open my $ENTRADA, '<', $nombre_archivo_entrada;
undef $/;                                                       # modo 'slurp'
my $archivo_entrada = <$ENTRADA>;
close   $ENTRADA;
 
 
## Partición del documento
my($cabeza,$cuerpo,$final) = $archivo_entrada =~ m/\A (.+? ^\\begin{document}) \s* (.+?) \s* (^ \\end{document}) \s* \z/msx;
 
 
## Cambios a realizar
my %cambios = (
    '\pspicture'                => '\TRICKS',
    '\endpspicture'             => '\ENDTRICKS',
 
    '\begin{pspicture'          => '\begin{TRICKS',
    '\end{pspicture'            => '\end{TRICKS',
 
    '\postscript'               => '\POSTRICKS',
 
    '\begin{postscript}'        => '\begin{POSTRICKS}',
    '\end{postscript}'          => '\end{POSTRICKS}',
);
 
## Cambiar
my $nodel = "\0";
my $del = $nodel;
 
while ($cuerpo =~
    /   (?<pre>\\verb \*? (?<del>[[:punct:]])) .+? \g{del}              # busca \verb con delimitador
    | ^ (?<pre>\s* \%+) .+? $                                           # busca en comentarios
    |   (?<pre>$del) .+? $del                                           # busca texto delimitado
    |   (?<pre>\\(?:Un)?DefineShortVerb)(?:\[\])?{(?<del>.+?)}          # (in)define delimitadores
    /gimsx) {
 
    my($pos_inicial, $pos_final) = ($-[0], $+[0]);                      # posiciones
    my $verbo = ${^MATCH};                                              # el verbo encontrado
    my $pre   = $+{pre};                                                # partícula inicial
 
    if (lc($pre) eq '\defineshortverb') {                               # definimos delimitador
        $del = $+{del};
        next;
    }
    elsif (lc($pre) eq '\undefineshortverb') {                          # indefinimos delimitador
        $del = $nodel;
        next;
    }
 
    while (my($busco, $cambio) = each %cambios) {                       # buscar y cambiar
    
        $verbo =~ s/\Q$busco\E/$cambio/g;                               # es necesario escapar $busco, ya que contiene
                                                                        # caracteres extraños
    }
 
    substr $cuerpo, $pos_inicial, $pos_final-$pos_inicial, $verbo;      # insertamos los nuevos cambios
    
    pos($cuerpo)= $pos_inicial + length $pre;                           # reposicionamos la búsqueda del siguiente verbo
                                                                        # empezando en donde lo encontramos, pero un poco más allá
}
 
 
## Escritura del resultado
open my $SALIDA, '>', $nombre_archivo_salida;
print   $SALIDA "$cabeza\n$cuerpo\n$final\n";
close   $SALIDA;
Coloreado en 0.003 segundos,  usando GeSHi 1.0.8.4

En cuanto a las preguntas que haces,
1. cambia 'verb' por '(?:verb|lst)' en la primera expresión regular
2. sí es posible hacerlo, siempre y cuando lo que queramos hacer se pueda expresar en forma de reglas; y sepamos traducir esas reglas a expresiones regulares

Foro - Perl en Español

Acotar expresión regular

Acotar expresión regular

Publicidad

Re: Acotar expresión regular

Re: Acotar expresión regular

Re: Acotar expresión regular

Re: Acotar expresión regular

Re: Acotar expresión regular

Re: Acotar expresión regular

Re: Acotar expresión regular

Re: Acotar expresión regular

Re: Acotar expresión regular

¿Quién está conectado?