Foro - Perl en Español

my $nueva_cadena;
for (my $i = 0; $i < length $cadena; ) {           # Para todo lo largo de la cadena
    $nueva_cadena .= substr $cadena, $i, 1;        # Copiamos una letra de la $cadena
    $i++;                                          # Siguiente posición
    if ($i % 4 == 0  and  $i != length $cadena) {  # ¿Es la posición múltiplo de 4 y
                                                   # no es el final de $cadena?
        $nueva_cadena .= ' ';                      # Sí, agregamos un espacio
    }
}

my $nueva_cadena = $cadena;              # Sacamos una copia

for (my $i                               # $i será la posición donde poner el ' '
        = int((length($cadena)-1)/4)*4;  # Inicialmente, en la última posición
     $i > 0 ;                            # Repetimos hasta llegar a la izquierda
     $i -= 4                             # Saltamos de 4 en 4 hacia la izquierda
) {
    substr($nueva_cadena, $i, 0) = ' ';  # Insertamos un ' ' en esa posición
}

(my $nueva_cadena = $cadena)    # Sacamos una copia

    =~ s/(.{4})(?!$)/$1 /g;     # (.{4}) Buscamos bloques de 4 caracteres
                                # (?!$)  que no estén al final de la cadena
                                # $1     y los sustituimos por ellos mismos
                                #        más un carácter en blanco
    ;

my $nueva_cadena        # Mi $nueva_cadena
    = join ' ',         # es la unión, con un ' ', de todas las partes
      grep { /./ }      # que al menos tengan una letra
      split /(.{4})/,   # extraídas de 4 en 4 letras
      $cadena           # de la cadena original
    ;

my $nueva_cadena        # Mi $nueva_cadena
    = join ' ',         # es la unión, con un ' ', de todas las partes
      unpack "(a4)*",   # extraídas de 4 en 4 letras
      $cadena           # de la cadena original
    ;

my $nueva_cadena;

for (my $i = 0; $i < length $cadena; $i+=4) {       # A lo largo de toda la cadena, con saltos de 4 letras
    $nueva_cadena .= substr($cadena, $i, 4) . ' ';  # Copiamos un bloque de 4 caracteres a la $nueva_cadena
                                                    # más un espacio en blanco
}
chop $nueva_cadena;                                 # Quitamos el último espacio en blanco, que sobra

my $nueva_cadena = '';
my $vieja_cadena = $cadena;

while ($vieja_cadena) {
    my $cacho = substr $vieja_cadena, 0, 4;         # Sacamos una parte, por la izquierda
    $vieja_cadena = substr $vieja_cadena, 4;        # Recortamos la $vieja_cadena
    $nueva_cadena = $nueva_cadena . $cacho . ' ';   # Añadimos la parte a la $nueva_cadena
}
chop $nueva_cadena;                                 # Quitamos último espacio en blanco, que sobra

# Mi $nueva_cadena es la unión, con espacio en blanco,
# de todos los grupos de 4 caracteres que pueda encontrar
# en la $cadena
my $nueva_cadena = join ' ', $cadena =~ /(.{4})/g;

my $nueva_cadena                        # Solución básica: corte y pega
    = substr($cadena, 0, 4) . ' '
    . substr($cadena, 4, 4) . ' '
    . substr($cadena, 8, 4) . ' '
    . substr($cadena,12, 4)
    ;