Foro - Perl en Español

por **sisifo80** » 2014-09-23 03:29 @187

Hola.

Estoy intentando hacer un script que realice ciertas modificaciones en varios XML. Se trata de eliminar ciertas etiquetas que aparecen dentro de la etiqueta <text>. Pero solo necesito eliminarlas cuando aparecen dentro de la etiqueta <text>. He intentado lo siguiente:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

opendir IN, 'input';
my @in = grep {/^[^.]/} readdir IN;
closedir IN;
 
for my $in (@in) {
    open IN,  '<', "input/$in"  || next;
    open OUT, '>', "output/$in" || die "can't open file output/$in";
    $/ = undef;
 
    $file = <IN>;
 
    while ( $file =~ /<text id.*?>(.*?)<\/text>/gsmi ) {
 
        $text = $1;
 
        $text =~ s/<name>//g;
        $text =~ s/<\/name>//g;
        $text =~ s/<placeName>//g;
        $text =~ s/<\/placeName>//g;
        $text =~ s/<note n="contraction">(.*?)<\/note>/$1/g;
 
    }
    print OUT $file;
 
    close OUT;
    close IN;
}
 
Coloreado en 0.004 segundos,  usando GeSHi 1.0.8.4

Mi problema es que el resultado que obtengo es el mismo que tenía en el archivo input, es decir, no se aplican las modificaciones que quiero. Si cambio la línea final de "print" por "print OUT $text" sí que se aplican las modificaciones, pero no obtengo todo el archivo input sino sólo la parte de <text>. Resumiendo:

a) puedo imprimir todo el input intacto
b) puedo imprimir la parte de <text> con las modificaciones

¿Cómo puedo imprimir todo el input con las modificaciones?

¡Gracias!

#!/usr/bin/perl
use autodie;
 
open IN,  '<', "entrada.txt";
open OUT, '>', "salida.txt";
$/ = undef;
 
my $file = <IN>;
 
while ( $file =~ /<text id.*?>(.*?)<\/text>/gsmi ) {
 
    my $text = $1;
    my $text_inicio = $-[1];
    my $text_final  = $+[1];
 
    $text =~ s/<name>//g;
    $text =~ s/<\/name>//g;
    $text =~ s/<placeName>//g;
    $text =~ s/<\/placeName>//g;
    $text =~ s/<note n="contraction">(.*?)<\/note>/$1/g;
 
    substr($file, $text_inicio, $text_final - $text_inicio) = $text;
    pos($file) = $text_inicio + length $text;
 
}
print OUT $file;
 
close OUT;
close IN;
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

Además de sacar $text, definimos dos variables más, en las que guardamos las posiciones iniciales y finales de esa captura.

Luego hacemos las modificaciones.

Y finalmente, con la ayuda de substr() "metemos" el nuevo $text dentro de $file, ajustando el tamaño (la longitud de lo extraído se ajusta al nuevo contenido).

Luego, con pos(), ajustamos la posición que usa el motor de expresiones regulares, para que comience la siguiente búsqueda justo donde hemos terminado el nuevo $text. Esto hay que hacerlo porque, al cambiar la longitud total de $file, si iniciáramos la siguiente vuelta de búsqueda, podríamos estar haciéndolo pasado el comienzo de un <text>, así que no lo detectaríamos. Por eso, colocamos el puntero justo donde hemos terminado (mejor dicho: colocamos el puntero justo delante del último </text>, pero no importa, porque el patrón buscará el siguiente <text>).

por **sisifo80** » 2014-09-23 04:54 @245

Ok. Ya entiendo por qué no era capaz de imprimir como yo quería. Efectivamente, la cosa era menos sencilla de lo que yo creía. Había que jugar con la posición inicial y final de mi captura. Tu explicación es muy clara. ¡Gracias, explorer!

Foro - Perl en Español

Imprimir resultado con modificaciones

Imprimir resultado con modificaciones

Publicidad

Re: Imprimir resultado con modificaciones

Re: Imprimir resultado con modificaciones

¿Quién está conectado?