Foro - Perl en Español

        1 #!/usr/bin/perl
        2 #
        3 # Extractor de administraciones de la Lotería Nacional,
        4 # a partir de una serie de números, desde la página oficial.
        5 #
        6 # Joaquín Ferrero. Diciembre 2007.
        7
        8 use WWW::Mechanize;
        9 use HTML::TableExtract;
       10
       11 use strict;
       12 use warnings;
       13
       14 $|++; # no caché
       15
       16 # Constantes ################################################################
       17 my $URL = 'http://onlae.terra.es/loteria/navidad07/PrincipalD.htm';
       18 my $fichero_de_salida = 'administraciones.txt';
       19
       20 #############################################################################
       21
       22 # Vemos si el usuario nos manda un argumento, o le informamos
       23 # de cómo funciona este programa
       24 # Hay dos formas de indicarlo: o números sueltos, separados por comas,
       25 # y/o un rango, separados por '..'.
       26 @ARGV or die "Uso: $0 [<número[,número,...]|<número>..<número>]\n";
       27
       28 # Leemos los números indicados por el usuario
       29 my $numeros_a_buscar = shift @ARGV;
       30
       31 # Lo evaluamos como una posible lista de números
       32 my @numeros_a_buscar = eval ($numeros_a_buscar);
       33
       34 # Hacemos un bucle por todos ellos
       35 foreach my $numero ( @numeros_a_buscar ) {
       36     next if $numero > 84999;                    # Límites de números permitidos
       37     next if $numero < 0;
       38
       39     obtener_datos_del($numero);
       40
       41     sleep 3 + rand 3
       42         if $numero != $numeros_a_buscar[-1];    # Somos amables... esperamos
       43 }
       44
       45 sub obtener_datos_del {
       46     my $numero = shift;
       47
       48     print "Obteniendo información del número $numero...";
       49
       50     my $mech = WWW::Mechanize->new();           # Nuestro robot
       51     $mech->agent_alias('Linux Mozilla');        # Vamos a despistar un poco
       52
       53     $mech->get($URL)
       54         or die "ERROR: No me pude conectar al $URL\n";
       55
       56     $mech->submit_form(                         # Solicitamos información
       57         with_fields => {'numero' => $numero},
       58     );
       59
       60     $mech->success()                            # ¿Todo va bien?
       61         or die "ERROR: No pude hacer la petición para el número $numero\n";
       62
       63     my $pagina = $mech->content();              # A ver qué tenemos...
       64
       65     # Nos construímos el extractor de tablas y buscamos la que nos interesa
       66     my $tabla_extractor
       67         = HTML::TableExtract->new(
       68             headers => [qw(Admon. Domicilio Localidad Provincia Teléfono)],
       69         );
       70     $tabla_extractor->parse($pagina);           # Adelante... parsea...
       71
       72     my ($tabla) = $tabla_extractor->tables()    # Tabla obtenida
       73         or die "ERROR: No encontré la tabla de Administraciones\n";
       74
       75     # Extraemos información de la tabla
       76     # Y la guardamos en el fichero de salida
       77     open ADMON,">>$fichero_de_salida"
       78         or die "ERROR: No puedo añadir a $fichero_de_salida: $!\n";
       79
       80     # Primero, una cabecera
       81     print ADMON "Administraciones con el número $numero:\n";
       82
       83     # Luego, la información de la tabla
       84     foreach my $row ($tabla->rows) {
       85         print ADMON join(',', @$row), "\n";
       86     }
       87
       88     close ADMON;
       89
       90     print " Ok\n";
       91 }
       92
       93 __END__

#!/usr/bin/perl

use HTTP::Request::Common qw(POST);
use LWP::UserAgent;

my $ua = LWP::UserAgent->new(
            agent => 'Mozilla/5.0 (X11; U; Linux i686; es-ES; rv:1.8.1.8) Gecko/20071015 SUSE/2.0.0.8-1.1 Firefox/2.0.0.8',
);

my $matricula = '1253-BCN';

my $req = POST
            'http://www.juntadeandalucia.es/economiayhacienda/apl/surweb/dwr/call/plaincall/ProxyDWR.invocarPorReflexion.dwr',
            Content_Type => 'text/plain',
            Content      => <<"EOF",
callCount=1
page=/economiayhacienda/apl/surweb/modelos/modelo621/621.jsp
httpSessionId=0ae2803530d90efa31d72dc24a68aff2f815336f489f.e38Ob38NahaLbi0LbhqSb3iRcheRe0
scriptSessionId=96DA3B6AB5E867109CF9AF7A7D6DBD93892
c0-scriptName=ProxyDWR
c0-methodName=invocarPorReflexion
c0-id=0
c0-param0=string:dgt.AjaxDGT.devolverDatosMatriculacion
c0-e1=string:$matricula
c0-param1=Array:[reference:c0-e1]
batchId=14
EOF
            ;

$req->header(
    'Accept'            => 'text/xml,application/xml,application/xhtml+xml,text/html;q=0.9,text/plain;q=0.8,image/png,*/*;q=0.5',
    'Accept-Language'   => 'es,es-es;q=0.8,en;q=0.5,en-us;q=0.3',
    'Accept-Charset'    => 'ISO-8859-1,utf-8;q=0.7,*;q=0.7',
    'Keep-Alive'        => 300,
    'Connection'        => 'keep-alive',
    'Content-Type'      => 'text/plain',
    'Referer'           => 'http://www.juntadeandalucia.es/economiayhacienda/apl/surweb/modelos/modelo621/621.jsp',
    'Cookie'            => 'JSESSIONID=0ae2803530d90efa31d72dc24a68aff2f815336f489f.e38Ob38NahaLbi0LbhqSb3iRcheRe0',
    'Pragma'            => 'no-cache',
    'Cache-Control'     => 'no-cache',
);

my $respuesta = $ua->request($req)->as_string;

#print $respuesta,"\n";

if ( (my $datos) = $respuesta =~ m/\{(.*)\}/ ) {

    foreach ( split q{,}, $datos ) {
        my ($tipo, $valor) = split q{:};
        printf "%-22s %s\n", $tipo, $valor;
    }

}
else {
    print "No hubo respuesta\n";
}