Foro - Perl en Español

por **felloz** » 2019-09-01 19:34 @857

Un saludo.

Tengo este código con el que busco hasta el final de la línea pero me gustaría que buscara hasta que se encuentre un punto, para que me extraiga un texto con coherencia.

A continuación el código:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
 
use strict;
use warnings;
 
my $body;
my $smtpCode;
 
$body = "Diagnostic-Code: smtp; 550-5.1.1 The email account that you tried to reach does
    not exist. Please try 550-5.1.1 double-checking the recipient's email
    address for typos or 550-5.1.1 unnecessary spaces. Learn more at 550 5.1.1
    https://support.google.com/mail/?p=NoSuchUser s35si4587705qvc.145 - gsmtp";
 
foreach ( split( /\n/, $body ) ) {
    next if (/^\s*$/);
 
    if ( $_ =~ /^Diagnostic-Code:\ssmtp;\s(.*)$/ ) {
        $smtpCode = $1;
        print $smtpCode;                       # Salida: 550-5.1.1 The email account that you tried to reach does
 
    }
}
 
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

Y lo que realmente me gustaría que mostrara es lo siguiente:

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

550-5.1.1 The email account that you tried to reach does
not exist.
Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

O que por lo menos muestre todo el párrafo después de Diagnostic-Code: smtp;

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

550-5.1.1 The email account that you tried to reach does
not exist. Please try 550-5.1.1 double-checking the recipient's email
address for typos or 550-5.1.1 unnecessary spaces. Learn more at 550 5.1.1
https://support.google.com/mail/?p=NoSuchUser s35si4587705qvc.145 - gsmtp
Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

Muchas gracias.

#!/usr/bin/perl
use strict;
use warnings;
 
my $body = "Diagnostic-Code: smtp; 550-5.1.1 The email account that you tried to reach does
    not exist. Please try 550-5.1.1 double-checking the recipient's email
    address for typos or 550-5.1.1 unnecessary spaces. Learn more at 550 5.1.1
    https://support.google.com/mail/?p=NoSuchUser s35si4587705qvc.145 - gsmtp";
 
my $resultado;
 
for ( split /\n/, $body ) {
    next if /^\s*$/;                            # saltamos líneas en blanco
 
    s/^\s+//;                                   # quitamos espacios iniciales de la línea
 
    # si estamos en el rango "Diagnostic" ... punto+espacio o fin de archivo
    if ( my $en_rango = /^Diagnostic-Code:\ssmtp;/ .. (/\. / || eof) ) { 
        my $linea = $_;
 
        if ($en_rango == 1) {                   # si es la primera...
            $linea =~ s/^Diagnostic-Code:\ssmtp;\s//;
        }
        elsif ($en_rango =~ /E0$/) {            # si es la última línea...
            $linea =~ s/\.\K.*//;               # quitamos lo que hay después del punto
        }
 
        if ($resultado) {                       # acumulamos la $linea al $resultado
            $resultado .= " $linea";
        }
        else {
            $resultado = $linea;
        }
    }
}
 
print "[$resultado]\n";                         # [550-5.1.1 The email account that you tried to reach does not exist.]
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

pero... sería mejor tener más información de cómo es el texto de donde queremos extraer esa información. Si es un registro de actividad (log), ese texto vendrá en una sola línea, por lo que la solución es más sencilla.

por **felloz** » 2019-09-02 09:20 @430

Muchas gracias por tu respuesta.

En el caso de que quiera retirar de la variable $resultado el texto Diagnostic-Code: smtp;, ¿me recomiendas hacerlo con la función substr()?

por **explorer** » 2019-09-02 09:43 @447

Se puede hacer, pero es mucho más cómodo usar una operación de sustitución s///.

por **felloz** » 2019-09-02 10:20 @472

explorer escribiste:Se puede hacer, pero es mucho más cómodo usar una operación de sustitución s///.

Excelente

Sintáxis: [ Descargar ] [ Ocultar ]

$resultado =~ s/Diagnostic-Code: smtp;//;

por **felloz** » 2019-09-03 09:59 @457

Me he percatado de algo interesante: ¿Qué pasaría si ese dato yo lo quisiera ingresar en un campo de una base de datos? ¿Qué pasaría si ese texto contiene comillas simples? Pasaría que la consulta destinada al hacer el INSERT fallaría y no podría registrar los datos.

Se me ocurrió utilizar la función que me recomendaste (s///) pero, ¿qué pasaría si hay más de una comilla? Pues ahí fue donde se me ocurrió usar un while(), pero ocurre algo. A pesar de que el texto se almacena en toda la variable parece que el salto de página persiste en la variable $resultado y si la comilla está en la segunda línea no las extrae.

Hasta aquí pude avanzar, cualquier ayuda estaría agradecido.

Sintáxis: [ Descargar ] [ Ocultar ]

use strict;
use warnings;
my $body = "Diagnostic-Code: smtp; 550-5.1.1 The email's account that you tr'ied to re'ach do'es
n'ot 'exist. Please try 550-5.1.1 double-checking the recipient's email
address for typos or 550-5.1.1 unnecessary spaces. Learn more at 550 5.1.1
https://support.google.com/mail/?p=NoSuchUser s35si4587705qvc.145 - gsmtp";
my $resultado;
for ( split /\n/, $body ) {
next if /^\s*$/; # saltamos líneas en blanco
s/^\s+//; # quitamos espacios iniciales de la línea
# si estamos en el rango "Diagnostic" ... punto+espacio o fin de archivo
if ( my $en_rango = /^Diagnostic-Code:\ssmtp;\s(.*)$/ .. (/\. / || eof ) ) {
my $linea = $_;
if ($en_rango =~ /E0$/) { # si es la última línea,
$linea =~ s/\.\K.*//; # quitamos lo que hay después del punto
}
if ($resultado) { # acumulamos la $linea al $resultado
$resultado .= " $linea";
}
else {
$resultado = $linea;
$resultado =~ s/Diagnostic-Code: smtp;//;
while($resultado =~ /'/){
$resultado =~ s/'//;
}
}
}
}
print "$resultado\n"; #Mostrará: 550-5.1.1 The emails account that you tried to reach does n'ot 'exist.

por **explorer** » 2019-09-03 11:22 @515

No necesitas quitar las comillas.

Si haces la consulta con el sistema de "placeholders" del módulo DBI, es el propio DBI el que se encarga de "escapar" esos caracteres peligrosos.

Mira este código:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

$sth = $dbh->prepare('INSERT INTO tabla VALUES( ?, ? )');
$sth->execute( $id, $resultado );
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

En la primera línea llamamos al método prepare() con la consulta SQL que queremos ejecutar. Es igual a cualquier otra consulta, pero aparecen un par de caracteres '?'. Estos son los que se llaman "placeholder" o guardasitios. El DBI "prepara" la consulta, pero no la ejecuta.

Luego, en la segunda línea es cuando ejecutamos la consulta, pero pasando dos argumentos. Cada argumento se "colocará" en su "placeholder" correspondiente, escapando los caracteres peligrosos. Luego ejecuta la consulta.

Otro ejemplo más sencillo y enlaces.

Sobre la forma de quitar las comillas... hay otra forma más cómoda: sustitución global (/g), sin necesidad de bucles.

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

$resultado=~s/'//g;Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

No nos has dicho nada de cómo es la información en origen. ¿Realmente te llega en varias líneas o solo en una? Ese tipo de mensajes les veo con frecuencia en nuestros servidores, y llegan en una sola línea. Si es así, la solución se acorta bastante.

por **felloz** » 2019-09-03 12:07 @547

La información de origen es una bandeja de correos con sus cabeceras. Pero básicamente la información viene muy parecida en como la presenté en la variable, en algunos casos puede venir con comillas simples y nos puede arrojar un error SQL. Quiero prever la situación, pensé en hacerla con la función para no meternos con los query.

por **explorer** » 2019-09-03 12:30 @562

Entonces con el sistema de "placeholder" lo tienes resuelto, no tienes que quitar nada.

por **felloz** » 2019-09-03 12:47 @574

explorer escribiste:Entonces con el sistema de "placeholder" lo tienes resuelto, no tienes que quitar nada.

El problema es que la persona que construyó el codigó inicial para hacer los INSERT en la base de datos lo hizo de una manera que no sé si fue la mejor pero creo que tendríamos que hacer cambios importantes en el código.

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

        for my $row ( sort keys %devueltos ) {
 
            $query        = undef;
            $queryColumns = undef;
            $queryValues  = undef;
 
            if ( exists( $campanas{ $devueltos{$row}{'campanaid'} } ) ) {
                $campanas{ $devueltos{$row}{'campanaid'} }{'count'}++;
                $campanas{ $devueltos{$row}{'campanaid'} }{'adminid'} = $devueltos{$row}{'adminid'};
            }
            else {
                $campanas{ $devueltos{$row}{'campanaid'} }{'count'}   = 1;
                $campanas{ $devueltos{$row}{'campanaid'} }{'adminid'} = $devueltos{$row}{'adminid'};
            }
 
            if ( defined $devueltos{$row}{'smtpcode'} ) {
                $queryColumns .= "smtpcode1, ";
                $queryValues  .= " '" . $devueltos{$row}{'smtpcode'} . "', ";
            }
            if ( defined $devueltos{$row}{'email'} ) {
                $queryColumns .= "email, ";
                $queryValues  .= " '" . $devueltos{$row}{'email'} . "', ";
            }
            if ( defined $devueltos{$row}{'smtpaction'} ) {
                $queryColumns .= "smtpaction, ";
                $queryValues  .= " '" . $devueltos{$row}{'smtpaction'} . "', ";
            }
            if ( defined $devueltos{$row}{'smtpstatus'} ) {
                $queryColumns .= "smtpcode, ";
                $queryValues  .= " '" . $devueltos{$row}{'smtpstatus'} . "', ";
            }
            if ( defined $devueltos{$row}{'smtpdiagnosticcode'} ) {
                my $deletechar = $devueltos{$row}{'smtpdiagnosticcode'} =~ s/'//g;
                $queryColumns .= "smtpprefixdetail, ";
 
                #$queryValues .= " E'".encode('utf8', decode('iso-8859-1', $devueltos{$row}{'smtpdiagnosticcode'}))."', ";
                $queryValues .= " '" . encode( 'utf8', decode( 'iso-8859-1', $deletechar ) ) . "', ";
            }
            if ( defined $devueltos{$row}{'smtpremotemta'} ) {
                $queryColumns .= "smtpremote, ";
                $queryValues  .= " '" . $devueltos{$row}{'smtpremotemta'} . "', ";
            }
            if ( defined $devueltos{$row}{'smtplastattempdate'} ) {
                $queryColumns .= "smtpdate, ";
                $queryValues  .= " '" . $devueltos{$row}{'smtplastattempdate'} . "', ";
            }
            if ( defined $devueltos{$row}{'userid'} ) {
                $queryColumns .= "id_usuario, ";
                $queryValues  .= "$devueltos{$row}{'userid'}, ";
            }
            if ( defined $devueltos{$row}{'adminid'} ) {
                $queryColumns .= "id_admin, ";
                $queryValues  .= "$devueltos{$row}{'adminid'}, ";
            }
            if ( defined $devueltos{$row}{'campanaid'} ) {
                $queryColumns .= "id_campana, ";
                $queryValues  .= "$devueltos{$row}{'campanaid'}, ";
            }
            if ( defined $devueltos{$row}{'listaid'} ) {
                $queryColumns .= "id_lista, ";
                $queryValues  .= "$devueltos{$row}{'listaid'}, ";
            }
            if ( defined $devueltos{$row}{'status'} ) {
                $queryColumns .= "status, ";
                $queryValues  .= "true, ";
            }
 
            $queryColumns .= "fecha ";
            $queryValues  .= "now() ";
 
            $query = "INSERT INTO ex_tbl_devueltos ($queryColumns) VALUES ($queryValues);";
            $string .= $query . "\n";
            $sth = $dbh->prepare($query) or die "Can't prepare SQL statement: ", $dbh->errstr(), "\n";
            $sth->execute() or die "Can't execute SQL statement: ", $sth->errstr(), "\n";
 
        }
 
Coloreado en 0.003 segundos,  usando GeSHi 1.0.8.4

Foro - Perl en Español

Buscar y almacenar párrafo o hasta determinado símbolo

Buscar y almacenar párrafo o hasta determinado símbolo

Publicidad

Re: Buscar y almacenar párrafo o hasta determinado símbolo

Re: Buscar y almacenar párrafo o hasta determinado símbolo

Re: Buscar y almacenar párrafo o hasta determinado símbolo

Re: Buscar y almacenar párrafo o hasta determinado símbolo

Re: Buscar y almacenar párrafo o hasta determinado símbolo

Re: Buscar y almacenar párrafo o hasta determinado símbolo

Re: Buscar y almacenar párrafo o hasta determinado símbolo

Re: Buscar y almacenar párrafo o hasta determinado símbolo

Re: Buscar y almacenar párrafo o hasta determinado símbolo

¿Quién está conectado?