Perdón, he metido la pata...
Los módulos Gtk2 no se instalan por separado: están todos reunidos en una sola librería.
Pues el caso es que no sé porqué te sale ese mensaje. Se supone entonces que con el primer 'use Gtk2' debería valer.
Te he dejado un ejemplo que a mí sí que me funciona:
Using perl Syntax Highlighting
#!/usr/bin/perl
use strict;
use warnings;
use diagnostics;
use Gtk2 '-init';
use Glib qw/TRUE FALSE/;
my @valores = 11 .. 20;
## Titular
my $frase = Gtk2::Label->new('Indique cuántos documentos desea buscar');
## Lista de opciones
my $comboBox = Gtk2::ComboBox->new_text();
for (@valores) {
$comboBox->append_text($_);
}
$comboBox->set_active (0);
## Tabla de la lista
my $tabla_combo= Gtk2::Table->new(2,3,TRUE);
$tabla_combo->attach_defaults($comboBox, 1,2,1,2);
## Botón Atrás
my $boton_atras = Gtk2::Button->new_with_label('Atras');
$boton_atras->signal_connect(clicked => \&atras);
## Botón Ok
my $boton_ok = Gtk2::Button->new_from_stock('gtk-ok');
$boton_ok->signal_connect(clicked => \&ir_a);
## Tabla de los botones
my $tabla_botones = Gtk2::Table->new(3,5, TRUE);
$tabla_botones->attach_defaults($boton_atras, 1,2,1,2);
$tabla_botones->attach_defaults($boton_ok, 3,4,1,2);
## Tabla contenedor
my $tabla_contenedor = Gtk2::Table->new(3,7, FALSE);
$tabla_contenedor->attach_defaults($frase, 1,2,1,2);
$tabla_contenedor->attach_defaults($tabla_combo, 1,2,3,4);
$tabla_contenedor->attach_defaults($tabla_botones, 1,2,5,6);
## Ventana principal
my $ventana = Gtk2::Window->new('toplevel');
$ventana->set_title('Documentos');
$ventana->set_border_width(20); # 20px
## Estilo
my $rc_style = Gtk2::RcStyle->new;
$rc_style->bg_pixmap_name('normal', 'fondo.jpg');
$ventana->modify_style($rc_style);
$ventana->signal_connect (delete_event => sub {Gtk2->main_quit; TRUE}); # Cierre de la app
$ventana->add($tabla_contenedor);
$ventana->set_default_size(200,200);
$ventana->set_keep_above(TRUE);
$ventana->set_resizable(FALSE);
$ventana->move(380, 300);
$ventana->show_all;
Gtk2->main;
sub ir_a {
print 'Índice: ', $comboBox->get_active(), "\n";
print 'Texto : ', $comboBox->get_active_text(), "\n";
}
sub atras{
Gtk2->main_quit;
}
Coloreado en 0.002 segundos, usando
GeSHi 1.0.8.4
Es igual que el tuyo, salvo que el orden de creación de los componentes es por jerarquía de menos a más. Así quedan agrupadas las órdenes para un mismo componente (que es lo contraría de lo que haríamos si usáramos el método del pack()).
Presta atención a los trucos de agregar elementos al
Combobox por medio del for(), que también es válido para listas de elementos.
He añadido también llamadas a Gtk2->main_quit() para terminar correctamente la aplicación, tanto al pulsar el botón 'Atrás' como cuando la ventana recibe la señal de cierre (puesto de dos formas distintas).
En cuanto a la lectura del Combobox, uso los métodos get_active() y get_active_text().
