Foro - Perl en Español

por **cmp** » 2009-07-23 12:08 @547

Hola a todos.

Estoy escribiendo un script para poder crear subdominios de forma automática así como un pequeño espacio web.

No tengo muy claro si va a Avanzado...

La idea es la siguiente: un usuario del sitio, con solo rellenar un formulario con el nombre del subdominio deseado y su e-mail tenga listo en un momento su subdomino.

De Perl se lo justo y de momento tengo esto:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use strict;
use File::Copy;
 
#perl genera_dominio.pl  NOMBRE_SUBDOMINIO  E-MAIL
 
my $nom_dom = $ARGV[0]; #p.e. nom que el usuario quiere para subdominio
my $sites_apache = "/etc/apache2/sites-available"; la
my $ruta = "$sites_apache/$nom_dom"; 
my $mail = $ARGV[1]; #recogemos el e-mail del usuario
my $dominio = "www.$nom_dom.dominio.com";
my $ubicacion = "/var/www/$nom_dom";
my $log_error = "/var/log/apache2/error_$nom_dom.log";
my $log_custom = "/var/log/apache2/access_$nom_dom.log";
 
#Creamos el nuevo fichero de configuración
#Comprobamos que no exista ya
if (-e "$sites_apache/$nom_dom") {
    print "El nombre de subdominio $nom_dom ja existe ! \n";
} 
else { 
  
  #Tenemos una plantilla con los valores clave a cambiar
  copy("$sites_apache/plantilla", "$sites_apache/$nom_dom") or die "No se pudo copiar el fichero: $!";
 
  #Colocar valor de escape delante de '@' para que funcione bien
  #valor a sustituir =~ s/patrón de búsqueda/patrón de sustitución/opciones 
  my $mail_arroba = "$mail";
  $mail_arroba =~ s/@/\\@/;
  
  #Buscamos los valores a sustituir en el fichero /etc/apache2/sites-available/$nom_dom
  system("perl -p -i -e 's/EMAIL/$mail_arroba/g;' $ruta");
  system("perl -p -i -e 's/DOMINIO/$dominio/g;' $ruta");
  system("perl -p -i -e 's {UBICACION} {$ubicacion}g;' $ruta");
  system("perl -p -i -e 's {LOG_ERROR} {$log_error}g;' $ruta");
  system("perl -p -i -e 's {LOG_CUSTOM} {$log_custom}g;' $ruta");
 
  #Añadimos el subdominio en /etc/hosts para simular DNS a nivel local
  system("perl -p -i -e 's/#AÑADIR_DOM_AQUI/$dominio #AÑADIR_DOM_AQUI/;' /etc/hosts");
 
  #Activamos (enable) el nuevo Vhost
  system("cd $sites_apache");
  system("sudo a2ensite $nom_dom");
 
  #Creamos el directorio para el nuevo site
  mkdir "/var/www/$nom_dom", 0755 or warn"No se pudo crear el directorio: $!";
  #Creamos un index.html para que se muestre algo hasta que el usuario ponga su contenido
  open(fd,">/var/www/$nom_dom/index.html") or die "No se pudo crear el fichero index.html\n";   
  print fd "<title>$dominio</title> <html>Espacio web $nom_dom</html>";
  close(fd);
 
  #Reiniciamos apache para que los cambios tengan efecto
  system("sudo /etc/init.d/apache2 reload");
 
  #Para las pruebas
  print "\n-------------------\nSe creó el dominio $dominio con exito! \n";
  print "Correo electronico: $mail \n";
  print "El log de errores : $log_error \n";
  print "El log de accesos : $log_custom \n-------------------\n";
Coloreado en 0.004 segundos,  usando GeSHi 1.0.8.4

Como podéis ver utilizo la técnica de buscar patrones en una plantilla prediseñada para poner los datos adecuados para cada usuario. No sé si hay alguna forma más elegante o eficaz pero no se me ha ocurrido...

¿Es una buena opción hacerlo en Perl?

Me gustaría que me dierais vuestra opinión y cosas a mejorar/cambiar, etc... o directamente si es una barbaridad XD

Unos comentarios rápidos...

* Te recomiendo la lectura del módulo Text::Template. Vete a la parte de la descripción, al ejemplo que trae. Verás que el uso de plantillas simplifica bastante tu código y te ahorra todas las llamadas "perl -p -i -e".

* Para añadir un dominio al final de un fichero de texto, te vale con abrir el fichero en modo añadir ('>>'). Si, en cambio estás añadiendo en una determinada línea, el uso de Tie::File permite mapear el fichero de texto a un arreglo, con lo que localizar, cambiar y grabar la línea es muy sencillo (5 líneas). A cambio, te ahorras otra llamada a un proceso externo, que siempre es algo muy costoso para el sistema operativo.

* De la parte

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

system("cd $sites_apache");
system("sudo a2ensite $nom_dom");Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Puedes simplificarlo a

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

system("cd $sites_apache ;sudo a2ensite $nom_dom");Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

pero da el caso que a a2ensite le da igual dónde estés ejecutándolo, así que al final queda

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

system("sudo a2ensite $nom_dom");Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Ahora bien... ¿qué es lo que hace a2ensite? Pues, aparte de unos controles, solo esto:

Sintáxis: [ Descargar ] [ Ocultar ]

Using bash Syntax Highlighting

ln-sf$SYSCONFDIR/sites-available/$SITENAME$SYSCONFDIR/sites-enabled/$SITENAMEColoreado en 0.002 segundos,  usando GeSHi 1.0.8.4

es decir, un enlace simbólico entre el directorio de sites-available y sites-enabled. Finalmente, pide al usuario que haga un reload del Apache. O sea, que lo puedes hacer todo desde Perl: el enlace simbólico lo puedes hacer con la función symlink(). Y el reload, con un system().

Recuerda: si estás llamando a perl dentro de perl, es que estás haciendo algo mal.

Y cualquier llamada con system(), es costosa.

por **cmp** » 2009-07-24 07:45 @364

Muchísimas gracias por todos los consejos y correcciones.

Recuerda: si estás llamando a perl dentro de perl, es que estás haciendo algo mal.

¡Esto me lo apunto!
El código ha quedado mucho más elegante y eficiente, la verdad:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use strict;
use File::Copy;
use Text::Template;
use Tie::File;
 
#perl genera_dominio.pl  NOMBRE_SUBDOMINIO  E-MAIL
 
my $nom_dom = $ARGV[0]; #p.e. nombre que el usuario quiere para subdominio
my $sites_apache = "/etc/apache2/sites-available"; 
my $SYSCONFDIR = "/etc/apache2/";
my $ruta = "$sites_apache/$nom_dom"; 
my $mail = $ARGV[1]; #recogemos el e-mail del usuario
my $dominio = "www.$nom_dom.dominio.com";
my $ubicacion = "/var/www/$nom_dom";
my $log_error = "/var/log/apache2/error_$nom_dom.log";
my $log_custom = "/var/log/apache2/access_$nom_dom.log";
 
#Comprobamos que no exista ya
if (-e "$sites_apache/$nom_dom") {
    print "El nombre de subdominio $nom_dom ja existe ! \n";
} 
else { 
  
  #Tenemos una plantilla con los valores clave a cambiar   
  my $template = Text::Template->new(TYPE => 'FILE', SOURCE => "$sites_apache/plantilla")
             or die "Couldn't construct template: $Text::Template::ERROR";
 
  my %vars = (EMAIL => $mail,
              DOMINIO => $dominio,
              UBICACION => $ubicacion,
              LOG_ERROR => $log_error,
              LOG_CUSTOM => $log_custom,
             );
 
  my $result = $template->fill_in(HASH => \%vars);
  
  #Creamos el nuevo fichero de config.
  open CONFIG, ">$sites_apache/$nom_dom";
 
  if (defined $result) { print CONFIG $result }
  else { die "Couldn't fill in template: $Text::Template::ERROR" }
  close(CONFIG);
 
  #Añadimos el subdominio en /etc/hosts para simular DNS a nivel local
  tie my @array, 'Tie::File', "/etc/hosts" or die "Error Tie::File";
  for (@array) { s/#AFEGIR_DOM_AQUI/$domini #AFEGIR_DOM_AQUI/g; }
 
  #Activamos el nuevo Vhost
  my $ret = symlink("$SYSCONFDIR/sites-available/$nom_dom","$SYSCONFDIR/sites-enabled/$nom_dom");
  if (!$ret){ print "Error al crear symbolic link \n"; }
 
  #Creamos el directorio para el nuevo site
  mkdir "/var/www/$nom_dom", 0755 or warn"No se pudo crear el directorio: $!";
  #Creamos un index.html para que se muestre algo hasta que el usuario ponga su contenido
  open(fd,">/var/www/$nom_dom/index.html") or die "No se pudo crear el fichero index.html\n";   
  print fd "<title>$dominio</title> <html>Espacio web $nom_dom</html>";
  close(fd);
 
  #Reiniciamos apache para que los cambios tengan efecto
  system("sudo /etc/init.d/apache2 reload");
 
  #Para las pruebas
  print "\n-------------------\nSe creó el dominio $dominio con éxito! \n";
  print "Correo electronico: $mail \n";
  print "El log de errores : $log_error \n";
  print "El log de accesos : $log_custom \n-------------------\n";
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

Ahora tan solo hay una llamada a system() para reiniciar Apache.
Para añadir el nuevo dominio al fichero hosts he utilizado la misma técnica de antes de la sustitución pero utilizando el use Tie::File que me comentaste. Es la mejor forma que se me ha ocurrido (no he encontrado muchos ejemplo que es como mejor entiendo estas cosas). Otra forma seria añadir siempre al final algo como:

Sintáxis: [ Descargar ] [ Ocultar ]

127.0.0.1 Nuevodominio.com

Pero de esta forma se repetiría muchas veces '127.0.0.1' innecesariamente.

De nuevo gracias, es de gran ayuda que alguien con experiencia en esto te eche una mano, ya que para un proyecto de la universidad estoy tocando demasiados lenguajes y es imposible empaparse de todos a un nivel profundo (ya me gustaría).

Y una última cosita. Tengo un servidor de XML-RPC también en Perl y utilizo Frontier::Daemon. ¿Crees que es la mejor opción?
Si me surge alguna otra duda ya me verás por aquí dando la lata.

Un saludo.

por **explorer** » 2009-07-24 10:08 @464

No conozco Frontier::Daemon, no puedo decirte qué tal es.

por **cmp** » 2009-07-28 12:20 @555

Ok, gracias.

Ahora tengo un problema para borrar un directorio (que puede contener subdirectorios). Para evitar utilizar una llamada al sistema he encontrado File::Path que puede hacerlo.

Resumiendo. Tengo el siguiente código:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use strict;
use File::Path 'remove_tree';
 
remove_tree( 'var/www/borrar/',  {error => \my $err} );
  if (@$err) {
      for my $diag (@$err) {
          my ($file, $message) = %$diag;
          if ($file eq '') {
              print "general error: $message\n";
          }
          else {
              print "problem unlinking $file: $message\n";
          }
      }
  }
  else {
      print "No error encountered\n";
  }
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Pues me dice que no ha habido errores pero no me elimina el directorio... ¿Alguna idea?

Un saludo

por **explorer** » 2009-07-28 13:50 @618

Te falta un '/' delante de 'var'.

por **cmp** » 2009-07-29 10:53 @495

Madre mía

Vaya días que llevo...
Lo que es raro, es que no lo reportara como error.

Muchas gracias.

por **explorer** » 2009-07-29 11:41 @529

He estado mirando el código del módulo: no reporta error porque no ha encontrado ningún fichero qué borrar.

Una forma de saber si lo ha hecho bien es guardar el valor que devuelve la función: es el número de ficheros que ha conseguido borrar. En tu caso, te devuelve un 0.

por **cmp** » 2009-07-30 11:06 @504

Cierto, muchas gracias ya funciona perfecto.

Foro - Perl en Español

Script para crear subdominios automaticamente

Script para crear subdominios automaticamente

Publicidad

Re: Script para crear subdominios automaticamente

Re: Script para crear subdominios automaticamente

Re: Script para crear subdominios automaticamente

Re: Script para crear subdominios automaticamente

Re: Script para crear subdominios automaticamente

Re: Script para crear subdominios automaticamente

Re: Script para crear subdominios automaticamente

Re: Script para crear subdominios automaticamente

¿Quién está conectado?