Foro - Perl en Español

por **jcarranza** » 2010-04-20 15:07 @671

¡Hola!

Quiero hacer una comunicación cliente-servidor por sockets de tal forma que:

1. al conectarse el cliente se muestre un mensaje en el servidor de CLIENTE CONECTADO (esto ya lo he conseguido),

2. desde el cliente escribo una cadena de texto que envío al servidor para que lo procese y lo convierta a mayúsculas,

3. y el servidor envía al cliente la cadena en mayúsculas.

Y FALLO EN EL TERCER PUNTO.

¿Cómo lo consigo? Tengo este código hecho:

SERVIDOR:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl -w
 
#servidor
 
use IO::Socket;
system ("title SERVIDOR");
 
$puerto = 9000;
$protocolo="tcp";
 
$servidor = IO::Socket::INET->new(
    Proto       => $protocolo,
    LocalPort   => $puerto,
    Listen      =>  1,
    Reuse       =>  1,
);
 
die "No puedo configurar el Servidor" unless $servidor;
 
system("cls");
system ("color a");
 
print "\n";
print scalar(localtime); print "\n\n";
print "[Servidor INICIADO]\n\n";
print "Puerto de comunicaciones: $puerto \n\n";
print "Esperando conexiones remotas...\n\n";
# $|++;
 
while( $remoto = $servidor->accept() ) #se mantiene a la espera de conexiones cliente
{
    $remoto->autoflush(1); 
        #activar el autoflush(), para que el envío de mensajes sea por cada línea, y no por bloques.
    print "\nNuevo Cliente conectado!\n";
 
    while($datos_cliente = <$remoto> ) 
        {
                print "Cadena recibida: $datos_cliente";
                print "Cadena transformada por el servidor: ";
                $datos_cliente=uc($datos_cliente);
                print $datos_cliente; print "\n\n";
    }
}
 
close $servidor;
Coloreado en 0.006 segundos,  usando GeSHi 1.0.8.4

CLIENTE

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl -w
#CLIENTE MUY SENCILLO
 
use IO::Socket;
system ("title CLIENTE");
 
$puerto = 9000;
$protocolo="tcp";
 
$cliente = IO::Socket::INET->new(
    Proto       => $protocolo,
    PeerAddr    => "localhost",
    PeerPort    =>  $puerto,
    Reuse       =>  1, 
);
 
die "problema" unless $cliente;
 
system ("cls");
 
print scalar(localtime); print "\n\n";
print "[Cliente INICIADO]\n\n";
print "Puerto de comunicaciones: $puerto \n\n";
 
 
print "Introduce un texto para enviar: ";
$mensaje = <STDIN>;
print $cliente $mensaje; #envío el mensaje al servidor a través del socket abierto.
 
close $cliente or die "close: $!";
 
print "\nSOCKET Cerrado\n";
print "Pulse INTRO para continuar";
$nada=<STDIN>;
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

Gracias, efectivamente, esto era lo que ponía pero en el sitio equivocado en el código del servidor... lo ponía fuera del bucle foreach().

Ahora funciona perfectamente.

En este mismo sentido, me gustaría que si le paso una cadena en minúsculas, el servidor me la devuelva en mayúsculas y si es una cadena en mayúsculas la que paso, que el servidor me la devuelva en minúsculas. ¿Cómo es esto?, ¿cómo sabe perl cuándo una cadena es en mayúsculas o en minúsculas y obrar en consecuencia?

¡¡Saludos!!

por **explorer** » 2010-04-21 05:00 @250

Perl no lo sabe. Es cuestión de saber antes en qué codificación estamos trabajando.

Tienes más información en perllocale, en concreto, donde hace referencia a la categoría LC_CTYPE.

Con el módulo POSIX, tienes dos funciones que te dicen si un carácter o cadena está escrito en minúsculas o mayúsculas: islower() y isupper(), pero no funciona con caracteres Unicode con valor superior a 255. Se recomienda usar las expresiones regulares /[[:lower:]]/ y /[[:upper:]]/.

Creo recordar que hay algún módulo más en CPAN, que también pueda dar esta información.

por **jcarranza** » 2010-04-21 16:03 @711

Hola,

anteriormente codifiqué un socket para enviar una cadena al servidor y que éste lo devolviera al cliente de una determinada forma. Y pensando un poco en esta potencialidad, ¿se puede enviar un archivo (PDF, txt, JPG) desde el cliente al servidor o viceversa? ¿Cómo sería el código?

¡¡Saludos!!

por **creating021** » 2010-04-21 18:47 @824

¡Claro qué se puede!

¿Cómo sería el código?

Creo que es obvio que eso depende del protocolo o sistema de envío y recepción que estás usando.

Aquí hay un servidor "semihttp" con unos cuantos bugs :roll:

como ejemplo de que es posible, de hecho puedes implementar cualquier protocolo de comunicaciones usando sockets, es más ya existe algunos programas en Perl que hacen justamente eso:
Sólo mira esta lista :wink:

por **jcarranza** » 2010-04-22 01:20 @097

¿Y cuál sería el código para enviar un PDF desde el cliente?

Hola,
estoy programando un sencillo socket cliente-servidor de tal forma que al conectarse el cliente en el servidor aparece el mensaje 'Nuevo cliente conectado'. El cliente, a su vez, recibirá un mensaje de que se ha conectado al servidor.

¿Cómo puedo programarlo de tal forma que el servidor no deje de ejecutarse (no salga a MSDOS) en espera de otros clientes? El cliente preguntará si se quiere abandonar o seguir conectado. Aquí les dejo el código que tengo: he sustituido WHILE por IF en el bucle del servidor ya que sino el cliente se quedaba bloqueado y no recibía el mensaje enviado por el servidor.

De momento tengo implementado el socket básico:

SERVIDOR

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl -w
 
#servidor
 
use IO::Socket;
system ("title SERVIDOR 4.1a");
 
$puerto = 9000;
$protocolo="tcp";
 
$servidor = IO::Socket::INET->new(
    Proto       => $protocolo,
    LocalPort   => $puerto,
    Listen      =>  1,
    Reuse       =>  1,
);
 
die "No puedo configurar el Servidor" unless $servidor;
 
system("cls");
system ("color a");
 
print "\n";
print scalar(localtime); print "\n\n";
print "[Servidor INICIADO]\n\n";
print "Puerto de comunicaciones: $puerto \n\n";
print "Esperando conexiones remotas...\n\n";
# $|++;
 
 
$mensaje="Conexión establecida con el servidor!!";
 
while ($remoto = $servidor->accept() ) #se mantiene a la espera de conexiones cliente
{
    $remoto->autoflush(1); 
        #activar el autoflush(), para que el envío de mensajes sea por cada línea, y no por bloques.
        
        #para cada conexión entrante muestro en el servidor un mensaje y envío un comunicado al cliente
    print "\nNuevo Cliente conectado!\n";
        print $remoto $mensaje;
}
 
 
close $servidor;
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

CLIENTE

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl -w
#CLIENTE MUY SENCILLO
 
use IO::Socket;
system ("title CLIENTE 4.1a");
 
$contador=0;
$puerto = 9000;
$protocolo="tcp";
 
$cliente = IO::Socket::INET->new(
    Proto       => $protocolo,
    PeerAddr    => "localhost",
    PeerPort    =>  $puerto,
    Reuse       =>  1, 
 
);
 
die "problema" unless $cliente;
 
system ("cls");
 
print scalar(localtime); print "\n\n";
print "[Cliente INICIADO]\n\n";
print "Puerto de comunicaciones: $puerto \n\n";
 
$|++; #La caché está activada por defecto. Para quitarla, basta con hacer $|++
 
 
#recibiendo el mensaje del servidor y lo muestro en pantalla
$mensaje = <$cliente>; 
print "$mensaje";  #mostrandolo en pantalla
print "\n";
 
 
 
while ($contador==0)
{
        print "Desea salir (S/N)?: ";
        $salida= <STDIN>;
        chop($salida);
 
        if ($salida eq "S" or $salida eq "s")
        {
                $contador=1;
                print "Ha decidido cerrar la comunicacion: \n";
                close $cliente or die "close: $!";
                print "\nSOCKET Cerrado\n";
                print "Pulse INTRO para continuar";
                $nada=<STDIN>;
                exit;
        }
        
        else
        {
                $contador=0;
                print "OK. Sigue conectado al servidor \n";
                
        }
 
}
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

por **explorer** » 2010-04-22 02:52 @161

Pero... ¿es obligatorio usar IO::Socket?

Estoy con creating021: es mejor usar un servidor ya hecho. Por ejemplo, para el intercambio de ficheros, puedes usar Net::FTPServer en el lado del servidor, y luego, en el lado del cliente, puedes usar cualquier cliente de FTP.

Si lo que quieres es aprender a manejar IO::Socket, primero debes leerte la página dedicada a ello, aunque un poco antigua. Ahí encontrarás clientes y servidores que se conectan de diversas formas. Algunas de ellas incluyen las opciones de reutilizar las conexiones en bucles, que es lo que responde a tu segunda pregunta, pero yo creo que ya lo tienes hecho.

Mira, estos son dos ejemplos muy sencillos. El servidor está siempre funcionando, mientras que el cliente cierra en cuanto transmite la cadena.

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl -w
 
use IO::Socket;
 
my $server = IO::Socket::INET->new(
    Proto       => 'tcp',
    LocalPort   =>  5800,
    Listen      =>  1,
    Reuse       =>  1,
);
 
die "No puedo configurar servidor" unless $server;
print "Server $0 aceptando clientes...\n";
 
$|++;
 
while( $cliente = $server->accept() ) {
    $cliente->autoflush(1);
    print "Cliente Conectado\n";
    while(  defined( $line = <$cliente> )  ) {
        print $line;
    }
    print "Cliente Desconectado\n";
    close $cliente;
}
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl -w
 
use IO::Socket;
 
$sock = IO::Socket::INET->new(
    PeerAddr    => "localhost",
    PeerPort    =>  5800,
    Proto       => 'tcp',
    Timeout     =>  1,
);
die "problema" unless $sock;
 
print "Introduce texto para mandar: ";
$msg = <STDIN>;
print $sock $msg;
close $sock;
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Para el intercambio de ficheros, en lugar de usar print(), deberás cambiar el modo de transmisión a binario con binmode(), y luego usar syswrite() sobre el canal. En el lado del cliente, al revés, usar sysread().

Actualización: aquí hay unos ejemplos para transmitir un fichero.

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use strict;
use warnings;
 
use IO::Socket;
 
$|++;
 
my $server = IO::Socket::INET->new(
    Proto       => 'tcp',
    LocalPort   =>  5800,
    Listen      =>  1,
    Reuse       =>  1,
);
 
die "No puedo configurar servidor" unless $server;
print "Servidor $0 aceptando clientes...\n";
 
while( my $cliente = $server->accept() ) {
 
    $cliente->autoflush(1);
 
    print "Cliente conectado. Esperamos nombre de fichero\n";
 
    my    $fichero = <$cliente>;
    chomp $fichero;
 
    if (! -e $fichero) {
        print $cliente "ERROR: no encuentro ese fichero\n";
        next;
    }
 
    print $cliente "Ok\n";
 
    my $largo = -s $fichero;
 
    print "Transmitiendo fichero $fichero al cliente ($largo bytes)\n";
 
    open my $FICHERO, q[<], $fichero  or next;  # Abrimos el fichero
    binmode $FICHERO;
    sysread $FICHERO, my($buffer), $largo;      # y lo leemos
    close   $FICHERO;
 
    binmode  $cliente;
    syswrite $cliente, $buffer, $largo;         # y lo enviamos
}
continue {
    print "Cliente desconectado\n";
 
    close $cliente;
}
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use strict;
use warnings;
 
use IO::Socket;
 
$|=1;
 
my $sock = IO::Socket::INET->new(
    PeerAddr    => "localhost",
    PeerPort    =>  5800,
    Proto       => 'tcp',
    Timeout     =>  1,
);
die 'Problema en la conexión' unless $sock;
 
print "Introduce fichero a leer: ";
 
my    $fichero = <STDIN>;
chomp $fichero;
 
print $sock "$fichero\n";
 
my    $respuesta = <$sock>;
print $respuesta;
chomp $respuesta;
 
if ($respuesta eq 'Ok') {
 
    binmode $sock;
 
    open my $FICHERO, q[>], "$fichero.new" or die "ERROR: No puedo escribir el fichero\n";
    binmode $FICHERO;
 
    while (sysread $sock, my $buffer, 10000) {       # vamos leyendo en bloques de 10k
        print $FICHERO $buffer;
        print '.';
    }
 
    print "\n";
 
    close  $FICHERO;
}
 
close $sock;
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Foro - Perl en Español

SOCKET para enviar un archivo

SOCKET cliente-servidor

Publicidad

Re: SOCKET cliente-servidor

Re: SOCKET cliente-servidor

Re: SOCKET cliente-servidor

SOCKET para enviar un archivo

Re: SOCKET para enviar un archivo

Re: SOCKET para enviar un archivo

Re: SOCKET para enviar un archivo

¿Quién está conectado?