Foro - Perl en Español

por **dbustos** » 2012-04-03 14:01 @625

Hola de nuevo.

Necesito reordenar un archivo de la siguiente manera:
Archivo original

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

A,B,5,6

A,C,8,9

A,F,52,4

B,C,5,6Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

rearreglo por campo primero:

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

A,B,5,6,C,8,9,F,52,4

B,C,5,6Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

El script que tengo hasta ahora es:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use strict;
use warnings;
 
### Cabecera
open my $OUTPUT, '>>', 'beta_doms.out';
 
### Leer el primer archivo
open my $ARQ, '<', "beta_arch_unip.out" or die "can not open the file $ARGV[0]";
my @arq = <$ARQ>;
 
close $ARQ;
 
### Leer el segundo archivo
open my $LIST, '<', "beta_arch_unip.out" or die "can not open the file $ARGV[1]";
my @list = <$LIST>;
close $LIST;
 
### Comparación
for my $lastline (@arq) {              # para todas las líneas del primer archivo
 
    for my $thisline (@list) {         # para todas las líneas del segundo archivo
 
        my ( $NP1, $dom1, $I1, $F1 ) = split /,/, $thisline;
        my ( $NP2, $dom2, $I2, $F2 ) = split /,/, $lastline;
 
        if (    $NP1 eq $NP2
            and $I1 ne $I2
            and $F1 ne $F2 ) {
            print $OUTPUT join( "\,", $NP1, $dom1, $I1, $F1, $dom2, $I2, $F2, "\n" );
        }
    }
}
 
close $OUTPUT;
 
Coloreado en 0.003 segundos,  usando GeSHi 1.0.8.4

pero solo me sirve para dos filas iguales y no si hay tres o más filas con igual campo primero.

Desde ya, muchas gracias.

#!/usr/bin/perl
use strict;
use warnings;
use autodie;
 
my %archivo;                                            # Nueva versión del archivo
 
open my $archivo, '<', 'beta_arch_unip.out';            # Leemos el archivo
 
while (my $linea = <$archivo>) {                        # Miramos todas las líneas
    chomp $linea;                                       # Quitamos los finales de línea
    my($primer_campo, $resto) = split /,/, $linea, 2;   # Partimos la línea en dos cachos
    next if not $primer_campo;                          # Saltamos las líneas vacías
    #print "[$primer_campo][$resto]\n";
 
    push @{$archivo{$primer_campo}}, $resto;            # Guardamos según el $primer_campo
}
 
close $archivo;
 
open my $salida, '>', 'beta_doms.out';
for my $campo (sort keys %archivo) {                    # Sacamos ordenado por los primeros campos
    print $salida join(',', $campo, @{$archivo{$campo}}), "\n";    # El $campo, y sus valores correspondientes
}
close $salida;
 
__END__
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

El trabajo que hacemos es leer línea por línea; de cada una de ellas, le quitamos los caracteres de fin de línea, ya que no nos sirven para nada; partimos la línea en dos partes según la primera coma; la primera parte será nuestro $primer_campo, que nos servirá de clave hash para guardar (push) el $resto, en un array que estará apuntado por el valor asociado a esa clave. En otras palabras, estamos creando una estructura hash de arrays.

Ya solo queda hacer la salida, haciendo un recorrido ordenado por las claves que hemos ido recolectando; por cada una de ellas, la imprimimos, junto con una coma, y la unión de todos los "restos" de línea acumulados en el array asociado.

Bueno, esta es una manera de hacerlo. Hay otras muchas.

por **dbustos** » 2012-04-04 07:50 @368

¡¡¡Muchas gracias!!!

por **explorer** » 2012-04-04 10:05 @461

Si algo no entiendes, pregunta.

Más información -en tu propio ordenador- en perldoc perllol (Web) (traducido).

Foro - Perl en Español

Ordernar archivo

Ordernar archivo

Publicidad

Re: Ordernar archivo

Re: Ordernar archivo

Re: Ordernar archivo

¿Quién está conectado?