Foro - Perl en Español

por **dbustos** » 2012-03-29 08:23 @390

Hola .

He estado utilizando un script para comparar archivos y que me genere uno nuevo solo con los datos que necesito por algún tiempo. Sin embargo, algo pasó que ahora me funciona bien cuando el segundo archivo tiene 3 campos, pero no cuando tiene más de 3 campos. ¿Qué puede estar pasando?

Muchas gracias y saludos a todos

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use strict;
use warnings;
 
### Cabecera
open my $OUTPUT, '>>', 'zeta_clubsI.out';
 
### Leer el primer archivo
open my $ARQ, '<', "kkk.out" or die "can not open the file $ARGV[0]";
my @arq = <$ARQ>;
 
close $ARQ;
 
### Leer el segundo archivo
open my $LIST, '<', "kkkk.csv" or die "can not open the file $ARGV[1]";
my @list = <$LIST>;
close $LIST;
 
### Comparación
for my  $lastline(@arq) {                       # para todas las líneas del primer archivo
        
 
    for my $thisline (@list) {                  # para todas las líneas del segundo archivo
 
            my ($club, $sym, $ens1, $D1) = split /,/, $thisline;
            my ($NP2, $ensemb2) = split /,/, $lastline;
                
            if ($ens1 eq $ensemb2 
                ){
                print $OUTPUT join("\,", $NP2, $club, $D1, "\n");
            }
        }
}
 
Coloreado en 0.005 segundos,  usando GeSHi 1.0.8.4

Yo veo correcta la extracción de datos, con el split(), salvo que no eliminas antes el carácter o caracteres de fin de línea de $thisline, por lo que podría afectar a la salida posterior.

Es mejor que pongas un chomp($thisline) antes del split(), para que quite esos caracteres.

Por otra parte, este método de comparación es muy ineficiente, debido a que estás comparando todas las líneas del segundo archivo con todas del primero. Mejor dicho, no las líneas, sino solo unos campos. El número de comparaciones puede ser muy grande.

Si, por ejemplo, supiéramos que los campos $ens1 del segundo archivo no se repiten (solo aparecen una vez en todo el segundo archivo), entonces es mucho mejor, en el proceso de lectura de ese archivo, guardarlo como un hash, y así, solo necesitas realizar un bucle:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use strict;
use warnings;
use autodie;
 
### Leer el segundo archivo
my %ens;
open my $LIST, '<', "kkkk.csv";
while (<$LIST>) {
    chomp;                                      # quitamos retorno de carro
    my ($club, undef, $ens, $D1) = split /,/;
 
    $ens{$ens} = [ $club, $D1 ];                # almacenamos información
}
close   $LIST;
 
### Leer el primer archivo
### mientras sacamos el resultado
open my $OUTPUT, '>>', 'zeta_clubsI.out';
open my $ARQ,    '<',  'kkk.out';
 
while (<$ARQ>) {
    chomp;                                      # quitamos retorno de carro
    my ($NP2, $ensemb2) = split /,/;
 
    if ($ens{$ensemb2}) {                       # si $ensemb2 existe como clave en %ens,
                                                # hacemos la salida de datos
        print $OUTPUT join(',', $NP2, @{ $ens{$ensemb2} } ), "\n";
    }
}
 
close $ARQ;
close $OUTPUT;
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

por **dbustos** » 2012-03-29 12:08 @547

Sí, efectivamente, ¡¡agregando el chomp() funciona!!
¡Mil Gracias!

Foro - Perl en Español

Comparación de archivos

Comparación de archivos

Publicidad

Re: Comparación de archivos

Re: Comparación de archivos

¿Quién está conectado?