Foro - Perl en Español

por **visualfree** » 2009-11-20 22:08 @964

Hola, mi problema es el siguiente: necesito saber cómo hacer para que no todo quede tan separado uno de otro... espero hacerme entender.

Ejemplo:

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

________________________________________________________________ <-largo aplicación

_________lb1___________________.____________txt1________________Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

entonces el lb1 se auto estira junto el text1...

y lo que yo necesito es:

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

________

lb1.txt1 <---que no se estire o poder definir las dimensiones de los componentesColoreado en 0.000 segundos,  usando GeSHi 1.0.8.4

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

use Gtk2 '-init';
my $window=Gtk2::Window->new('toplevel');
$window->set_border_width(10);
$window->signal_connect(destroy =>sub{
 Gtk2->main_quit
});
$lb1=Gtk2::Label->new('Numero 1:');
$lb2=Gtk2::Label->new('Numero 2:');
$lb3=Gtk2::Label->new('Opcion:');
$lb4=Gtk2::Label->new('Resultado:');
$text1=Gtk2::Entry->new;
$text2=Gtk2::Entry->new;
$text3=Gtk2::Entry->new;
$boton=Gtk2::Button->new('Calcular');
$vertical=Gtk2::HBox->new(3,false);
$horizontal=Gtk2::HBox->new(2,false);
$radiobutton1 = Gtk2::RadioButton->new_with_label('grupo', '+');
@grupo = $radiobutton1->get_group;
$radiobutton2 = Gtk2::RadioButton->new_with_label(@grupo, '-');
$radiobutton3 = Gtk2::RadioButton->new_with_label(@grupo, '*');
$radiobutton4 = Gtk2::RadioButton->new_with_label(@grupo, '/');
$vertical->pack_start($radiobutton1,false,false,false);
$vertical->pack_start($radiobutton2,false,false,false);
$vertical->pack_start($radiobutton3,false,false,false);
$vertical->pack_start($radiobutton4,false,false,false);
$horizontal->pack_start($text3,false,false,false);
$horizontal->pack_start($boton, gtk.TRUE, gtk.TRUE, 0);
$tabla=Gtk2::Table->new(4,2,FALSE);
$tabla->attach_defaults($lb1,0,1,0,1);
$tabla->attach_defaults($text1,1,2,0,1);
$tabla->attach_defaults($lb2,0,1,1,2);
$tabla->attach_defaults($text2,1,2,1,2);
$tabla->attach_defaults($lb3,0,1,2,3);
$tabla->attach_defaults($vertical,1,2,2,3);
$tabla->attach_defaults($lb4,0,1,3,4);
$tabla->attach_defaults($horizontal,1,2,3,4);
$window->add($tabla);
$window->show_all;
Gtk2->main;
Coloreado en 0.004 segundos,  usando GeSHi 1.0.8.4

De paso me gustaría saber si alguien sabe agregar un Table o JTable en Java pero en Perl con Gtk2::, algo como una grilla, no sé si me entienden; espero que sí. Saludos...

Con esto, ya salen ajustados los contenidos dentro de la tabla. Lo mismo pasa con la palabra 'false'.

Perl, por defecto, cuando encuentra una palabra que no sabe lo que es y está seguro de que no es una función, la convierte a una palabra suelta (una cadena de caracteres). Así que, en tu programa, estás poniendo un valor verdadero (la cadena de caracteres 'false') en un sitio donde realmente querías poner un valor falso (que, tendría que ser una cadena vacía '' o un 0). Así que te toca cambiar todos los 'false' del programa por la nueva constante 'FALSE'.

Para evitar estos errores, nadie mejor que el propio Perl para que nos avise.

Ponemos 'use warnings;' al principio del programa y empiezan a salir errores y avisos como este:

Unquoted string "false" may clash with future reserved word at ./code_19824_2.pl line 9.

Perl te está avisando de que ha encontrado una cadena de caracteres, que es "false", y que, de la manera que la has escrito (sin entrecomillar), sospecha que puede interferir con futuras palabras reservadas del Perl. Te deja seguir, pero te lo advierte. Para nosotros, significa que hemos colocado un literal donde realmente queríamos colocar una constante.

Además, Perl nos avisa de otro error:

Unquoted string "gtk" may clash with future reserved word at ./code_19824_2.pl line 43.

¡Vaya! Perl tampoco sabe lo que es "gtk".

El método pack_start() va agregando componentes desde el comienzo del contenedor. Tiene 4 argumentos, que son: el objeto a empaquetar, una bandera que indica si debe tomar espacio suficiente para expandirse, una bandera para indicar si el espacio extra debe ser tomado por el propio objeto o por espacio vacío, y un valor del extra de píxeles que deben rodear al objeto con respecto a sus vecinos.

Veo también que a la hora de crear los HBox, pones valores como 3 y 2, en lugares donde Gtk2 espera un valor booleano. Así que lo que realmente estás pasando es un valor verdadero. Y es precisamente aquí donde estás definiendo que el espacio ocupado por los objetos sea homogéneo, cuando realmente no queremos eso.

El programa quedaría así:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use warnings;
 
use Gtk2 '-init';
 
use constant TRUE  => 1;
use constant FALSE => 0;
 
my $window = Gtk2::Window->new('toplevel');
$window->set_border_width(10);
$window->signal_connect(destroy =>sub{ Gtk2->main_quit });
 
$lb1 = Gtk2::Label->new('Numero 1:');
$lb2 = Gtk2::Label->new('Numero 2:');
$lb3 = Gtk2::Label->new('Opcion:');
$lb4 = Gtk2::Label->new('Resultado:');
 
$text1 = Gtk2::Entry->new;
$text2 = Gtk2::Entry->new;
$text3 = Gtk2::Entry->new;
 
$boton = Gtk2::Button->new('Calcular');
 
$vertical   = Gtk2::HBox->new(FALSE,3);
$horizontal = Gtk2::HBox->new(FALSE,3);
 
#$radiobutton1 = Gtk2::RadioButton->new_with_label(undef, '+');
#$grupo = $radiobutton1->get_group;
#$radiobutton2 = Gtk2::RadioButton->new_with_label($grupo, '-');
#$radiobutton3 = Gtk2::RadioButton->new_with_label($grupo, '*');
#$radiobutton4 = Gtk2::RadioButton->new_with_label($grupo, '/');
 
$radiobutton1 = Gtk2::RadioButton->new_with_label(undef,         '+');
$radiobutton2 = Gtk2::RadioButton->new_with_label($radiobutton1, '-');
$radiobutton3 = Gtk2::RadioButton->new_with_label($radiobutton2, '*');
$radiobutton4 = Gtk2::RadioButton->new_with_label($radiobutton3, '/');
 
$vertical->pack_start($radiobutton1,FALSE,FALSE,0);
$vertical->pack_start($radiobutton2,FALSE,FALSE,0);
$vertical->pack_start($radiobutton3,FALSE,FALSE,0);
$vertical->pack_start($radiobutton4,FALSE,FALSE,0);
 
$horizontal->pack_start($text3,FALSE,FALSE, 0);
$horizontal->pack_start($boton, TRUE, TRUE, 5);
 
$tabla=Gtk2::Table->new(4,2,FALSE);
$tabla->attach_defaults($lb1,0,1,0,1);
$tabla->attach_defaults($text1,1,2,0,1);
$tabla->attach_defaults($lb2,0,1,1,2);
$tabla->attach_defaults($text2,1,2,1,2);
$tabla->attach_defaults($lb3,0,1,2,3);
$tabla->attach_defaults($vertical,1,2,2,3);
$tabla->attach_defaults($lb4,0,1,3,4);
$tabla->attach_defaults($horizontal,1,2,3,4);
 
$window->add($tabla);
 
$window->show_all;
 
Gtk2->main;
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

Fíjate también que he colocado una versión alternativa de creación del grupo de botones radio. Tanto la versión que está comentada como la que no, funcionan de la misma manera. Fíjate que el primer botón lo he marcado con un 'undef'.

Todo esto lo he sacado de los manuales de ayuda de Gtk2 en http://gtk2-perl.sourceforge.net/doc/pod/

por **visualfree** » 2009-11-21 13:46 @615

Muy bien, gracias maestro

Lo último: ¿qué tipo de grilla puedo usar con gtk2...?
Por ejemplo, en Java usaba JTable. Acá, no sé qué podré usar...

por **explorer** » 2009-11-21 16:54 @746

Una grilla es la hembra del grillo. ¿O no?

por **visualfree** » 2009-11-21 17:04 @753

Lógicamente, sí

Y lo que te preguntaba ya lo averigüé, que es "Gtk2::SimpleList " pero no sé cómo usarlo. Si me pudieras dar un ejemplo muy básico te lo agradecería...

por **explorer** » 2009-11-21 17:48 @783

Yo no, pues nunca lo he manejado... ¿no te vale el ejemplo que está en la sinopsis de Gtk2::SimpleList?

Foro - Perl en Español

Ajuste de widgets en Gtk2

Ajuste de widgets en Gtk2

Publicidad

Re: Ajuste de widgets en Gtk2

Re: Ajuste de widgets en Gtk2

Re: Ajuste de widgets en Gtk2

Re: Ajuste de widgets en Gtk2

Re: Ajuste de widgets en Gtk2

¿Quién está conectado?