Foro - Perl en Español

por **MARKO** » 2012-07-02 13:10 @590

Saludos, Perl en Español.

Necesito ordenar el siguiente hash de horas->precio:

: sin orden.png (7.59 KiB) Visto 884 veces

(el ingreso es 1->precio, 2->precio, 3->precio y así sucesivamente pero al imprimir el hash sale en el orden mostrado.

Curioseando en el foro me fui hacia un articulo que Uds. recomendaron y escribí esto:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

foreach my $hora( sort ordenar_por_valor keys %precio) {
  my $valor = $precio{$hora};
  print "$hora => $valor\n";
}
 
sub ordenar_por_valor {
  return $precio{$a} <=> $precio{$b};
}
 
Coloreado en 0.003 segundos,  usando GeSHi 1.0.8.4

el cual nos da el siguiente resultado:

: orden parcial.png (10.06 KiB) Visto 884 veces

Como podrán ver, la hora (1,2,3,4,5,24) tienen el precio menor y las horas (19, 20, 21 y 22) tienen el precio mayor.

A mi solo me interesa el precio menor y el mayor pero con la primera hora con que apareció algo así:

%precio [
1 = > 140.65300329,
2 = > 140.65300329,
3 = > 140.65300329,
4 = > 140.65300329,
5 = > 140.65300329,
24 = > 140.65300329,
.
.
.
.
19 = > 167.96513356
20 = > 167.96513356
21 = > 167.96513356
22 = > 167.96513356
]

simplemente es coincidencia que el precio menor haya quedado en las primeras horas y el mayor en las últimas, podría haber sucedido en cualquier hora del día pero lo que me interesa es que se ordenen primeramente por el precio y luego por su llave.

¿Tengo el enfoque correcto o sería mejor meterlo en un arreglo y hacer el proceso "burbuja" para ordenar? ¿Ideas?

Gracias por adelantado.

De esa manera, estamos primero comparando -numéricamente y por orden ascendente- por el precio, y en el caso de igualdad de precio, el orden lo define la comparación -también numéricamente y por orden ascendente- de los valores de las claves (las horas).

Otra opción: como solo hay un precio por hora, podrías haber usado un array, y te ahorrabas algo de código.

Edito: hummm, quizás no te ahorras tanto código como yo creía.

por **MARKO** » 2012-07-02 16:59 @749

Gracias por tu pronta respuesta.

Probé con el código que recomiendas, el orden cambió un poco pero no es el óptimo. Además aparecen muchas líneas de advertencia de error "odd number of elements in anonymous hash":

: OTRO ORDEN.png (21.69 KiB) Visto 852 veces

¿Qué me recomiendas hacer si solo me interesa obtener el valor mínimo y la primera hora a la que este valor ocurrió y lo mismo para el valor máximo; el valor máximo y la primera hora a la que este valor ocurrió?

Las demás horas y precios pueden ser obviadas.

Otra opción: como solo hay un precio por hora, podrías haber usado un array, y te ahorrabas algo de código.

¿Método de ordenamiento burbuja o qué me recomiendas? De que no es menos código estoy seguro.

Gracias por adelantado.

por **explorer** » 2012-07-03 01:30 @104

Por favor, no publiques volcados gráficos. Copia y pega siempre texto. Veo que es una consola de MSDOS, y sí que puedes copiar ese texto, con el ratón.

MARKO escribiste:Probé con el código que recomiendas, el orden cambió un poco pero no es el óptimo. Además aparecen muchas líneas de advertencia de error "odd number of elements in anonymous hash":
OTRO ORDEN.png

Sin ver un código de ejemplo, es difícil decir qué pasa.
El mensaje de error dice que el hash tiene un número impar de elementos, así que se te está colando algún elemento, o pones un elemento de más, o algo así.

MARKO escribiste:¿Qué me recomiendas hacer si solo me interesa obtener el valor mínimo y la primera hora a la que este valor ocurrió y lo mismo para el valor máximo; el valor máximo y la primera hora a la que este valor ocurrió?

Es muy sencillo: ordenas el hash como te indiqué, y luego solo hay que leer el primer par y el último par.

MARKO escribiste:¿Método de ordenamiento burbuja o qué me recomiendas?

Nada, no hay que hacer nada de eso. Con ordenarlo una vez, vale.

Edito: Este es un ejemplo:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/env perl
use v5.14;
 
my %precios = (
    1   => 140.65,
    2   => 140.65,
    3   => 140.65,
    4   => 140.65,
    5   => 140.65,
    6   => 150.27,
    7   => 154.12,
    8   => 163.73,
    9   => 162.60,
    10  => 154.12,
    11  => 154.12,
    12  => 154.12,
    13  => 154.12,
    14  => 163.73,
    15  => 163.73,
    16  => 163.73,
    17  => 163.73,
    18  => 163.73,
    19  => 167.97,
    20  => 167.97,
    21  => 167.97,
    22  => 167.97,
    23  => 150.27,
    24  => 140.65,
);
 
my @horas_ordenadas = sort { $precios{$a} <=> $precios{$b} || $a <=> $b } keys %precios;
 
for (@horas_ordenadas) {
    say "$_ => $precios{$_}";
}
 
my $hora_precio_mas_bajo = 0;
my $hora_precio_mas_alto = $#horas_ordenadas;
 
while ($hora_precio_mas_alto > 0) {                     # encontrar la primera hora con precio más alto
    last if $precios{$horas_ordenadas[$hora_precio_mas_alto-1]} != $precios{$horas_ordenadas[-1]};
 
    $hora_precio_mas_alto--;
}
 
say "Precio más bajo: $precios{$horas_ordenadas[$hora_precio_mas_bajo]}";
say "Primera hora con ese precio: $horas_ordenadas[$hora_precio_mas_bajo]";
say "Precio más alto: $precios{$horas_ordenadas[$hora_precio_mas_alto]}";
say "Primera hora con ese precio: $horas_ordenadas[$hora_precio_mas_alto]";
 
__END__
1 => 140.65
2 => 140.65
3 => 140.65
4 => 140.65
5 => 140.65
24 => 140.65
6 => 150.27
23 => 150.27
7 => 154.12
10 => 154.12
11 => 154.12
12 => 154.12
13 => 154.12
9 => 162.6
8 => 163.73
14 => 163.73
15 => 163.73
16 => 163.73
17 => 163.73
18 => 163.73
19 => 167.97
20 => 167.97
21 => 167.97
22 => 167.97
Precio más bajo: 140.65
Primera hora con ese precio: 1
Precio más alto: 167.97
Primera hora con ese precio: 19
Coloreado en 0.003 segundos,  usando GeSHi 1.0.8.4

por **MARKO** » 2012-07-05 13:57 @623

Perfecto, explorer, me ayudaste muchísimo.

Muchísimas gracias.

Foro - Perl en Español

Ordenando un hash por sus valores y por sus llaves

Ordenando un hash por sus valores y por sus llaves

Publicidad

Re: Ordenando un hash por sus valores y por sus llaves

Re: Ordenando un hash por sus valores y por sus llaves

Re: Ordenando un hash por sus valores y por sus llaves

Re: Ordenando un hash por sus valores y por sus llaves

¿Quién está conectado?