Foro - Perl en Español

por **BigBear** » 2009-08-29 17:46 @782

Hola estoy tratando de separar de manera par los números de una cifra pero no sé cómo hacerlo.

Lo que pretendo hacer es esto

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

Cifra = 480102304

Resultado = 4

            0

            0 

            3 

            4Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

Agradecería cualquier ayuda.

A la cifra le damos la vuelta (reverse()) para que el dígito que está en la primera posición accedamos a él como si estuviera en la posición 0 (la primera), con la función substr(). Sin esto, habría que hacer otra cuenta dentro de substr() para saber a qué dígito nos referimos.

Luego recorremos las cifras, de dos en dos.

Y para cada cifra, la extraemos y la guardamos en el arreglo, en orden inverso (deshacemos de alguna manera el efecto del reverse() anterior). Con unshift() estamos metiendo las cifras por la parte 'izquierda' del arreglo.

Ya solo queda pintarlo.

Y esta es una de la media docena de formas de hacerlo... ¿Alguien más se anima?

por **netsoul** » 2009-08-30 01:33 @106

También usé un poco de matemáticas.

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use strict;
use warnings;
 
my @cifra = split //, "480102304"; #Almacenamos cada dígito en cada lugar de @cifra
 
print map {$cifra[$_] if !($_ % 2)} 0..$#cifra; #Imprimimos si la posición es (im)par
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

No sé si el código es bueno, pero espero que pueda valer.

por **explorer** » 2009-08-30 09:29 @437

Esta es la solución con expresiones regulares

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use strict;
use warnings;
use diagnostics;
 
my $cifra = '480102304';
 
$cifra = reverse $cifra;
 
my @cifras;
 
while ($cifra =~ /(\d)\d?/g) {
 
    unshift @cifras, $1;
}
 
print "@cifras";
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

que puede quedar reducida a:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
my $cifra  = reverse '480102304';          # Le damos la vuelta para contar desde la derecha
my @cifras = reverse $cifra =~ /(\d)\d?/g; # De cada grupo de dos dígitos, nos quedamos con el primero
                                           # A todos ellos, les invertimos de orden (reverse)
                                           # por exigencias del formato de salida,
                                           # y los guardamos en @cifras
print "@cifras";
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

(Sí, es algo "enrevesada"

)

¡Ánimo, quedan más formas de resolverlo!

¿Alguien más se anima?

P.D. La solución de netsoul no vale porque empieza a contar los dígitos desde el lado izquierdo :twisted:

Le falta un reverse() :wink:

por **netsoul** » 2009-08-30 10:31 @480

Este explorer es un cabrón. Si él fuera mi jefe en una empresa, ya me hubiera despedido antes de pestañear dos veces. :twisted:

Aquí va otro:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use strict;
use warnings;
 
my $cifra = reverse "480102304";
print reverse map {substr $cifra, $_, 1 if !($_ % 2)} 0..length $cifra;
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

por **explorer** » 2009-08-30 13:26 @601

He encontrado un patrón de búsqueda de los dígitos que se buscan.

Se trata de pensar en ir de dos en dos dígitos, de izquierda a derecha, mostrando el segundo de ellos. Hay una excepción a la regla, que es el primer dígito de la cifra, el que está a la izquierda. Podría estar ocupando una posición par o no. Para saberlo, debemos asegurarnos que los dígitos que quedan detrás de él forman pares de dígitos.

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use strict;
use warnings;
use diagnostics;
 
my $cifra = '480102304';
 
print $1 while $cifra =~ /(\d)(?=(?:\d\d)*$)/gx;
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Un poco mejor explicado:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use strict;
use warnings;
use diagnostics;
 
my $cifra = '480102304';
 
while (
    $cifra =~ /
                (\d)                # Solo nos quedamos con el primer dígito
                (?=                 # que esté seguido
                    (?:\d\d)*       #   por pares de dígitos
                    $               #   hasta el final
                )
              /gx                   # (la opción /x nos permite hacer este ascii-art)
) {
    print $1;
}
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

Ya no es necesario usar los reverse()

por **netsoul** » 2009-08-30 15:59 @707

Aquí va más uno. Presento la versión 3.0. Los anteriores tenían algunas fallas.

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use strict;
use warnings;
 
my @cifra = split '', reverse "480102304";
 
print reverse map {$cifra[$_] if /[02648]$/} 0..$#cifra;
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

por **BigBear** » 2009-08-30 19:34 @857

Ok, teniendo cualquiera de sus diversos códigos competitivos, ¿cómo haría para separarlos y multiplicarlos de a dos? Ejemplo:

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

4x5

4x6Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

¿Y tener el resultado guardado con un my() para poder ver si éstos son mayor que 9?

por **netsoul** » 2009-08-30 22:21 @972

¿Un código?

por **BigBear** » 2009-08-31 17:46 @782

Pues en realidad un pequeño script. Disculpen si les estoy pidiendo demasiado, pero es lo único que me falta para terminar un extenso proyecto en el que estoy.

Foro - Perl en Español

Cómo separar los números de una cifra

Cómo separar los números de una cifra

Publicidad

Re: Cómo separar los números de una cifra

Re: Cómo separar los números de una cifra

Re: Cómo separar los números de una cifra

Re: Cómo separar los números de una cifra

Re: Cómo separar los números de una cifra

Re: Cómo separar los números de una cifra

Re: Cómo separar los números de una cifra

Re: Cómo separar los números de una cifra

Re: Cómo separar los números de una cifra

¿Quién está conectado?