Ver Tema - Configuración de vim para programar en Perl

explorer · 2011-10-20 10:45 @489

Esta es la configuración que yo uso para editar código Perl en Vim.

Como suelo programar tanto como un usuario normal, como siendo superusuario, la configuración está puesta de forma global, en el directorio /etc. Si se quiere que se use por parte de un solo usuario, pues vale con colocarlo en el directorio local.

Depende de la versión Linux/Unix que tengamos, pero lo normal es tener un fichero vimrc con opciones globales a toda el sistema, y vimrc.local, con opciones más personalizadas a cada usuario.

Algunas de las opciones globales que puede haber en vimrc, y que son interesantes activar para programar en Perl son:

Syntax: [ Download ] [ Hide ]

Using vim Syntax Highlighting

" Activar el resaltado de sintaxis
syntax on
" Saltar a la última línea que se estaba editando
if has("autocmd")
    au BufReadPost * if line("'\"") > 1 && line("'\"") <= line("$") | exe "normal! g'\"" | endif
endif
" Activar reglas de indentación
if has("autocmd")
    filetype plugin indent on
endif
" Interpretar lo que dice vimrc.local
if filereadable("/etc/vim/vimrc.local")
    source /etc/vim/vimrc.local
endif

Y este es el contenido de /etc/vim/vimrc.local, donde están las configuraciones propias para Perl. La mayor parte son configuraciones muy personales, así que es mejor desactivar, activar o cambiar aquellas opciones que más se acomoden a nuestra forma de trabajo:

Syntax: [ Download ] [ Hide ]

Using vim Syntax Highlighting

version 6.0       
if &cp | set nocp | endif
let s:cpo_save=&cpo
set cpo&vim       
nmap gx <Plug>NetrwBrowseX
nnoremap <silent> <Plug>NetrwBrowseX :call netrw#NetrwBrowseX(expand("^V<cWORD>"),0)^V^M
let &cpo=s:cpo_save
unlet s:cpo_save
 
" vim: set ft=vim :
 
"=====[ Personalización ]===============================
 
" set verbose=3
" set autoindent                                " Activar la indentación automática
set background=dark                             " Fondo de pantalla en negro
set backspace=indent,eol,start                  " Permitir backspace sobre esto en modo inserción
set backup                                      " Archivos Backup~
set backupdir=$HOME/.backup/,.                  " Directorio donde hacer los backup
set colorcolumn=120                             " Marcar columna margen derecho
set copyindent                                  " Copia la estructura de indentación al autoindentar
set endofline                                   " La última línea debe tener un fin de línea
set errorbells                                  " Toca la campana cuando error
set esckeys                                     " Asigna secuencias de escape inexistentes (activa las teclas del keypad)
set fileencodings=ucs-bom,utf-8,default,latin1  " Codificaciones de los ficheros
set fileformat=unix                             " Modo de fichero es unix
" set fileformats=unix,dos                      " Detecta formatos de fin de líneas en el fichero
set helplang=es                                 " Mensajes de ayuda
set hidden                                      " Recuerda el contenido del undo después de salir
set history=50                                  " Número de líneas que se almacenan en el histórico de comandos
set hlsearch                                    " Ilumina los patrones encontrados
set ignorecase                                  " Búsqueda insensible a las mayúsculas/minúsculas
set isfname=@,48-57,/,.,-,_,+,,,#,$,%,~,=,:     " Caracteres permitidos en los nombres de los ficheros
set listchars=tab:▸\ ,eol:¬                     " Caracteres invisibles al ser visibles
set laststatus=2                                " 0: no línea de estado. 1: solo si hay más de un fichero. 2: siempre
" set magic                                     " Cambia la forma en que los backslashes son usados en los patrones de búsqueda
set matchpairs+=<:>                             " Agrega los ángulos como caracteres emparejados
set modeline                                    " Muestra la línea indicador de modo
set mouse=a                                     " Usa el ratón (a=todos, n=normal, v=visual, i=insert, c=comando, h=ayuda)
set number                                      " Muestra números de línea
set printoptions=paper:a4                       " Tamaño del papel en la impresora
set ruler                                       " Muestra la posición del cursor en la barra de estado
" set runtimepath=~/.vim,/var/lib/vim/addons,/usr/share/vim/vimfiles,/usr/share/vim/current,/var/lib/vim/addons/after,~/.vim/after
set scrolloff=3                                 " Líneas por arriba/abajo cuando se desplace
set showcmd                                     " Muestra el comando en la barra de estado  
set showmatch                                   " Muestra el carácter emparejado (saltando brevemente)
set showmode                                    " Muestra el modo en la barra de estado (insert/replace/...)
set smartcase                                   " Sensible al tamño de caja si se usan mayúsculas en las búsquedas
                                                " Ficheros menos interesantes en las búsquedas
set suffixes=.bak,~,.swp,.o,.info,.aux,.log,.dvi,.bbl,.blg,.brf,.cb,.ind,.idx,.ilg,.inx,.out,.toc
set termencoding=utf-8                          " Codificación usada por la terminal
set textwidth=0                                 " Ancho máximo del texto. 0: desactivado
set title                                       " Muestra el nombre del fichero en la barra del título
set viminfo='20,\"500                           " Recuerda registros de copia después de salir, en el fichero .viminfo -- 20 ficheros, 500 líneas
set window=39                                   " Altura de la ventana de desplazamiento
set wildmenu                                    " Completado con menú
set nowrap                                      " No partir las líneas
 
"=====[ Definición de lo que son palabras clave ]===============================
 
set iskeyword+=$
set iskeyword+=%
set iskeyword+=@
set iskeyword-=,
 
"=====[ Add or subtract comments ]===============================
 
function! ToggleComment ()
    let currline = getline(".")
    if currline =~ '^#'
        s/^#//
    else "if currline =~ '\S'
        s/^/#/
    endif
endfunction
 
function! ToggleBlock () range
    let currline = getline(a:firstline)
    if currline =~ '^#'
        execute ":" . a:firstline . "," . a:lastline . "s/^#//"
    else "if currline =~ '\S'
        execute ":" . a:firstline . "," . a:lastline . "s/^/#/"
    endif
endfunction
 
 map <silent> # :call ToggleComment()<CR>j0
vmap <silent> # :call ToggleBlock()<CR>
 
"=====[ Programming support ]===================================
 
" Insert shebang lines...
" iab hbc #! /bin/csh
" iab hbs #! /bin/sh
iab plperl #! /usr/bin/perl<CR>
\use common::sense; <TAB><TAB># Hay que tener sentido común<CR><CR>
\use Modern::Perl; <TAB><TAB># Somos modernos<CR>
\use utf8; <TAB><TAB><TAB># este programa está escrito en utf8<CR><CR>
\use autodie; <TAB><TAB><TAB># es mejor morir que regresar con deshonor (proverbio Klingon)<CR>
\use open qw(:utf8 :std); <TAB># la salida y la entrada estándar serán en utf8<CR><CR>
\use File::Slurp;<CR><BS><CR><CR><CR>__END__<CR>
" iab hbp #! /opt/local/bin/perl5.10.0<CR>use 5.010;<CR>use warnings;
" iab hbr #! /Users/damian/bin/rakudo<CR>use v6;
 
" Insert common Perl code structures...
iab udd use Data::Dumper::Simple;<CR>warn Dumper [];<ESC>hi
iab ubm use Benchmark qw( cmpthese );<CR><CR>cmpthese -10, {<CR>};<ESC>O
iab usc use Smart::Comments;<CR>###
iab uts use Test::Simple 'no_plan';
iab utm use Test::More 'no_plan';
iab dbs $DB::single = 1;<ESC>
 
" Add new highlight combinations...
highlight YELLOW_ON_BLACK ctermfg=yellow ctermbg=black
highlight WHITE_ON_RED ctermfg=white ctermbg=red
 
" Track "faux" references...
function! BadRefs ()
    match WHITE_ON_RED /_ref[ ]*[[{(]\|_ref[ ]*-[^>]/
endfunction
call BadRefs()
 
 
"=====[ Highlight cursor column on request ]===================
 
highlight CursorColumn term=bold ctermfg=black ctermbg=DarkGrey cterm=bold
highlight CursorLine term=bold ctermfg=white ctermbg=DarkGrey cterm=bold
 
map <silent> ;c :set cursorcolumn!<CR>
map <silent> ;r :set cursorline!<CR>
 
set cursorcolumn
set cursorline
 
"=====[ Tab handling ]======================================
 
set tabstop=8       " Número de espacios que aparenta un carácter tabulador
set softtabstop=8   " Número de espacios cuando se inserta un tabulador
set noexpandtab     " No convertir los caracteres tabulador a espacios
set shiftwidth=4    " Número de espacios a usar en la indentación
set shiftround      " Siempre indentar al más cercano punto de parada del tabulado
set smarttab        " Usa shiftwidths a la izquierda, tabstops en el resto
set smartindent     " Activa el indentado inteligente
 
" Make the completion popup look menu-ish on a Mac...
highlight Pmenu ctermbg=white ctermfg=black
highlight PmenuSel ctermbg=blue ctermfg=white cterm=bold
highlight PmenuSbar ctermbg=grey ctermfg=grey
highlight PmenuThumb ctermbg=blue ctermfg=blue
 
" Execute Perl file...
map W :!clear;perl %;echo<CR>
 
" Debug Perl file...
map Q :!perl -d %<CR>
 
" Format file with perltidy...
map ;t 1G!Gperltidy<CR>
 
" Activar el modo de completado omnifunc
if has("autocmd") && exists("+omnifunc")            
    autocmd Filetype *                              
        \   if &omnifunc == "" |            
        \           setlocal omnifunc=syntaxcomplete#Complete |
        \   endif                           
endif
 

Mucho de este código está tomado del vimrc de Damian Conway

Algunas líneas requieren explicación:

14 a 57: configuraciones generales. Algunas se desvían un poco de lo recomendado por Damian en su libro Perl Best Practices, pero para mí, son suficientes tal y como están.
61 a 64: indicamos a Vim qué consideramos que es un identificador.
66 a 87: comentar y descomentar un bloque de líneas, de forma rápida y sencilla.
89 a 110: macros, para meter código que repetimos con frecuencia.
117: si seguimos la nomenclatura de Damian, todas las variables escalares que almacenan referencias, debemos llamarlas con un nombre que termina en '_ref'. Esta función nos coloreará aquellas zonas del programa en las que no estamos manejando bien esas variables.
123 a 132: le ponemos color a la fila y columna en donde estamos trabajando.
134 a 142: una parte importantísima: la gestión de los tabuladores, espacios e indentación automática del código.
144 a 148: colores para los menús desplegables, en el autocompletado de código.
150 a 157: macros especiales: ejecutar el código, depurar el código, formatear (con perltidy) el código.
159 a 165: activar modo de completado 'omnifunc' (una de las macros de Vim).

Ejemplo de uso:
Imagen

Observen el colorido de la columna actual, la del margen derecho, la de la fila actual, el resultado de la llave de cierre correspondiente a la llave en donde está ahora nuestro cursor, el resultado de las cadenas que se estaban buscando, y el resaltado de sintaxis propio del lenguaje.

P.D. La opción colorcolumn está disponible a partir de Vim 2.73.

Thomson_ · 2011-10-31 23:31 @021

Pero esta configuración se hace con un nuevo archivo, ¿o cómo?
Es que solo me aparecen dos archivos:

Citar:

/etc/vim# ls
vimrc vimrc.tiny

explorer · 2011-11-01 08:18 @387

Depende de cada sistema.

Por ejemplo, en el mío, al final de /etc/vimrc, están estas líneas:

Syntax: [ Download ] [ Hide ]

Using vim Syntax Highlighting

" Source a global configuration file if available

if filereadable("/etc/vimrc.local")

  source /etc/vimrc.local

endif

Es decir: vim usará el fichero /etc/vimrc global, para inicializarse, pero además, mira a ver si el usuario ha creado un fichero /etc/vimrc.local, con más personalizaciones, y si está, lo carga e interpreta.

Mira a ver si tú tienes las mismas líneas. O las pones y luego metes mi configuración en vimrc.local. O también puedes editar el vimrc global y añadir mi configuración al final (bueno... quizás no sea recomendable... pero, por probar, no se pierde nada).

Thomson_ · 2011-11-01 12:24 @558

El archivo vimrc tiene las líneas que tu indicas.
Funciona y queda excelente.

¡Gracias!

Publicidad

Socializa