Foro - Perl en Español

por **danusol** » 2011-02-09 06:12 @300

Hola.

Tengo un archivo con el siguiente formato
>GW156IX01BW18G length=114 xy=0669_2046 region=1 run=R_2011_02_01_18_40_56_
40 40 40 40 40 40 40 40 40 40 40 40 40 40 40 40 40 40 33 30 28 28 28 28
>GW156IX01AUUGH length=76 xy=0234_0799 region=1 run=R_2011_02_01_18_40_56_
40 40 40 40 40 40 40 40 40 39 40 27 26 16 16 16 26 29 14 26 21 21 21 21
>GW156IX01AOII3 length=113 xy=0162_0317 region=1 run=R_2011_02_01_18_40_56_
4 9 40 40 40 40 40 40 40 40 40 39 27 27 27 40 40 40 40 40 40 40
>GW156IX01BZQTZ length=72 xy=0700_0261 region=1 run=R_2011_02_01_18_40_56_
36 40 36 33 37 32 30 27 30 26 29 15 12 12 12 11 15 16 11 11 11 18 11 11 12

y me gustaría eliminar de cada fila de números los cuatro primeros números. Mi idea inicial era eliminar los doce primeros caracteres de cada línea (cuatro números de dos dígitos más su espacio posterior).

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

while (<IN>) {
  chomp;
  if (/^>/) { 
    print OUT $_,"\n";
    }
  else {
    $line=substr($_,12);
    print OUT $line,"\n";
 
    }
}
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

pero en algunos casos los números son de un dígito como podéis ver en negrita. y por tanto no funciona en esos casos. He pensado en eliminar contando espacios en blanco, de tal manera que me elimine todo hasta él incluyendo el cuarto espacio, pero ¿cómo puedo poner esto en código?

Gracias.

D.

#!/usr/bin/perl
use common::sense;
 
open IN,  q[<], 'kk.txt';
open OUT, q[>], 'kk.txt.out';
 
while (my $línea = <IN>) {
    given($línea) {
        when(/^>/) {
            print OUT $línea;
        }
        default {
            my(undef,undef,undef,undef,$resto_línea) = split " ", $línea, 5;
            print OUT $resto_línea;
        }
    }
}
 
close IN;
close OUT;
 
__END__
>GW156IX01BW18G length=114 xy=0669_2046 region=1 run=R_2011_02_01_18_40_56_
40 40 40 40 40 40 40 40 40 40 40 40 40 40 33 30 28 28 28 28
>GW156IX01AUUGH length=76 xy=0234_0799 region=1 run=R_2011_02_01_18_40_56_
40 40 40 40 40 39 40 27 26 16 16 16 26 29 14 26 21 21 21 21
>GW156IX01AOII3 length=113 xy=0162_0317 region=1 run=R_2011_02_01_18_40_56_
40 40 40 40 40 40 40 39 27 27 27 40 40 40 40 40 40 40
>GW156IX01BZQTZ length=72 xy=0700_0261 region=1 run=R_2011_02_01_18_40_56_
37 32 30 27 30 26 29 15 12 12 12 11 15 16 11 11 11 18 11 11 12
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Comentarios: usamos split() para que corte la $línea en cinco partes (cortando por los espacios en blanco). Las cuatro primeras son desechadas (asignadas a undef es lo mismo que tirarlas a la basura). Pero la quinta es lo que contiene la línea desde el quinto campo hasta el final, por lo que ahí tenemos el $resto_línea, que sacaremos fuera.

por **danusol** » 2011-02-09 09:41 @445

¡Fenomenal solución! Muchas gracias, explorer.

por **Leo_Gutierrez** » 2011-02-10 01:12 @092

Hola, solo por agregar, tal vez te sirva algo como esto:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

open(my $file, q[<], "file.txt") or die("Error abriendo archivo. $!");
open(my $salida, q[>], "salida.txt") or die $!;
 
while(<$file>)
{
        if(/^>/) {
                print $salida "\n$_";
        } else {
                print $salida (m/\d+\s\d+\s\d+\s\d+\s(.*)/);
        }
}
 
close($file);
close($salida);
 
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

o incluso:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

m/^>/ ? print $salida "\n$_" : print $salida (m/\d+\s\d+\s\d+\s\d+\s(.*)/) while(<$file>);
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Ah, cada vez me gusta más Perl

Saludos.

por **explorer** » 2011-02-10 05:22 @265

Ya te digo... creo que es la primera vez en mi vida que veo usar una expresión regular de esa manera...

Requiere un poco de explicación, para el neófito.

Una expresión regular, en contexto escalar, devuelve verdadero o falso, indicando si el patrón de búsqueda ha coincidido o no con la cadena de prueba. Pero, en contexto de lista, devuelve todos los elementos capturados por los paréntesis de captura.

En este caso, la cadena de prueba es la variable por defecto, $_, aunque no se vea. Y el contexto es de lista, gracias a los paréntesis que rodean a la expresión regular.

Los paréntesis devuelven todos los elementos capturados, que en este caso solo es uno (el resto de la línea a partir de la quinta columna), así que lo que recibe print() no es un escalar (un trozo de cadena), sino una lista de valores compuesto por un único valor, que es el trozo de cadena.

Bueno, el caso es que obtenemos lo que queremos, aunque de forma poco común. Pero válida.

Solo comentar, finalmente, que se puede reescribir esa expresión regular a algo como esto: m/(?:\d+\s+){4}(.*)/. El '(?:...)' indica sólo agrupamiento, no captura. Y el '{4}' indica el número de repeticiones de lo que le precede.

por **Leo_Gutierrez** » 2011-02-10 11:49 @534

explorer escribiste:Ya te digo... creo que es la primera vez en mi vida que veo usar una expresión regular de esa manera...

No sé si eso es bueno o malo.

Sé que la sentencia es algo críptica o algo difícil de leer, y claro, no es recomendable usarla pero solo la uso para aprender. Un amigo programador me recomendó que tratara de usar éstas solo por aprender, porque frecuentemente son las que exigen más análisis.

explorer escribiste:Solo comentar, finalmente, que se puede reescribir esa expresión regular a algo como esto: m/(?:\d+\s+){4}(.*)/. El '(?:...)' indica sólo agrupamiento, no captura. Y el '{4}' indica el número de repeticiones de lo que le precede.

No sabía que se pudieran usar así, sin duda queda más bonito.

Saludos.

Foro - Perl en Español

Contar espacios y eliminar

Contar espacios y eliminar

Publicidad

Re: Contar espacios y eliminar

Re: Contar espacios y eliminar

Re: Contar espacios y eliminar

Re: Contar espacios y eliminar

Re: Contar espacios y eliminar

¿Quién está conectado?