Foro - Perl en Español

por **pacoparedes** » 2012-08-20 18:02 @793

Buenas tardes, estoy trabajando con una matriz de datos que tiene la siguiente estructura:

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

        Muestra 1       Muestra 2       Muestra3

Gen 1   3.92191         4.03648          4.0114

Gen 2   11.93265        12.4678          11.67605

Gen 3   4.22257         3.99756          4.17728Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

Los valores numéricos indican la expresión de cada uno de los genes en cada una de las diferentes muestras, por lo que yo necesito sacar la correlación (r) existente entre la expresión del Gen 1 con el Gen 2, Gen 1 con Gen 3, Gen 2 con Gen 3, por lo que he escrito el siguiente código:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl -w
#ejercicio1.pl
my $arch = $ARGV[0];
open( ARCH, $arch );
my @array = <ARCH>;
close ARCH;
foreach $i (@array) {                  #cálculo de los valores de X, media y desviación estándar
    chomp($i);
    @array2 = split( /\t+/, $i );
    $sumatoria_x = 0;
    for ( $j = 1; $j < @array2; $j++ ) {
        $sumatoria_x += $array2[$j];
    }
    $num_elem = @array2;
    $media_x = $sumatoria_x / ( $num_elem - 1 );
 
    #print "$array2[0]\t$media_x\n";
    $sumatoria_x = 0;
    for ( $k = 1; $k < @array2; $k++ ) {
        $sumatoria_x += ( $array2[$k] - $media_x )**2;
    }
    $des_stnd_x = sqrt( $sumatoria_x / ( $num_elem - 2 ) )
        ;                              #le resto dos por la presencia del identificador en la posc. 0 y 1 q indica la fórmula n-1.
 
    #print "$array2[0]\t$media\t$des_stnd_x\n";
 
    foreach $l (@array) {              #cálculo de los valores de Y, media y desviación estándar
        chomp($l);
        @array3 = split( /\t+/, $l );
        $sumatoria_y = 0;
        for ( $m = 1; $m < @array3; $m++ ) {
            $sumatoria_y += $array3[$m];
        }
        $num_elem = @array3;
        $media_y = $sumatoria_y / ( $num_elem - 1 );
 
        #print "$array2[0]\t$media_y\n";
        $sumatoria_y = 0;
        for ( $n = 1; $n < @array3; $n++ ) {
            $sumatoria_y += ( $array3[$n] - $media_y )**2;
        }
        $des_stnd_y = sqrt( $sumatoria_y / ( $num_elem - 2 ) )
            ;                          #le resto dos por la presencia del identificador en la posc. 0 y 1 q indica la fórmula n-1.
 
        #print "$array2[0]\t$media\t$des_stnd_y\n";
        $suma_cov = 0;
        for ( $o = 1; $o < @array2; $o++ ) {    #utilizo una sola variable por que ambos arreglos son del mismo tamaño
            $suma_cov += ( $array2[$o] - $media_x ) * ( $array3[$o] - $media_y );
        }
        $cov         = $suma_cov / ( $num_elem - 1 );
        $correlacion = $cov /      ( $des_stnd_y * $des_stnd_x );
        $co = sprintf( "%.2f", $correlacion );
        print "$array2[0]\t$array3[0]\t$co\n";
    }
}
Coloreado en 0.004 segundos,  usando GeSHi 1.0.8.4

Este código funciona bien, sin embargo calcula la correlación existente entre
Gen 1-Gen 1, Gen 1-Gen 2, Gen 1-Gen 3,
Gen 2-Gen 1, Gen 2-Gen 2, Gen 2-Gen 3, etc...

Pero como podemos notar el cálculo de la correlación existente entre Gen 1-Gen 2, es lo mismo que el cálculo entre Gen 2-Gen 1, es decir, me está repitiendo cálculos.

Es por eso que pido su ayuda para optimizar mi código y evitar estas situaciones.

Gracias...

Según los cálculos que muestras, creo que lo que estás intentando hacer es calcular los coeficientes de correlación de Pearson. ¿Es así?

En ese caso, creo que el error está en la línea 27, ya que si suponemos que los valores x son los leídos en el bucle de la línea 7 (las filas), en el 27 los valores y deberían ser los de las columnas (las muestras), pero en lugar de eso estás volviendo a leer las líneas.

por **pacoparedes** » 2012-08-24 17:48 @783

Asi es, explorer. Estoy tratando de calcular el coeficiente de correlación de Pearson. Revisaré tus observaciones. Gracias.

por **pacoparedes** » 2012-08-25 19:36 @858

Buenas tardes explorer. Revisé mi código y lo que hice fue sustituir los foreach de las líneas 7 y 27 por for, y en la condición de inicio del for para el cálculo de Y utilicé $l=$i+1 y está funcionando bien.

Gracias...

por **explorer** » 2012-08-28 18:05 @795

Esta es mi versión, aunque no he comprobado si los datos que salen son correctos...

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/env perl
use Acme::Tools;                                # Caja de herramientas marca ACME
use Data::ShowTable;
 
### Leemos el archivo
my @filas;
readfile('code_32086.txt', \@filas);
 
### Procesamos las cabeceras de las columnas
my @nombres_columnas = split /\t+/, shift @filas;
 
### Procesamos las cabeceras de las filas
@filas = map { [ split /\t+/, $_ ] } @filas;    # conversión a array de array
my @nombres_filas = map { shift @$_} @filas;
 
### Extraemos las columnas
my @columnas;
for my $i (0 .. $#{$filas[0]}) {
    $columnas[$i] = [ map { $_->[$i] } @filas ];
}
 
### Comprobación
die "ERROR: no coinciden el número de filas con el de columnas.\n"
    if @filas != @columnas;
 
### Cálculo de las medias
my @medias_filas    = map { avg @$_    } @filas;
my @medias_columnas = map { avg @$_    } @columnas;
 
### Cálculo de las desviaciones estándar
my @desv_filas      = map { stddev @$_ } @filas;
my @desv_columnas   = map { stddev @$_ } @columnas;
 
### Recorrer la tabla, calculando la correlación
my @correlaciones;
 
for my $i (0 .. $#filas) {
    for my $j (0 .. $#columnas) {
        my $suma_cov = 0;
        for my $k (0 .. $#filas) {
            $suma_cov += ( $filas   [$i][$k]  -  $medias_filas   [$i] )
                        *
                         ( $columnas[$j][$k]  -  $medias_columnas[$j] )
            ;
        }
 
        my $cov         = $suma_cov / @filas;
        my $correlacion = $cov / ( $desv_filas[$i] * $desv_columnas[$j] );
        
        $correlaciones[$i][$j] = $correlacion;
    }
}
 
### Presentación de la tabla
my $corr_i = 0;
 
ShowTable({
    titles      => \@nombres_columnas,
    types       => [ 'titulo', ('valor') x @columnas ],
    widths      => [ 7,        ("12.2")  x @columnas ],
    row_sub     => sub {
                    my $rebobinar = shift;
                    
                    if ($rebobinar == 0) {              # nos piden una fila
                        if  ($corr_i < @correlaciones) {
                            my $fila_ref = $correlaciones[$corr_i];
                            my @row = ($nombres_filas[$corr_i], @{$fila_ref});
                            $corr_i++;
                            return @row;
                        }
                        else {
                            return;                     # fin de tabla
                        }
                    }
                    else {                              # rebobinar
                        $corr_i = 0;
                        return 1;
                    }
                },
    fmtsub      => sub {                                # Formateo de cada celda
                    my($valor, $tipo, $max_width, $width, $precision) = @_;
                    if ($tipo eq 'titulo') {
                        return sprintf "%*s", $width, $valor;
                    }
                    else {
                        return sprintf "%*.*f", $width, $precision, $valor;
                    }
                },
    max_width   => 80,
    show_mode   => 'Box',
});
 
__END__
 
Coloreado en 0.003 segundos,  usando GeSHi 1.0.8.4

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

 +-------+-----------+-----------+----------+

 |       | Muestra 1 | Muestra 2 | Muestra3 |

 +-------+-----------+-----------+----------+

 | Gen 1 |      0.46 |      0.44 |     0.46 |

 | Gen 2 |      0.62 |      0.63 |     0.63 |

 | Gen 3 |     -0.66 |     -0.65 |    -0.66 |

 +-------+-----------+-----------+----------+Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

Foro - Perl en Español

Cálculo de la correlación entre datos de una matriz

Cálculo de la correlación entre datos de una matriz

Publicidad

Re: Cálculo de la correlación entre datos de una matriz

Re: Cálculo de la correlación entre datos de una matriz

Re: Cálculo de la correlación entre datos de una matriz

Re: Cálculo de la correlación entre datos de una matriz

¿Quién está conectado?