Foro - Perl en Español

por **jairo15** » 2016-11-10 10:27 @477

En una matriz de n × n, ¿cómo puedo detectar e imprimirlos?

Por ejemplo que quede así: 1 1 2, siendo esos números espacios NO vacíos, que es así: 1 espacio en uso, espacio vacío, espacio en blanco, luego 2 espacios en uso.

Siendo esto una variación, ya que son aleatorios los espacios usados.

Espero haberme explicado bien.

El siguiente programa resuelve el problema, resolviendo primera para las filas, y luego resolviendo para las columnas, previo cálculo de la transformada de la matriz (esto no siempre se puede hacer según el tamaño de la matriz en memoria).

El procesamiento de cada fila (y columna) se realiza buscando conjuntos de caracteres que no sean "X".

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/env perl
use v5.22;
use experimental 'signatures';
 
## PROGRAMA
# Leemos la matriz
my @matriz;
 
while (my $linea = <DATA>) {
    chomp $linea;
    next if not $linea;
 
    push @matriz, [ split " ", $linea ];
}
 
use Data::Dump;
dd @matriz;
 
# Cálculo de las filas
# recorremos las filas, las convertimos a cadenas, y le pasamos una expresión regular que busca lo que queremos
say "Resultado por filas";
for my $fila_array_ref (@matriz) {
    say procesa_fila(@$fila_array_ref);
}
 
# Cálculo de la transpuesta de la matriz
# recorremos toda la matriz, creando una transpuesta
my @matriz_transpuesta;
 
for my $fila_array_ref (@matriz) {
    while (my($f, $v) = each @$fila_array_ref) {
        push @{ $matriz_transpuesta[$f] }, $v;
    }
}
 
dd @matriz_transpuesta;
 
# Cálculo de las columnas
say "Resultado por columnas";
for my $columna_array_ref (@matriz_transpuesta) {
    say procesa_fila(@$columna_array_ref);
}
 
 
 
## SUBRUTINAS
# procesa una fila de elementos
sub procesa_fila(@elementos) {
    my $fila = join '' => @elementos;
 
    my @resultado;
 
    while ($fila =~ /[^X]+/g) {                 # buscamos, de forma repetida, conjuntos de caracteres que no sean "X"
        push @resultado, length $&;             # el resultado es la longitud de esos conjuntos
    }
 
    return $fila, "  ", join " " => @resultado;
}
 
## DATOS
__DATA__
H X X O X
X L X X A
C O X X M
O X E S X
T A S X X
Coloreado en 0.005 segundos,  usando GeSHi 1.0.8.4

El resultado es:

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

(

  ["H", "X", "X", "O", "X"],

  ["X", "L", "X", "X", "A"],

  ["C", "O", "X", "X", "M"],

  ["O", "X", "E", "S", "X"],

  ["T", "A", "S", "X", "X"],

)

Resultado por filas

HXXOX  1 1

XLXXA  1 1

COXXM  2 1

OXESX  1 2

TASXX  3

(

  ["H", "X", "C", "O", "T"],

  ["X", "L", "O", "X", "A"],

  ["X", "X", "X", "E", "S"],

  ["O", "X", "X", "S", "X"],

  ["X", "A", "M", "X", "X"],

)

Resultado por columnas

HXCOT  1 3

XLOXA  2 1

XXXES  2

OXXSX  1 1

XAMXX  2Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

Foro - Perl en Español

Detectar espacios en blanco en una matriz

Detectar espacios en blanco en una matriz

Publicidad

Re: Detectar espacios en blanco en una matriz

Re: Detectar espacios en blanco en una matriz

Re: Detectar espacios en blanco en una matriz

¿Quién está conectado?