Foro - Perl en Español

por **tyranus** » 2009-09-13 11:21 @515

Hola, comunidad de Perl en Español. Soy nuevo en el foro y ando complicado con el tema de hash de hashs.

Crearlos es sencillo pero leerlos no termino de comprender... tal vez esté haciendo todo mal.

A ver...

Tengo esto:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

print "Nombre de la carpeta: ";
$carpeta = <STDIN>;
chomp($carpeta);
opendir(DIR,$carpeta) || die "Error al abrir la carpeta.";
readdir(DIR);
readdir(DIR);
while( $file=readdir(DIR)) {
        open(F,"$carpeta\\$file") || die "archivo no encontrado";
        while ( $linea=<F> ) {
                chomp($linea);
                @palabras = split(" ",$linea);
                foreach $clave (@palabras) {
                        $terminos{$file}{$clave}+=1;
                };
        };
        close(F);
};
print "Va a imprimir el hash de hashes \n";
while ( my ($key, $value) = each(%terminos) ) {
        print "Archivo: $key \n"; # el problema está en que no sé recuperar los valores
        foreach $key2 (keys %value) {
                print $key2;
                print "$value{%key2} \n";
        };
};
Coloreado en 0.005 segundos,  usando GeSHi 1.0.8.4

Seguramente estoy haciendo varias cosas mal en la lectura.
Porque en $value termina habiendo un hash pero no puedo sacar los valores de allí.
Hace 2 o 3 días que empecé con Perl, sean comprensivos.

Espero se me entienda lo que quise preguntar.

¡Muchas gracias desde ya!

Un saludo.

Bienvenido a los foros de Perl en Español, tyranus.

En la línea 21 haces referencia a la variable hash %value, pero esa variable no la has definido en ningún sitio. Habrás querido decir %$value, es decir, $value contiene una referencia al hash correspondiente a la clave $key, que ha devuelto each().

Y en la línea 23 vuelves a hacer referencia a esa variable desconocida, %value, además de otra nueva: %keys. Seguramente querrás decir $value->{$key2}.

Más detalles: no es necesario poner ';' detrás de las llaves, excepto en un par de casos.

El acceso al contenido de los hash se puede realizar de varias maneras, como te pongo aquí, en el último print():

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use strict;
use warnings;
use diagnostics;
 
my %terminos = (
    fichero1 => {
                    La    => 2,
                    casa  => 1,
                    de    => 12,
                    omega => 6,
                },
    fichero2 => {
                    Los   => 1,
                    los   => 1,
                    tres  => 2,
                    de    => 9,
                    alfa  => 1,
                },
);
 
 
use Data::Dumper;
print Dumper \%terminos;
 
print "Va a imprimir el hash de hashes \n";
 
while (my ($fichero, $palabras_del_fichero) = each(%terminos) ) {
    print "Archivo: $fichero\n";
    foreach my $palabra (keys %$palabras_del_fichero) {
        print "$palabra => $terminos{$fichero}{$palabra} | $palabras_del_fichero->{$palabra}\n";
    }
}
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

Recuerda también que el módulo Data::Dumper es tu amigo.

Aquí te lo pongo de otra manera:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use strict;
use warnings;
use diagnostics;
 
my %ficheros = (
    fichero1 => {
                    La    => 2,
                    casa  => 1,
                    de    => 12,
                    omega => 6,
                },
    fichero2 => {
                    Los   => 1,
                    los   => 1,
                    tres  => 2,
                    de    => 9,
                    alfa  => 1,
                },
);
 
 
for my $fichero (keys %ficheros) {
    print "Archivo: $fichero\n";
 
    for my $palabra (keys %{$ficheros{$fichero}}) {
        print "$palabra  => $ficheros{$fichero}{$palabra}\n";
    }
}
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Digamos que el acceso es casi igual que en otros lenguajes, como el C. Sólo hay que seguir de forma correcta la sintaxis. Lo bueno de Perl es que permite hacerlo de más de una forma.

por **tyranus** » 2009-09-13 12:14 @551

¡Muchas gracias, explorer! Por la bienvenida y por la explicación, ha quedado todo muy claro.

Foro - Perl en Español

Hash de hash

Hash de hash

Publicidad

Re: Hash de hash

Re: Hash de hash

¿Quién está conectado?