Foro - Perl en Español

por **explorer** » 2010-04-04 08:07 @380

RockoX escribiste:Una pregunta sobre el foro, ¿cómo puedo cambiar el nombre de mi usuario?

Mándame un mensaje privado, indicándome el nombre de usuario que quieres tener.

El problema con el programa Gtk es el siguiente: la función que se dispara al pulsar el botón de buscar, está creando una nueva etiqueta, cada vez:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

                $label_mensaje = Gtk2::Label->new($rae);
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

y además, no la estás presentando al usuario.

La solución pasa por cambiar el texto de la etiqueta. Solo eso:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

                $label_mensaje->set_text($rae);
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

#!/usr/bin/perl
use warnings;
use strict;
use WWW::Mechanize;
use Gtk2 '-init';
use constant TRUE => 1;
use constant FALSE => 0;
 
sub raeSearch()
{
        my $mech = WWW::Mechanize->new();
        $mech->get("http://buscon.rae.es/draeI/SrvltGUIBusUsual?LEMA=$_[0]");
        my $string = $mech->content(format => "text");
        
        $string =~ s/^.*?(?=1\.)//;
        $string =~ s/(\d+\.)/\n$1/g;
        $string =~ s/Real Academia.*$//;
 
        return $string;
}
 
my $window = Gtk2::Window->new('toplevel');
$window->set_border_width(100); 
$window->signal_connect(destroy => sub{Gtk2->main_quit});
 
my $label = Gtk2::Label->new("RAE Search.");
my $button = Gtk2::Button->new("Buscar");
my $vbox = Gtk2::VBox->new(5, FALSE);
$vbox->add($label);     
$vbox->pack_end($button, FALSE, FALSE, FALSE);  
my $dir_entry = Gtk2::Entry->new;       
$dir_entry->set_text("");       
 
$vbox->pack_start($dir_entry, FALSE, FALSE, FALSE);
my $label_mensaje = Gtk2::Label->new("");
my $rae;
$button->signal_connect(clicked => sub
        {
                $rae = $dir_entry->get_text;
                print "$rae\n";
                $label_mensaje->set_text(&raeSearch($rae));     # Llamada a la función.
        }
);
$vbox->add($label_mensaje);
$window->add($vbox);
$window->show_all;
 
Gtk2->main;
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

Gracias por todo.

por **explorer** » 2010-04-04 13:54 @621

Muy bonito. Y el tema de Ubuntu me gusta

Por favor, revisa mi último código. Verás que con LWP::Simple obtendrás la función get(), de forma más rápida y cómoda que con WWW::Mechanize.

por **Leo_Gutierrez** » 2010-04-04 18:04 @795

Gracias por las respuestas, explorer.

Mira, tu último código lo he tratado así (agregué la función binmode() porque me daba el aviso de "wide character"):

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
#use feature 'say';
#use open 'locale';
use LWP::Simple;
binmode STDOUT, ":encoding(UTF-8)";
sub Search()
{
        my $rae = get("http://buscon.rae.es/draeI/SrvltGUIBusUsual?LEMA=$_[0]"); 
        while ($rae =~ m/name="[\d_]+"> (.*?) <\/p/smgix)
        {
                $desc = $1;
                # Quitar las marcas HTML
                $desc =~ s/<.*?>//gsm;
                # Quitar los espacios a los lados
                $desc =~ s/^\s+//sm;
                $desc =~ s/\s+$//sm;
                # Quitar espacios excesivos
                $desc =~ s/\s+/ /gsm;
                return "$desc";
        }
}
print &Search("fortuito"), "\n";
 
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Y la salida que me da es:

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

leo@lein:~/Escritorio$ perl simple.pl

abyecto, ta.

leo@lein:~/Escritorio$ 
Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

Es decir, si lo trato como función no me funciona bien, pero sí sin función.

He quitado estas líneas:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

use feature 'say';
useopen'locale';
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Porque Perl me estaba dando este aviso:

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

Can't locate feature.pm in @INC (@INC contains: /etc/perl /usr/local/lib/perl/5.8.8 /usr/local/share/perl/5.8.8 /usr/lib/perl5 /usr/share/perl5 /usr/lib/perl/5.8 /usr/share/perl/5.8 /usr/local/lib/site_perl .) at simple.pl line 2.

BEGIN failed--compilation aborted at simple.pl line 2.
Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

El say() lo cambié por un print(), pero igual, no me hace el trabajo, ¿se debe a las líneas que he comentado?

PD : He agregado las scroll bars a la interfaz, pero estoy teniendo problemas para unir las barras con el label.

por **explorer** » 2010-04-04 18:22 @807

El 'use open "locale" me resolvió lo del wide character, porque yo trabajo en mis máquinas con utf8, desde hace años.

El say() se activa con el 'feature', desde luego, pero solo si tienes el Perl v5.10. El mensaje de error dice que tienes un Perl v5.8.8, de hace ya unos años... ¡lástima!

El problema de la función está en el return().

Fíjate que lo has puesto dentro de un bucle while(). Eso quiere decir que en cuanto el while() encuentre la primera concordancia de la expresión regular, saldrá de la función. Por eso obtienes la línea de "abyecto", pero no las restantes: el bucle while() salió por el return() y no siguió buscando más concordancias.

Puedes hacer lo siguiente: crea una variable local, dentro de la función, que vaya almacenando lo que la expresión regular va encontrando, para luego devolverlo todo:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

    my $resultado;
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

        $resultado .= "$desc\n";
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

    return $resultado;
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

por **Leo_Gutierrez** » 2010-04-04 18:28 @811

Jaja, qué tonto fui, no vi que estaba dentro del while(), en seguida lo resuelvo.

por **Leo_Gutierrez** » 2010-04-04 19:47 @865

He rediseñado la interfaz, porque estaba muy desorganizado, también agregué un frame, queda así ahora:

http://img94.imageshack.us/img94/411/pantallazo2j.png

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use warnings;
use strict;
use LWP::Simple;
use Gtk2 '-init';
use constant TRUE => 1;
use constant FALSE => 0;
 
binmode STDOUT, ":encoding(UTF-8)";
 
sub raeSearch()
{
        my $rae = get("http://buscon.rae.es/draeI/SrvltGUIBusUsual?LEMA=$_[0]");
        my $resultado;
        while ($rae =~ m/name="[\d_]+"> (.*?) <\/p/smgix)
        {
                my $desc = $1;
                # Quitar las marcas HTML
                $desc =~ s/<.*?>//gsm;
                # Quitar los espacios a los lados
                $desc =~ s/^\s+//sm;
                $desc =~ s/\s+$//sm;
                # Quitar espacios excesivos
                $desc =~ s/\s+/ /gsm;
                $resultado .= "$desc\n";
        }
                return $resultado;
}
 
# Propiedades de ventana:
my $window = Gtk2::Window->new('toplevel');
$window->set_title("Rae Search");
$window->set_border_width(3);
$window->signal_connect(destroy => sub{Gtk2->main_quit});
 
# Frame:
my $frame = Gtk2::Frame->new("Entrada");
 
# VBox:
my $vbox = Gtk2::VBox->new(FALSE, 6);
$vbox->pack_start($frame, TRUE, TRUE, 0);
 
# HBox:
my $hbox = Gtk2::HBox->new(FALSE, 6);
 
# Entry:
my $dir_entry = Gtk2::Entry->new_with_max_length(30);
$dir_entry->set_text("encono");
 
# Label:
my $label_mensaje = Gtk2::Label->new("");
 
# Button
my $button = Gtk2::Button->new("_Buscar");
$button->signal_connect(clicked => sub
        {
                $label_mensaje->set_text(&raeSearch($dir_entry->get_text));
        }
);
$vbox->pack_end($label_mensaje, TRUE, TRUE, 0);
 
$frame->add($hbox);
 
$hbox->pack_start($dir_entry, FALSE, FALSE, 0);
$hbox->pack_start($button, FALSE, FALSE, 0);
 
$window->add($vbox);
$window->show_all;
Gtk2->main;
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

Igual sigo teniendo este problema con entradas que den bastante texto:
http://img100.imageshack.us/img100/5939/pantallazo3s.png

Voy a incorporar las scroll bars, a ver como me va, ojalá y no haya problemas.

Edito: He agregado un icono, pero aún sigo con el problema de las scroll bars.

por **Leo_Gutierrez** » 2010-04-04 22:37 @984

Me rindo, no puedo incorporar el label a las scroll bars.

Llevo horas intentándolo y no puedo, ¿alguien me podría dar una mano?

¿O podría usar otra cosa en vez de label?

Edito:

Hay un widget que se llama "TextView", voy a ver si puedo incorporarlo.

por **Leo_Gutierrez** » 2010-04-05 01:15 @094

Bueno, al fin pude, aquí está como quedó:

Imagen

Ya casi está lista, el problema que estoy teniendo ahora es solo que las búsquedas anteriores se quedan en el TextView.

Ah, y le he agregado un camello de icono a la aplicación.

Mañana veo si puedo agregarle un botón para mandar al clipboard.

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use warnings;
use strict;
use LWP::Simple;
use Gtk2 '-init';
use constant TRUE => 1;
use constant FALSE => 0;
 
binmode STDOUT, ":encoding(UTF-8)";
 
sub raeSearch()
{
        my $rae = get("http://buscon.rae.es/draeI/SrvltGUIBusUsual?LEMA=$_[0]");
        my $resultado;
        while ($rae =~ m/name="[\d_]+"> (.*?) <\/p/smgix)
        {
                my $desc = $1;
                # Quitar las marcas HTML
                $desc =~ s/<.*?>//gsm;
                # Quitar los espacios a los lados
                $desc =~ s/^\s+//sm;
                $desc =~ s/\s+$//sm;
                # Quitar espacios excesivos
                $desc =~ s/\s+/ /gsm;
                $resultado .= "$desc\n";
        }
                return $resultado;
}
 
# Propiedades de ventana:
my $window = Gtk2::Window->new();
$window->set_title("Rae Search");
$window->set_border_width(3);
$window->signal_connect(destroy => sub{Gtk2->main_quit});
$window->set_auto_startup_notification(TRUE);
$window->set_decorated(TRUE);
$window->set_default_icon_from_file("camel.ico");
$window->move(0, 0);
$window->resize(700, 100);
$window->set_resizable(TRUE);
 
# Frame:
my $frame = Gtk2::Frame->new("Entrada");
 
# VBox:
my $vbox = Gtk2::VBox->new(FALSE, 10);
$vbox->pack_start($frame, TRUE, TRUE, 0);
 
# HBox:
my $hbox = Gtk2::HBox->new(FALSE, 6);
 
# Entry:
my $dir_entry = Gtk2::Entry->new_with_max_length(30);
$dir_entry->set_text("encono");
$dir_entry->set_activates_default(FALSE);
$dir_entry->set_position(100);
 
# Button:
my $button = Gtk2::Button->new("_Buscar");
$button->set_focus_on_click(TRUE);
my $rae;
 
# TextView  : 
my $textview = Gtk2::TextView->new();
$textview->set_cursor_visible(TRUE);
$textview->set_border_window_size('top', 1);
$textview->set_justification('fill');
my $textbuffer = $textview->get_buffer;
my $textiter = $textbuffer->get_end_iter;
$button->signal_connect(clicked => sub
        {
                $textbuffer->insert($textiter, &raeSearch($dir_entry->get_text));
                $textview->set_buffer($textbuffer);
        }
);
 
# Scroll Window : 
 
my $scroll = Gtk2::ScrolledWindow->new();
$scroll->set_policy('automatic', 'automatic');
 
$scroll->add($textview);
 
$vbox->pack_end($scroll, TRUE, TRUE, 0);
 
$frame->add($hbox);
 
$hbox->pack_start($dir_entry, FALSE, FALSE, 0);
$hbox->pack_start($button, FALSE, FALSE, 0);
 
$window->add($vbox);
$window->show_all;
Gtk2->main;
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

Cualquier sugerencia es bien recibida.

por **panterozo** » 2010-04-05 10:16 @469

Esta muy bueno tu programa Leo_Gutierrez

Foro - Perl en Español

Dudas con HTML::Parser

Re: Dudas con HTML::Parser

Publicidad

Re: Dudas con HTML::Parser

Re: Dudas con HTML::Parser

Re: Dudas con HTML::Parser

Re: Dudas con HTML::Parser

Re: Dudas con HTML::Parser

Re: Dudas con HTML::Parser

Me rindo.

Re: Dudas con HTML::Parser

Re: Dudas con HTML::Parser

¿Quién está conectado?