Foro - Perl en Español

por **MARKO** » 2015-11-25 20:05 @879

Saludos, Perl en Español, de nuevo por acá con una duda.

Tengo 4 tipos de archivos:

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

WEB13112015.xls ----------> programación diaria

WEB06062015R1_1201.xls ---> reprogramación diaria No.1

WEB07062015R2_0301.xls ---> reprogramación diaria No.2

WEB07062015R3_1101.xls ---> reprogramación diaria No.3

WEB23112015V1.xls --------> nueva versión de programación No.1

WEB23112015V2.xls --------> nueva versión de programación No.2

WEB23112015V3.xls --------> nueva versión de programación No.3

25_PDS20150614.xls -------> programación semanal

25_PDSREP20150614.xls ----> reprogramación semanalColoreado en 0.000 segundos,  usando GeSHi 1.0.8.4

Elaboraré un sistema para analizar los diferentes tipos de archivo y quisiera ideas de cómo identificar a través de expresiones regulares cada tipo de archivo en base a su nombre para luego llamar a una rutina (que yo elaboraré) encargada de analizar cada tipo de archivo.

El resultado que me gustaría tener es en una $variable el resultado del análisis del nombre. Por ejemplo:

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

$variable = programación diaria

$variable = reprogramación diaria No.2

$variable = nueva versión No.3

$variable = programación semanal

$variable = reprogramación semanalColoreado en 0.000 segundos,  usando GeSHi 1.0.8.4

Quisiera algunas ideas.

Para empezar, creo que la forma de hacerlo sería con expresiones regulares y conteo de caracteres.

¿¿¿Ideas???

Gracias por adelantado.

#!/usr/bin/env perl
use v5.22;
use feature 'switch';
no warnings 'experimental';
use utf8::all;
 
my @pruebas = qw(
    WEB13112015.xls
    WEB06062015R1_1201.xls
    WEB07062015R2_0301.xls
    WEB07062015R3_1101.xls
    WEB23112015V1.xls
    WEB23112015V2.xls
    WEB23112015V3.xls
    25_PDS20150614.xls
    25_PDSREP20150614.xls
);
 
# gramática
my $extensión  = qr/[.] xls                    /x;
my $fecha       = qr/\d{8}                      /x;
my $diario      = qr/WEB $fecha                 /x;
my $reprograma  = qr/R (?<repro>  \d) _ \d{4}   /x;
my $versión    = qr/V (?<version>\d)           /x;
my $semanal     = qr/25_PDS    $fecha           /x;
my $re_semanal  = qr/25_PDSREP $fecha           /x;
 
my %regexes = (
    'programación diaria'              => qr/^ $diario             $extensión $/x,
    'reprogramación diaria'            => qr/^ $diario $reprograma $extensión $/x,
    'nueva versión de programación'   => qr/^ $diario $versión    $extensión $/x,
    'programación semanal'             => qr/^ $semanal            $extensión $/x,
    'reprogramación semanal'           => qr/^ $re_semanal         $extensión $/x,
);
 
for my $prueba (@pruebas) {
    keys %regexes;
    while ( my ( $nombre, $regex ) = each %regexes ) {
        if ( $prueba =~ $regex ) {
            for ($nombre) {
                when ('reprogramación diaria') {
                    $nombre .= " Nº $+{repro}";
                }
                when ('nueva versión de programación') {
                    $nombre .= " Nº $+{version}";
                }
            }
            say "$prueba => $nombre";
            last;
        }
    }
}
 
__END__
Coloreado en 0.003 segundos,  usando GeSHi 1.0.8.4

La salida es:

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

WEB13112015.xls => programación diaria

WEB06062015R1_1201.xls => reprogramación diaria Nº 1

WEB07062015R2_0301.xls => reprogramación diaria Nº 2

WEB07062015R3_1101.xls => reprogramación diaria Nº 3

WEB23112015V1.xls => nueva versión de programación Nº 1

WEB23112015V2.xls => nueva versión de programación Nº 2

WEB23112015V3.xls => nueva versión de programación Nº 3

25_PDS20150614.xls => programación semanal

25_PDSREP20150614.xls => reprogramación semanalColoreado en 0.000 segundos,  usando GeSHi 1.0.8.4

Esta es otra opción:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/env perl
use feature 'say';
 
my @pruebas = qw(
    WEB13112015.xls
    WEB06062015R1_1201.xls
    WEB07062015R2_0301.xls
    WEB07062015R3_1101.xls
    WEB23112015V1.xls
    WEB23112015V2.xls
    WEB23112015V3.xls
    25_PDS20150614.xls
    25_PDSREP20150614.xls
);
 
my $variable;
 
for my $prueba (@pruebas) {
 
    if ($prueba
           =~   /
                ^                                       # inicio de texto
                (?:
                    (?<semanal>25_PDS(?<repsem>REP)?)   # semanal
                    |                                   # o
                    WEB                                 # diario
                )
                \d{8}                                   # fecha
                (?:
                    R(?<repdia>\d) _ \d{4}              # reprogramación
                    |                                   # o
                    V(?<version>\d)                     # version
                    |                                   # o nada
                )
                [.] xls                                 # extensión
                $                                       # fin de texto
                /x
    ) {
        if ($+{'semanal'}) {
            $variable = 'programación semanal';
            if ($+{'repsem'}) {
                $variable = "re$variable";
            }
        }
        elsif ($+{'repdia'}) {
            $variable = "reprogramación diaria Nº $+{'repdia'}";
        }
        elsif ($+{'version'}) {
            $variable = "nueva versión de programación Nº $+{'version'}";
        }
        else {
            $variable = "programación diaria";
        }
 
        say "$prueba => $variable";
    }
}
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

Foro - Perl en Español

Expresión regular para manejar nombre de archivos

Expresión regular para manejar nombre de archivos

Publicidad

Re: Expresión regular para manejar nombre de archivos

¿Quién está conectado?