Foro - Perl en Español

por **korsakof** » 2017-06-21 04:03 @210

Hola.

Estoy haciendo un pequeño programa y no sé por qué cuando solicito un dato por consola me indica que no puede acceder al archivo que le indico, copiando y pegando la ruta en la consola. En cambio, cuando le indico la ruta absoluta del archivo como se muestra en el primer bloque de código, funciona.

Cabecera:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

require 'C:\Users\Paco\Desktop\Recursos\perl\libreria.pm';
Coloreado en 0.004 segundos,  usando GeSHi 1.0.8.4

Funciona la llamada:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

print "\nIndica la ruta a testar:"; 
$ruta=<STDIN>; 
testFile('C:\Users\Paco\Desktop\Recursos\perl\prueba.log');
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

No funciona la llamada:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

print "\nIndica la ruta a testar:"; 
$ruta=<STDIN>; 
testFile($ruta);#Este metodo se encuentra dentro de libreria.pm
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Funcion Testlib:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

sub testFile {
    my $filename = $_[0];
    open( my $fh, "<", $filename )
        or die "Could not open file '$filename' $!";    #linea 520
 
    while ( my $row = <$fh> ) {
        chomp $row;
        if ( defined $row && $row ne "" ) {
            test( $row, 1 );
        }
    }
}
 
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

sub testFile {
    my $filename = shift @_;
    print "\nFilename=>$filename\n";
    open( my $fh, "<", $filename )
        or die "Could not open file '$filename' $!";    #linea 520
 
    while ( my $row = <$fh> ) {
        chomp $row;
        if ( defined $row && $row ne "" ) {
            test( $row, 1 );
        }
    }
}
 
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

Error:

Sintáxis: [ Descargar ] [ Ocultar ]

Using bash Syntax Highlighting

Could not open file 'C:\Users\Paco\Desktop\Recursos\perl\prueba.log
' Invalid argument at C:\Users\Paco\Desktop\Recursos\perl\libreria.pm line 520, <STDIN> line 1.
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

No sé qué estoy haciendo mal, he comprobado la variable al llegar al método y es capaz de mostrarla pero no la procesa.

Muchas gracias. Un saludo. Sigo investigando.

Actualizo

He conseguido hacerlo funcionar pero no entiendo por qué no funcionaba.

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

open(my $fh, "<$filename")
  or die "Could not open file '$filename' $!";
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

He probado varios que no sé por qué no funcionan, indica que es por el parámetro pero yo veo que llega bien la ruta a la función:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

open(my $fh, "<","$filename")
  or die "Could not open file '$filename' $!";
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

open(my $fh, '<',"$filename")
  or die "Could not open file '$filename' $!";
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

open(my $fh, '<','$filename')
  or die "Could not open file '$filename' $!";
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Cuando lees algo por el teclado, Perl recibe todos los caracteres MÁS los caracteres de final de línea (recuerda que has pulsado la tecla de Entrar o Enter en el teclado). Bueno, pues recibes todo eso.

Fíjate en el mensaje de error... hay un retorno de carro y un avance de línea justo después del texto prueba.log, que hace que la comilla simple aparezca en la línea siguiente.

El error está claro: el sistema no es capaz de abrir un archivo que se llama "prueba.log\n\r". Aunque tú no veas esos caracteres, el sistema sí que los ve y se cree que estás buscando algo así.

La solución es... la misma que tienes dentro de testFile(): poner un chomp() a la línea que hemos recibido del usuario:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

chomp($ruta = <STDIN>);
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Ahora bien... ¿por qué funciona con unos open() y con otro no?

Resulta que open(), cuando se le llama con la forma de 2 argumentos, hace una "limpieza" de los caracteres "espacio" que rodeen al nombre del archivo a abrir. Por ejemplo, estas dos líneas hacen lo correcto:

open(my $fh, "<$filename");
open(my $fh, "< $filename ");

Es más... si $filename contiene caracteres de espacio, TAMBIÉN los quita. Y eso es lo que está pasando en tu correo: Perl elimina en el open() los caracteres de fin de línea que estaban puestos en lo que metió el usuario por teclado. La explicación es que esos caracteres de fin de línea tienen la misma consideración que los caracteres de espacio.

Pero... eso no funciona en la versión de 3 argumentos:

open(my $fh, "<", $filename);

En este caso, Perl permite $filename contenga cualquier tipo de caracteres, incluidos los finales de línea, y no los quita... y por lo tanto salta el error de que no encuentra ese archivo.

Entonces,

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

open(my $fh, "<", "$filename");  # Da lo mismo comillas dobles que simples
open(my $fh, '<', "$filename");  #   alrededor de '<'.
open(my $fh, '<', '$filename');  # ¡ERROR! Le estamos pidiendo que nos abra el archivo '$filename', literal
open(my $fh, '<',  $filename );  # Las comillas dobles alrededor de $filename, sobran.
 
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

La recomendación es:

quitar los caracteres que sobran, en el momento de la lectura (el chomp() anterior), y
usar la forma de 3 argumentos de open() ya que tiene un plus de seguridad (la versión de 2 argumentos tiene, además, el problema de "interpretar" caracteres de redirección, así que puede ser algo peligroso).

por **korsakof** » 2017-07-04 03:57 @206

¡¡Muchísimas gracias!!!. Ya conseguí arreglarlo y entenderlo. La verdad es que no me había percatado de esa diferencia que comentas en el mensaje anterior.

Foro - Perl en Español

Cadena de ruta al archivo

Cadena de ruta al archivo

Publicidad

Re: Cadena de ruta al archivo

Re: Cadena de ruta al archivo

¿Quién está conectado?