Foro - Perl en Español

por **jcarranza** » 2010-04-26 08:23 @391

Hola, me gustaría hacer una comunicación cliente-servidor para que desde el cliente se pasen comandos al servidor (fecha, usuarios, salir). En concreto:

1. Los comandos permitidos son:
fecha: Muestra la fecha y hora actual del servidor
usuarios: Muestra los usuarios activos del sistema (asumiremos
2. que el servidor se ejecuta en un sistema compatible con UNIX y
que posee el comando who).

* La comunicación se llevará a cabo de la siguiente manera (cada envío,
del servidor o del cliente, finalizará con un salto de línea):
+ Al recibir la conexión del cliente, el servidor enviará el mensaje
"Bienvenido.".
+ El cliente enviará el comando deseado ("fecha" o "usuarios").
+ En caso de tratarse de un comando válido, el servidor responderá
con "OK" seguido del resultado de la ejecución del mismo (el cual
puede constar de varias líneas) y luego el mensaje "FIN".
+ En caso de recibir un comando erróneo, el servidor responderá
con el mensaje "ERR".
+ En cualquier caso, el servidor volverá a esperar otro comando.
+ Si el cliente envía el comando "salir" el servidor responderá con
el mensaje de despedida "Adiós." y cerrará la conexión.

La conexión puede ser cerrada por el cliente en cualquier momento, sin que esto afecte el estado del servidor.

De momento he programado esto pero me he hecho un lío con tantas modificaciones que he hecho y por ello ¡¡solicito ayuda!!

SERVIDOR

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl -w
 
use IO::Socket;
$|++;
require "mis_funciones.pl";
 
 
 system("cls");
 system ("title SERVIDOR 5.1");
 
 
$puerto = 2222;
$protocolo='tcp';
 
$servidor = IO::Socket::INET->new(Proto    =>$protocolo,
                                  LocalPort=>$puerto,
                                  Listen   =>SOMAXCONN,
                                  Reuse    =>1)
            or die "Error al iniciar el servidor";
 
 
                        
system ("color a");
print "\n";
print scalar(localtime); print "\n\n";
print "[Servidor INICIADO] --> ";
print "Puerto de comunicaciones: $puerto \n\n";
print "->Esperando conexiones...\n\n";
 
while ($conexion = $servidor->accept()) 
{
        $ip = $conexion->peerhost;
        print "[Conexion establecida desde $ip]\n";
        print $conexion "SERVIDOR: Bienvenido.\n"; #mensaje de bienvenida que envío al cliente
        
    do 
        {
        if ($comando = <$conexion>) #si el cliente ha introducido un comando
                {
            $comando =~ s/\r\n|\n//g; #elimino el fin de línea al final de la cadena leída
                        ejecutar($comando, $conexion);
        } 
                else 
                {
            $comando = 'salir';
        }
    } 
        until ($comando eq 'salir');
        
        
    $conexion->shutdown(2);
    print "[Conexion finalizada desde $ip]\n\n";
}
Coloreado en 0.005 segundos,  usando GeSHi 1.0.8.4

MIS_FUNCIONES

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

sub ejecutar($$) 
{
        #capturamos las variables llamadas
        $comando =shift;
        $conexion =shift;
        #inicializamos la variable resultado
        $resultado = '';
        
        
        if ($comando eq 'fecha') 
                { $resultado = localtime() . "\n";} 
                
        elsif ($comando eq 'usuarios') 
                { $resultado = 'who' . "\n";} 
                
        elsif ($comando eq 'salir') 
                { $resultado= "Gracias por usar este servicio. Adiós.\n";} 
                
        else 
        {
        print $conexion "ERR\n";
    }
        
        
        
    if ($resultado) 
        {
        print "Valor de resultado= $resultado \n";
        print $conexion "OK\n";
        print $conexion $resultado;
        print $conexion "FIN\n";
    } 
        
 
}
1;
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

CLIENTE

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl -w
 
use IO::Socket;
 
$servidor='localhost';
$puerto=2222;
 
system("cls");
system("title CLIENTE 5.1");
 
 
$conexion = new IO::Socket::INET(PeerAddr => $servidor,
                                 PeerPort => $puerto,
                                 Proto => 'tcp')
 
or die "Error al conectar con el SERVIDOR $servidor \n";
 
 
#mensaje que captura el cliente enviado por el servidor
$mensaje = <$conexion>;
print "$mensaje"; 
print "\n";
 
 
print "Introduce el comando: ";
$comando=<STDIN>;
 
 
$estado = <$conexion>;
print "$estado \n";
 
if ($estado eq "OK\n") {
    $salida = <$conexion>;
    while ($salida ne "FIN\n") {
        print $salida;
        $salida = <$conexion>;
    }
} elsif ($estado eq "ERR\n") {
    print "Comando no valido\n";
} else {
    print "Error en el servidor\n";
}
print $conexion "salir\n";
 
$mensaje = <$conexion>;
$conexion->shutdown(2);
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

En el hilo que tu mismo abriste, llamado "SOCKET para enviar un archivo", te puse un enlace a una página de LinuxJournal (mensaje del día 2010-04-22 09:52 CET @452), donde repasa el funcionamiento de Socket en Perl.

Vienen varios ejemplos. En el apartado Bidirectional Communication, se comenta el ejemplo de un servidor que responde a los comandos enviados desde un cliente. En el listado 5 tienes el servidor, y en el listado 6, el cliente.

Viendo tu código por encima, creo que estás muy cerca.

por **jcarranza** » 2010-04-27 01:04 @086

¡Hola!
He estado todo el día de ayer con esto y nada, que no me sale. He leído la web que me recomendaste pero sigue fallándome.

Mira a ver si echas un vistazo al código y a ver si es posible que me aportes una solución. ¡¡¡¡Espero con impaciencia!!!!

¡¡¡Saludos!!!

por **explorer** » 2010-04-27 02:58 @165

No he visto que hayas cambiado el código.

Recuerda que puedes editar tus propios mensajes, pulsando en el botón que aparece en el mensaje, abajo a la derecha, donde pone "Editar mensaje".

Pones el nuevo código, y vemos lo que llevas hecho hasta ahora.

Otra forma, es empezar con los listados que te he indicado, ya que funcionan muy bien.

No lo he visto en profundidad, pero parece que hay un problema en el orden de los mensajes en que se intercambian el servidor y el cliente.

por **jcarranza** » 2010-04-28 03:55 @205

¡¡Hola, explorer!!

¿Y cómo lo codificarías correctamente bajo tu punto de vista?
¡¡Este script lo he viciado de tantos cambios aquí y allá!!

¡¡¡Saludos!!!

por **jcarranza** » 2010-04-29 02:19 @138

Hola, creo que he avanzado algo. Sin embargo, no sale como a mí me gustaría:

1. quiero que al introducir un comando válido desde el cliente que aparezca la respuesta así:

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

               OK

               <<la respuesta>>

               FINColoreado en 0.000 segundos,  usando GeSHi 1.0.8.4

pero el FIN no me aparece y eso que se lo paso al socket.

2. me gustaría ir insertando comandos en el cliente y que no se saliera a la consola hasta que no se introduzca el comando 'salir'.

Aquí dejo el código que he programado hasta ahora:

SERVIDOR

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl -w
 
use IO::Socket;
$|++;
require "mis_funciones.pl";
use Sys::Hostname;
 
 system("cls");
 system ("title SERVIDOR 5.1");
 
 
$puerto = 2222;
$protocolo='tcp';
 
$servidor = IO::Socket::INET->new(Proto    =>$protocolo,
                                  LocalPort=>$puerto,
                                  Listen   =>SOMAXCONN,
                                  Reuse    =>1)
            or die "Error al iniciar el servidor";
 
 
                        
system ("color a");
print "\n";
print scalar(localtime); print "\n\n";
print "[Servidor INICIADO] --> ";
print "Puerto de comunicaciones: $puerto \n\n";
print "->Esperando conexiones...\n\n";
 
while ($conexion = $servidor->accept()) 
{
        $ip = $conexion->peerhost;
        print "[Conexion establecida desde $ip]\n";
        print $conexion "SERVIDOR: Bienvenido "; print $conexion hostname() . "\n"; #mensaje de bienvenida que envío al cliente
        
    do 
        {
        if ($comando = <$conexion>) #si el cliente ha introducido un comando y lo captura el servidor
                {
            $comando =~ s/\r\n|\n//g; #elimino el fin de línea al final de la cadena leída
                        ejecutar($comando, $conexion);
        } 
                else 
                {
            $comando = 'salir';
        }
    } 
        until ($comando eq 'salir');
        
        
    $conexion->shutdown(2);
    print "[Conexion finalizada desde $ip]\n\n";
}
Coloreado en 0.003 segundos,  usando GeSHi 1.0.8.4

MIS-FUNCIONES

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

sub ejecutar($$) 
{
        #capturamos las variables llamadas
        $comando =shift;
        $conexion =shift;
        #inicializamos la variable resultado
        $resultado;
        
        
        if ($comando eq 'fecha') 
                { $resultado = localtime() . "\n";} 
                
        elsif ($comando eq 'usuarios') 
                { $resultado = 'who' . "\n";} 
                
        elsif ($comando eq 'salir') 
                { $resultado= "Gracias por usar este servicio. Adios.\n";} 
                
        else 
        {
        print $conexion "ERROR\n";
    }
        
        
        
    if ($resultado) 
        {
 
                print $conexion "OK\n";
                print $conexion $resultado;
                print $conexion "\nFIN\n";
    } 
        
 
}
return 1;
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

CLIENTE

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl -w
 
use IO::Socket;
 
 
$servidor='localhost';
$puerto=2222;
 
system("cls");
system("title CLIENTE 5.1");
 
 
 
$conexion = new IO::Socket::INET(PeerAddr => $servidor,
                                 PeerPort => $puerto,
                                 Proto => 'tcp')
 
or die "Error al conectar con el SERVIDOR $servidor \n";
 
 
#mensaje que captura el cliente enviado por el servidor
$mensaje = <$conexion>;
print "$mensaje"; 
print "\n";
 
 
print "Introduce el comando: ";
$comando=<STDIN>;
print $conexion $comando;
 
 
$estado = <$conexion>;
print "$estado \n";
 
if ($estado eq "OK\n") 
{
    $salida = <$conexion>;
    while ($salida ne "FIN\n") 
        {
        print $salida;
        $salida = <$conexion>;
    }
        
} 
 
elsif ($estado eq "ERROR\n") 
{
    print "Este Comando no es valido\n";
} 
 
else 
{
    print "Error en el servidor\n";
}
 
print $conexion "salir\n";
 
$mensaje = <$conexion>;
$conexion->shutdown(2);
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

por **explorer** » 2010-04-29 05:56 @289

Pero si no es tan complicado... es cuestión de seguir, una a una, las líneas de los listados que te he indicado...

Cliente:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use 5.010;
use strict;
use warnings;
 
use IO::Socket;
 
my $sock = IO::Socket::INET->new(
    PeerAddr    => "localhost",
    PeerPort    =>  5800,
    Proto       => 'tcp',
    Timeout     =>  1,
) or
    die "Problema al crear la conexión. $!";
 
STDOUT->autoflush(1);
$sock ->autoflush(1); # No es necesario porque está activo por defecto
 
while ($sock->connected) {
 
    print "Comando: ";
    my $comando = <STDIN>;
 
    print $sock $comando;               # comando
 
    print scalar <$sock>;               # respuesta
 
    last if $comando =~ /salir/;
 
}
 
close $sock;
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Servidor:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use 5.010;
use strict;
use warnings;
 
use IO::Socket;
 
 
# Crear servidor
my $servidor = IO::Socket::INET->new(
    Proto       => 'tcp',
    LocalPort   =>  5800,
    Listen      =>  1,
    Reuse       =>  1,
) or
    die "No puedo configurar servidor. $!";
 
say "Servidor $0 aceptando clientes...";
 
# No caché en salida
STDOUT->autoflush(1);
$servidor->autoflush(1);
 
# Bucle sin fin
while (my $conexion = $servidor->accept()) {
    say 'Cliente conectado. Esperando comandos.';
 
    while (defined(my $comando = <$conexion>)) {
        chomp $comando;
 
        say "Procesando [$comando]";
 
        my $respuesta = procesa($conexion, $comando);
 
        given ($respuesta) {
            when ('salir') {
                say $conexion 'Fin de sesión';
                say           'Fin de sesión';
                last;
            }
            when ('error') {
                say $conexion "ERROR. Los comandos permitidos son 'fecha', 'usuarios' y 'salir'";
            }
            default {
                say $conexion $respuesta;
            }
        }
    }
 
    say 'Cliente desconectado.';
    close $conexion;
}
 
sub procesa {
    my ($conexion, $comando) = @_;
 
    given ($comando) {
        when ('fecha') {
            return scalar localtime;
        }
        when ('usuarios') {
            # Componemos la lista de usuarios a partir de las líneas devueltas por 'who'
            # que, justamente, es lo que hace el comando 'users'
            return join q[ ], map { (split)[0] } qx(who);
        }
        when ('salir') {
            return 'salir';
        }
        default {
            return 'error';
        }
    }
}
 
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

por **jcarranza** » 2010-04-30 03:09 @173

Gracias Explorer, tu ejemplo me ha servido para depurar mis errores.
No lo he hecho así pero me has ayudado sobresalientemente, sobre todo en la forma de ordenar los mensajes atendiendo al resultado que se procesa.

¡¡Y tu ejemplo va de fábula!!

¡¡Mil gracias!!

Foro - Perl en Español

Paso de comandos a través de un socket

Paso de comandos a través de un socket

Publicidad

Re: Paso de comandos a través de un socket

Re: Paso de comandos a través de un socket

Re: Paso de comandos a través de un socket

Re: Paso de comandos a través de un socket

Re: Paso de comandos a través de un socket

Re: Paso de comandos a través de un socket

Re: Paso de comandos a través de un socket

¿Quién está conectado?