Foro - Perl en Español

por **creating021** » 2009-12-07 16:18 @721

Hola.

Tengo una lista, para ser exactos, una lista de paquetes es similar a esta:

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

xxx-0.1.tar.bz2

xxx-0.1.1.tar.bz2

xxx-0.1.2.tar.bz2

xxY-0.1.tar.bz2

xxx-0.2.tar.bz2

yyy-0.3.tar.gz

xxx-0.1.1.2.tar.bz2

xxx-1.9.10.tar.bz2

xxx-1.9.10.1.tar.bz2

...Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

Lo que yo necesito hacer es tomar la versión más nueva de xxx, que desconozco completamente, así que pensé en hacer una expresión regular, pero hay versiones de 4 dígitos, otras de tres y otras de dos...

¿Cuál sería la mejor forma de obtener la versión más nueva?

#!/usr/bin/perl
use strict;
use warnings;
use diagnostics;
 
use version 0.77;
 
my @nombres_de_ficheros = qw(
    xxx-0.tar.bz2
    xxx-0.1.tar.bz2
    xxx-0.010.1.tar.bz2
    xxx-0.1.2.tar.bz2
    xxY-0.1.tar.bz2
    xxx-0.2.tar.bz2
    yyy-0.3.tar.gz
    xxx-0.1.1.2.tar.bz2
    xxx-1.9.10.1.tar.bz2
    xxx-1.9.10.tar.bz2
);
 
my $fichero_con_version_mas_alta;
 
my $version_mas_alta = version->new('v0');
 
for my $nombre_de_fichero (@nombres_de_ficheros) {              # Recorremos los nombres de los ficheros
 
    next if $nombre_de_fichero !~ /^xxx/i;                      # Saltamos si no son los ficheros que nos interesan
 
    my ($numero_version) = $nombre_de_fichero =~ /-([\d.]+)\./; # Sacamos el número de versión
 
    if (defined $numero_version) {
 
        my $version = version->new("v$numero_version");         # Lo convertimos a objeto versión
 
        if ($version ge $version_mas_alta) {                    # Si la versión es mayor que la más alta encontrada
 
            #print "$version_mas_alta => $version\n";
 
            $version_mas_alta = $version;                       # Guardamos esa versión
 
            $fichero_con_version_mas_alta = $nombre_de_fichero; # Y guardamos el nombre de ese fichero
        }
    }
}
 
print "$fichero_con_version_mas_alta => $version_mas_alta\n";   # xxx-1.9.10.1.tar.bz2 => v1.9.10.1
 
__END__
Coloreado en 0.003 segundos,  usando GeSHi 1.0.8.4

¿A que no te lo esperabas?

Actualización: versión corregida, más reducida y limpia.

por **creating021** » 2009-12-07 17:28 @770

¡Wow! Muchas gracias, explorer!, y sí, la verdad es que no me lo esperaba.

Foro - Perl en Español

Tomar el mayor número de unos ficheros

Tomar el mayor número de unos ficheros

Publicidad

Re: Tomar el mayor número de unos ficheros

Re: Tomar el mayor número de unos ficheros

¿Quién está conectado?