Foro - Perl en Español

por **Camilein** » 2012-12-02 17:01 @750

Hola nuevamente a todos.

Primero que todo mis disculpas, si el título del tema no es muy representativo... No se me ocurrió otro asunto qué ponerle.

Estoy generando un script, en el que yo indico el directorio, y que me busca los archivos con determinados permisos. Mi script funciona, me encuentra los archivos, pero el detalle es que además de imprimirme el resultado deseado, me imprime un montón de líneas que dicen por ejemplo:

ls: no se puede acceder a /home/camilo/.mozilla/firefox/Crash: No existe el archivo o el directorio

En un principio pensé que había olvidado poner para que se saltara los archivos especiales, pero sí lo había puesto. Así que no se me ocurre por qué puede pasar.

Sé que existe File::Find para hacer esto mismo, pero quiero hacerlo a mi manera =)

Adjunto va mi código:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
# ls -l entrega :     permisos - N° de enlaces rígidos - propietario - grupo - tamaño(bytes) - ultima fecha de modificación
# Ejemplo de ls -l -> -rwxrwxr-x        1                  camilo      camilo        0           dic  2 16:03                     buscarPeligrosos.pl
 
use strict;
 
my $directorio = @ARGV[0];
if ( @ARGV <= 0 ) {
    die "Uso: $0 <directorio>\n";
}
 
chdir $directorio or die " No se puede abrir el directorio \n";
 
my @encontrados;                       #arreglo en el que se almacenan los archivos que coinciden
 
buscar($directorio);                   #llamado a la funcion
 
sub buscar {
    my $directorio = shift;
 
    opendir DIR, $directorio or die "ERROR: Algo salio mal: $!\n";
    my @archivos = readdir(DIR);
    closedir DIR;
 
    for my $archivo (@archivos) {
 
        next if $archivo eq '.';
        next if $archivo eq '..';
 
        my $file = "$directorio/$archivo";    #archivo con su ruta completa
        print "$file\n";
        if ( -f $file ) {
            my $info = qx/ls -l $file/;
            my @info_archivo = split( " ", $info );
 
            if (   @info_archivo[0] eq "-rwxrwxrwx"
                || @info_archivo[0] eq "-rwxrw-rw-"
                || @info_archivo[0] eq "-rw-rw-rw-" )    #realiza comparacion de permisos peligrosos
            {
                my $linea = @info_archivo[0] . '  ' . @info_archivo[2] . '  ' . @info_archivo[8];
                push @encontrados, $linea;  # cada vez que se encuentra un archivo, este es agregado al arreglo con push
                next;
            }
        }
        elsif ( -d $file )             #si $file es directorio llama a la funcion para entrar a ese directorio
        {
            buscar($file);
        }
    }
}
 
if ( @encontrados <= 0 ) {
    print "No hay archivos con permisos peligrosos\n";
}
else {
    print "---Archivos Peligrosos---\n";
    for my $archivo (@encontrados) {
 
        print "$archivo\n";
    }
}
 
Coloreado en 0.006 segundos,  usando GeSHi 1.0.8.4

Pues, muchas gracias de antemano por la ayuda.

Saludos

No estoy seguro, pero podría ser que el archivo a analizar hubiese desaparecido, desde el momento en que lo extraes desde la línea 22 hasta la línea 33.

Date cuenta que tienes hecho un proceso recursivo de recorrer los directorios, entonces puede pasar un tiempo hasta que accedes a esos archivos. Si son archivos temporales, pueden haber desaparecido. Y además, haces un 'ls' por cada archivo, que conlleva mucho tiempo y consumo de recursos de la máquina, por lo que tardará en recorrer los directorios.

Hay una forma más cómoda para realizar esto: existe la opción '-R' para el comando 'ls', que recorre todo el árbol de directorio de forma recursiva.

Una advertencia: no se debe escribir

@info_archivo[0]

sino

$info_archivo[0]

ya que solo estás accediendo a un solo elemento (consultar perldata).

Otra cosa: no necesitas hacer un 'ls' para obtener los detalles de cada archivo: con la función stat() ya lo tienes resuelto. En fin, todo esto ya te lo comenté antes.

por **Camilein** » 2012-12-02 19:02 @834

Okas. Lo de usar $ en lugar del @ para acceder a un elemento, me di cuenta solo y lo arregle, lo del stat... soy culpable, lo había olvidado por completo, pero me entró la duda: si uso ls -R, y encuentro una coincidencia... ¿cómo sé en qué directorio está el archivo? La solución que se me había ocurrido es usar locate, porque al encontrar un archivo que coincida con los permiso indicados, debo además mostrar su ruta absoluta. ¡Ah! y al usar ls -R... ¿es posible revisar los archivos a medida que los va listando, y ver si es archivo o directorio?

Esup

El código que envié primero, funciona bien. Esos errores que tiraba eran de la distribución que estaba usando, probablemente referencias, que quedan de archivos que no existen, porque el mismo código lo probé en otra distribución recién instalada y funcionó de lo más bien sin tirar ni un solo error.

por **explorer** » 2012-12-03 12:32 @564

A ver... antes hay que resolver un tema de concepto...

¿Quieres hacer un programa en Perl, completamente en Perl, o usando comandos externos?

El problema que estás intentando resolver se puede resolver completamente en Perl. Es más, el propio Perl te va a realizar el programa por ti, como he indicado en otro hilo.

Otro caso es usar comandos externos, como 'ls', 'locate' (este no está instalado en todos los sistemas). Esto tiene el problema de que no te funcionará en todos los sistemas (por ejemplo, en Windows, ya que no disponen del comando 'ls').

Claro que se puede resolver con esos comandos externos... con mi propuesta de 'ls -lR' obtienes una visión recursiva de todo un árbol de directorios:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use strict;
use warnings;
use diagnostics;
 
use File::Basename;
use File::Listing qw(parse_dir);
 
 
## Directorio a analizar, pasado por argumento al programa
my $directorio_base = shift // $ENV{HOME};
 
## Comprobar que existe el directorio
if (not -d $directorio_base) {
    my($filename, $directories, $suffix) = fileparse($directorio_base);
 
    if (not -d $directories) {
        die "ERROR: No encuentro el directorio $directorio_base: $!\n";
    }
 
    $directorio_base = $directories;
}
 
print "Analizando [$directorio_base]\n";
 
## Listado recursivo de directorios
$ENV{LANG} = "C"; # este módulo solo es capaz de interpretar fechas en formato original inglés
 
for (parse_dir(`ls -lR $directorio_base`)) {
    my ($name, $type, $size, $mtime, $mode) = @$_;
 
    next if $type ne 'f';       # solo analizaremos archivos normales
 
    $mode = $mode & 0777;       # nos quedamos con los permisos más bajos
 
    if ($mode == 0777
    or  $mode == 0766
    or  $mode == 0666
    ) {
        printf "\t%04o %s\n", $mode, $name;
    }
}
__END__
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

explorer@casa:~/Documentos/Desarrollo> ./kk.pl ~/Documentos/Desarrollo/test

Analizando [/media/500_1/home/explorer/Documentos/Desarrollo/test]

        0666 /media/500_1/home/explorer/Documentos/Desarrollo/test/test.pl~Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

Pero entonces... ¿por qué no seguimos con el mismo razonamiento, y utilizamos comandos externos que ahorren aún más trabajo?

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
my $directorio_base = shift // $ENV{HOME};
 
print "Listado de archivos peligrosos:\n";
my @archivos = qx(find $directorio_base -type f -perm 0777 -o -perm 0766 -o -perm 0666);
 
print "\t$_" for @archivos;
 
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

El verdadero reto es resolver el problema completamente en Perl

Foro - Perl en Español

Archivo o directorio que no existe al usar ls -l

Archivo o directorio que no existe al usar ls -l

Publicidad

Re: Archivo o directorio que no existe al usar ls -l

Re: Archivo o directorio que no existe al usar ls -l

Re: Archivo o directorio que no existe al usar ls -l

¿Quién está conectado?