Foro - Perl en Español

por **explorer** » 2011-02-14 12:07 @546

Mi fichero /etc/sysctl.conf no sigue tu patrón, así que esa puede ser una explicación. Y el fichero sshd_config no puedo leerlo como usuario.

Por otra parte, las tres funciones son casi iguales... podrías reducir las tres funciones (y las futuras) a una sola. Solo tendrías que pasar, como argumentos,

* el nombre del fichero a analizar
* la expresión regular a aplicar
* la referencia al hash que almacena los valores correctos.

El resto de la función se deja tal cual.

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use strict;
use warnings;
use diagnostics;
use autodie;
 
use Term::ANSIColor qw(:constants);
 
# Valores correctos esperados
my %valores_correctos_de = (
 
    login_defs  => {
                    fichero    => '/etc/login.defs',
                    patron     => qr/^ (\S+) \s+ (\S+) $/xi,
                    parametros => {
                                    PASS_MAX_DAYS => 99999,
                                    PASS_MIN_DAYS =>     0,
                                    PASS_WARN_AGE =>     7,
                                  },
                   },
 
    sysctl_conf => {
                    fichero    => '/etc/sysctl.conf',
                    patron     => qr/^ (\S+) \s* = \s* (\S+) $/xi,
                    parametros => {
                                    'net.ipv4.conf.all.rp_filter'               => 1,
                                    'net.ipv4.conf.default.promote_secondaries' => 0,
                                    'net.ipv4.conf.all.promote_secondaries'     => 1,
                                  },
                   },
    sshd_config => {
                    fichero    => '/etc/ssh/sshd_config',
                    patron     => qr/^ (\S+) \s* (\S+) $/xi,
                    parametros => {
                                    X11Forwarding               => 'yes',
                                    Port                        =>  2222,
                                    PasswordAuthentication      =>  'no',
                                  },
                   },
);
 
# Arrancamos los análisis
analiza($valores_correctos_de{login_defs});
analiza($valores_correctos_de{sysctl_conf});
analiza($valores_correctos_de{sshd_config});
 
# Subrutina que analiza
sub analiza {
    my $hash_ref = shift;
    my($fichero, $regex, $valores_correctos_ref) = @{$hash_ref}{'fichero','patron','parametros'};
 
    # Leemos el fichero a un hash según cómo lo indique la expresión regular
    my %valor_actual_de;
    open my $fh, q[<], $fichero;
    while (<$fh>) {
        if (/$regex/) {
            $valor_actual_de{ $1 } = $2;
        }
    }
 
    close $fh;
 
    # Comprobamos los valores correctos
    for my $parametro (sort keys %$valores_correctos_ref) {
        if (exists $valor_actual_de{$parametro}) {
            if ($valor_actual_de{$parametro} eq $valores_correctos_ref->{$parametro}) {
                print BOLD, GREEN, 'Positivo: ', RESET, "El valor del parametro $parametro es correcto\n";
            }
            else {
                print
                    BOLD, RED  , 'Negativo: ', RESET,
                    "El valor del parametro $parametro es incorrecto: ",
                    "[$valor_actual_de{$parametro}] != [$valores_correctos_ref->{$parametro}]\n",
                    ;
            }
        }
        else {
            print BOLD . 'No existe ' . RESET, "el parametro $parametro en $fichero\n";
        }
    }
}
 
__END__
Coloreado en 0.003 segundos,  usando GeSHi 1.0.8.4

He probado la versión 2.5 y me funciona, salvo que falta cerrar el final del fichero recomendación (el R).

Otro problema es que si se vuelve a ejecutar el programa, no sobreescribe los ficheros html, sino que añade nuevo contenido, lo cual no es coherente con el hecho de que siempre genera una cabecera HTML. Deberían ser abiertos en modo escritura, no en modo añadir. Y agregar la hora de la ejecución en el nombre del fichero.

Y el código HTML tiene cantidad de errores... los atributos no están entrecomillados, hay caracteres ';' que sobran... el DTD no corresponde con la forma de escritura de las marcas HTML... casi mejor, quitarlo...

Por otra parte, sabiendo que en las distribuciones Perl viene incluido de base el módulo CGI, podrías aprovecharlo para generar el código HTML, y reducir tu programa a la mitad.

Y si ejecutamos el programa con los avisos activados (no desactivados, como lo tienes puesto), Perl te da más pistas:

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

explorer@aprosi21:~/Documents/tmp> perl -c checklist-2.0.4.pl 

Switch will be removed from the Perl core distribution in the next major release. Please install it from CPAN. It is being used at checklist-2.0.4.pl, line 29.

Variable "%uid" will not stay shared at checklist-2.0.4.pl line 273.

Variable "%gid" will not stay shared at checklist-2.0.4.pl line 275.

Name "main::defaultuser" used only once: possible typo at checklist-2.0.4.pl line 151.

Name "main::archivos" used only once: possible typo at checklist-2.0.4.pl line 177.

checklist-2.0.4.pl syntax OKColoreado en 0.000 segundos,  usando GeSHi 1.0.8.4

O sea:
* Switch es un módulo maldito, así que no hay que usarlo. Hay que usar given/when
* Las variables defaultuser y archivos no se usan nunca
* Las variables %uid y %gid están en contextos diferentes, por lo que los cambios externos en ellas no se verán en sucesivas llamadas en la función que luego las usa. En tu caso, te avisa que la función wanted3() está definida dentro de la función sinownergroup(), por lo que, de las variables %uid y %gui que referencia, y que están declaradas y definidas fuera de ella, solo usará el primer valor que tuvieran, y no los posteriores. En tu caso, no te afecta, porque la función sinownergroup() solo se llama una vez.

por **situ** » 2011-02-15 12:29 @562

Yo tengo la:

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

This is perl, v5.10.1 (*) built for i686-linux-gnu-thread-multiColoreado en 0.000 segundos,  usando GeSHi 1.0.8.4

¡Qué raro! Por el output por terminal me lo da. El tema es el archivo =(.

Seguiré probando.

por **situ** » 2011-03-19 00:34 @065

Consulta: ¿cómo puedo adaptarle File::stat; para comprobar si existe el archivo, si puedo leerlo antes de parsearlo?

Saludos.

por **explorer** » 2011-03-19 07:14 @343

Para eso no es necesario usar ningún módulo.

Perl tiene una serie de operadores, los -X, que te permitan recibir información básica de ficheros y directorios. Por ejemplo:

say 'Es legible' if -r $fichero;

por **situ** » 2011-03-19 10:48 @491

Muchas Gracias.

por **situ** » 2014-07-11 08:54 @413

¿Existe la posibilidad de poder listar el contenido de una variable pero que no sea analizada? Solamente quiero ver su valor o en el caso que no esté que me lo informe.

Foro - Perl en Español

Análisis del archivo /etc/login.defs

Re: Análisis del archivo /etc/login.defs

Publicidad

Re: Análisis del archivo /etc/login.defs

Re: Análisis del archivo /etc/login.defs

Re: Análisis del archivo /etc/login.defs

Re: Análisis del archivo /etc/login.defs

Re: Análisis del archivo /etc/login.defs

Re: Análisis del archivo /etc/login.defs

Re: Análisis del archivo /etc/login.defs

Re: Análisis del archivo /etc/login.defs

Re: Análisis del archivo /etc/login.defs

¿Quién está conectado?