Foro - Perl en Español

por **situ** » 2014-08-04 12:52 @578

¿Cómo están?

Luego de un tiempo y con ayuda del foro pude concluir en forma parcial "https://github.com/marcositu/redhatchecklist", la cual es una aplicación para analizar la configuración de servidores RedHat o sus derivados.

Ahora estoy teniendo un problema; quiero dar la posibilidad de poder obtener un reporte en inglés o español según lo que la persona agregue como argumento.

Estoy armando así:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

if ($idioma eq "es" ) {
print F "<h1>analisis de seguridad - Informe</h1>";
print F "<p>Cabe aclarar que si algunos items estan vacios significa que la configuraci&oacute;n esta correcta. <a href=\"$Hostname-$dia-recomendaciones.html\"><button type=\"button\" class=\"button-warning pure-button\">Recomendaciones</button></a></p>";
}
elsif ($idioma eq "en" ) {
print F "<h1>Security analysis - Report</h1>";
print F "<p>Take into account, that if some items are empty, it means that the configuration is correct. <a href=\"$Hostname-$dia-recomendations.html\"><button type=\"button\" class=\"button-warning pure-button\">Recomendations</button></a></p>";
}
 
Coloreado en 0.003 segundos,  usando GeSHi 1.0.8.4

Pero no sé si es lo mejor ya que tengo muchos print por realizar y por ahora vengo duplicando ese código y cambiando los print.

Saludos y gracias.

use constant { 
    SALUDO    => 0, 
    DESPEDIDA => 1, 
};
 
my @msg = (  
    [
        "¡Hola!", 
        "¡Adiós!", 
    ],
    [ 
        "Hi!", 
        "Goodbay!", 
    ], 
); 
 
if ($idioma_solicitado eq 'ingles') {
    $idioma = 1;
}
else {
    $idioma = 0;
}
 
...; 
     
print "$msg[$idioma][1]\n";         # poniendo el número del mensaje
print "$msg[$idioma][DESPEDIDA]\n"; # usando constante (más fácil de recordar)
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

por **situ** » 2014-08-04 20:41 @903

¡Perfecto!

Una consulta: ahora tengo un script principal que va llamando a otros utilizando:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

use lib 'libs';
require "fase0.pl";
require "fase2.pl";
require "fase1.pl";
require "faseX.pl";
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Cómo puedo hacer para tener todos los print() en mi archivo principal y luego en los script usar:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

print F "$msg[$idioma][0]\n";
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Así tengo todo más ordenado.

Saludos.

por **explorer** » 2014-08-05 10:59 @499

En vez de require, lo mejor es usar do().

En ese caso, no se puede usar el módulo constant, ya que sus definiciones no son conocidas en módulos externos.

Una forma de resolverlo es convirtiendo las constantes a claves de un hash:

Sintáxis: (mensajes.pl) [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
 
our %msg = (
    SALUDO    => 0,
    DESPEDIDA => 1,
);
 
our @msg = (  
    [
        "¡Hola!",
        "¡Adiós!",
    ],
    [
        "Hi!",
        "Goodbay!",
    ],
);
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Sintáxis: (programa.pl) [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use v5.14;
 
do 'mensajes.pl';
 
our %msg;
our @msg;
 
my $idioma_solicitado = 'inglés';
my $idioma = $idioma_solicitado eq 'inglés' ? 1 : 0;
 
print "$msg[$idioma][0]\n";                     # poniendo el número del mensaje
print "$msg[$idioma][$msg{DESPEDIDA}]\n";       # usando constante (más fácil de recordar)
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Pero... queda un poco largo. Casi mejor si lo juntamos todo en forma de módulo:

Sintáxis: (Msg.pm) [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
 
package Msg;
use utf8;
use v5.14;
use Exporter 'import';
 
### Lista de idiomas
use constant {
    ESPAÑOL    => 0,
    INGLÉS     => 1,
    ALEMÁN     => 2,
};
 
### Lista de mensajes
use constant {
    SALUDO    => 0,
    DESPEDIDA => 1,
};
 
our @msg = (  
    [
        "¡Hola!",
        "¡Adiós!",
    ],
    [
        "Hi!",
        "Goodbay!",
    ],
    [
        "Hallo zusammen!",
        "Auf Wiedersehen!",
    ],
);
 
our $idioma = ESPAÑOL;                 # Idioma por defecto
 
sub cambia_idioma { $idioma = $_[0] }   # Cambiar de idioma
 
sub msg { $msg[$idioma][$_[0]] }        # Devolver mensaje
 
our @EXPORT = qw(&cambia_idioma &msg);  # Exportación
 
push @EXPORT, map { s/^Msg:://; $_ } keys %constant::declared;
 
1;
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Y ya desde el programa podemos usarlo de forma muy cómoda:

Sintáxis: (programa.pl) [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use utf8;
use v5.14;
use Msg;
use open IO => qw(:utf8 :std);          # para salida de caracteres tildados
 
#say "Índice idioma: $Msg::idioma";
#say $Msg::msg[$Msg::idioma][1];                # poniendo el número del mensaje
#say $Msg::msg[$Msg::idioma][DESPEDIDA];        # usando constante (más fácil de recordar)
 
my $idioma_solicitado = INGLÉS;
cambia_idioma($idioma_solicitado);
say msg(DESPEDIDA);                     # Goodbay!      
 
$idioma_solicitado = ESPAÑOL;
cambia_idioma($idioma_solicitado);
say msg(DESPEDIDA);                     # ¡Adiós!
say msg(SALUDO);                        # ¡Hola!
 
cambia_idioma(INGLÉS);
say msg(SALUDO);                        # Hi!
 
cambia_idioma(ALEMÁN);
say msg(DESPEDIDA);                     # Auf Wiedersehen!
 
 
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

por **situ** » 2014-08-05 12:35 @566

¡Perfecto! Muchas gracias, tengo una duda más.

Estoy usando un argumento para definir el idioma:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

$idioma_solicitado= $ARGV[0];
chomp $idioma_solicitado;
cambia_idioma($idioma_solicitado);
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

El problema es que el argumento guarda bien el valor, pero no entiendo por qué no cambia el texto. Digamos que si pongo inglés o español siempre me lo imprime en "español" salvo que yo fuerce directamente en la variable $idioma_solicitado = ingles.

Saludos.

por **explorer** » 2014-08-05 13:23 @599

En el módulo Msg.pm tenemos definido las cadenas de texto, las claves de los hash y las constantes (y por ende, todo el código Perl) que está todo codificado en UTF-8 (use utf8 al principio del módulo).

En el programa, hacemos lo mismo: declaramos que estamos usando código UTF-8 para escribir el código del programa, y además, indicamos que la entrada y la salida de archivos también deben ir en ese codificación (use open al principio del programa).

Pero... no hemos dicho nada con respecto a cómo deben estar codificados los argumentos que pasamos al programa. Y ahí debe estar el error: Perl no hace ninguna conversión de los argumentos de entrada (por defecto), así que, aunque estés trabajando en un ordenador con codificación UTF-8, Perl los tratará como si estuvieran codificados en ISO-8859-1 (la de por defecto de Perl).

Entonces, debes indicarle que sí debe tratar a los argumentos como que estuvieran en UTF-8. O transformarlos una vez leídos en el programa.

Al principio del programa, donde está la línea shebang, le agregas una serie de banderas, para indicar ese procesamiento:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl -CSDA
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

(Más información en tu propio ordenador en perldoc perlrun, y en la Web (traducido al español)).

Si eso no va, puedes probar con lo que dice al final de la regla ℞ 18: Hacer que toda la E/S y argumentos trabajen por defecto en utf8.

Foro - Perl en Español

Aplicación en 2 idiomas

Aplicación en 2 idiomas

Publicidad

Re: Aplicación en 2 idiomas

Re: Aplicación en 2 idiomas

Re: Aplicación en 2 idiomas

Re: Aplicación en 2 idiomas

Re: Aplicación en 2 idiomas

Re: Aplicación en 2 idiomas

Re: Aplicación en 2 idiomas

Re: Aplicación en 2 idiomas

Re: Aplicación en 2 idiomas

¿Quién está conectado?