Foro - Perl en Español

por **ccorrales001** » 2010-06-07 06:34 @315

Hola, perleros,
tengo una pequeña duda, a ver si me la podéis resolver.

Tengo hecha una aplicación que tiene un total de 4 interfaces encadenadas. Es decir, empieza con una interfaz en la que el usuario elige un idioma, y se le abre otra interfaz dependiendo del idioma, en la cual debe elegir otras opciones etc.

Lo que deseo es que una vez elegido el idioma, en la nueva interfaz que se abre, poner un botón de "atrás", es decir, que vuelva a la interfaz anterior.

He probado distintas opciones, pero en vez de destruirme esta interfaz, sale del programa. También he probado a hacer otra vez la llamada a la interfaz anterior, pero lógicamente, en vez de destruirme ésta, me vuelve a crear la anterior.
Este es la parte del código correspondiente a ese botón:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

my$hbox= Gtk2::HBox->new(0, 0);
$hbox->set_border_width(5);
$hbox->set_size_request(100,50);
my$boton_atras= Gtk2::Button->new_from_stock('Atrás');
$boton_atras->signal_connect('clicked'=>sub{ Gtk2->main_quit;});
$hbox->pack_start($boton_atras, FALSE, FALSE, 2);
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

Esta opción es la que me saca de la aplicación entera. No sé si me he explicado bien. Espero que me puedan ayudar.
Saludos.

No...

A ver, yo no conozco mucho de Gtk2, pero los interfaces gráficos se parecen mucho unos a otras...

Yo, lo que entiendo, es que si quiero que desde una ventana aparezca otra, y al desaparecer la segunda vuelva a aparecer la primera, se me ocurren dos opciones básicas:

* la segunda es llamada desde la primera, como una subrutina, por lo que al cerrarse, me devuelve el control

* la primera llama a la segunda, y termina. Y la segunda, cuando termine, que abra de nuevo la primera.

No sé si te estoy liando más. Quería decir que en vez de mandar cerrar la aplicación cuando el usuario cierra la ventana, lo que hacemos es, primero dar la orden de cerrarla y luego abrimos la siguiente ventana. Lo que no sé es si se pueden acumular llamadas de apertura y cierre de ventanas, en Gtk2, de esta manera.

¿Nos podrías enviar un ejemplo de código Gtk2 en la que se abra una ventana y ceda el control a una segunda?

por **ccorrales001** » 2010-06-08 06:36 @316

Hola explorer,
la primera opción es la que he estado intentando hacer todo este tiempo, es decir, a través de subrutinas. El problema es que no he averiguado cómo devolver el control a la primera interfaz, ya que lo único que consigo es cerrar toda la aplicación.

Este es el código:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

sub _init{
 
        my($ventana, $imagen, $footer, $opciones, $togglebutton1, $togglebutton2, $vbox);
 
        $ventana = Gtk2::Window->new('toplevel');
        $ventana->set_border_width(20);
        $ventana->set_title('Generador automático de resúmenes');
        
        $imagen = Gtk2::Image->new_from_file("informatica.jpg");
        $footer = Gtk2::Label->new( 'Choose language/ Elija idioma' );
 
        
        #Boton de cancelar
        my $hbox2 = Gtk2::HBox->new(0, 5);
        $hbox2->set_border_width(1);
 
        my $boton_cancelar = Gtk2::Button->new_from_stock('gtk-cancel');
        $boton_cancelar->signal_connect('clicked' => sub {Gtk2->main_quit; });
        $boton_cancelar->set_size_request(100, 30);
 
        #Boton de ayuda
        my $boton_ayuda = Gtk2::Button->new_from_stock('gtk-help');
        $boton_ayuda->signal_connect('clicked' => sub { &ayuda_idioma()});
        $boton_ayuda->set_size_request(100, 30);
        
        $hbox2->pack_start($boton_ayuda, FALSE, FALSE, 2);
        $hbox2->pack_start($boton_cancelar, FALSE, FALSE, 2);   
        
        sub ayuda_idioma{
                my $about = Gtk2::Dialog->new( 'Ayuda/Help', undef, 'modal',
                                   'Atrás' => 'ok' );
 
                my $text =<<INFO;
Tiene usted que elegir el idioma en el que desea realizar la búsqueda.
 
You have to choose the language in which you want to make the search.
                
INFO
 
                 # Podemos observar como un objeto Gtk2::Dialog contiene un vbox internamente
                 # para poder empaquetarle otros items.
 
                my $imagen = Gtk2::Image->new_from_file("ayuda2.png");
                $about->vbox->pack_start( $imagen, FALSE, FALSE, 4 );
                $about->vbox->pack_start( Gtk2::Label->new( $text ), FALSE, FALSE, 4 );
                $about->vbox->show_all;
 
                 # Simplemente, presionamos el botón y cerramos la ventana.
                 $about->destroy if $about->run;
                return TRUE;
 
 
 
        }
 
        #$opciones=&create_option_bar();
 
        my $hbox3 = Gtk2::HBox->new( FALSE, 0 );
 
        $togglebutton1 = Gtk2::ToggleButton->new_with_label('Castellano');
        $togglebutton2 = Gtk2::ToggleButton->new_with_label('English');
 
        $togglebutton1->set_size_request(100, 30);
        $togglebutton2->set_size_request(100, 30);
 
 
 
        $togglebutton1->signal_connect('clicked' => sub { &abrir_castellano() });
        $togglebutton2->signal_connect('clicked' => sub { &abrir_ingles() });
 
        $hbox3->pack_start( $togglebutton1, FALSE, FALSE, 3 );
        $hbox3->pack_start( $togglebutton2, FALSE, FALSE, 3 );
 
        my $separador = Gtk2::HSeparator->new();
        $separador->set_size_request(400, 30);
 
 
        $vbox = Gtk2::VBox->new( FALSE, 0 );
        $vbox->pack_start( $footer, FALSE, FALSE, 3 );
        $vbox->pack_start( Gtk2::HSeparator->new, FALSE, FALSE, 3 );
        $vbox->pack_start( $imagen, FALSE, FALSE, 3 );
        $vbox->pack_start( $hbox3, FALSE, FALSE, 3 );
        $vbox->pack_start( $separador, FALSE, FALSE, 3 );
        $vbox->pack_end( $hbox2, FALSE, FALSE, 3 );
        
 
        $ventana->add($vbox);
        $ventana->set_position('center');
        $ventana->show_all;
        return;
        
}
_init;
Gtk2->main;
 
sub abrir_ingles{
 
 
        my $ventana = Gtk2::Window->new('toplevel');
        $ventana->set_border_width(20);
        $ventana->set_title('Interface 2');
 
        my $imagen = Gtk2::Image->new_from_file("informatica.jpg");
        my $footer =  Gtk2::Label->new( 'Choose kind of summary' );
 
        
        #Boton de cancelar
        my $hbox2 = Gtk2::HBox->new(0, 0);
        $hbox2->set_border_width(5);
        my $boton_cancelar = Gtk2::Button->new_from_stock('gtk-cancel');
        $boton_cancelar->signal_connect('clicked' => sub {Gtk2->main_quit; });
        
        #Boton de ayuda
        my $boton_ayuda = Gtk2::Button->new_from_stock('gtk-help');
        $boton_ayuda->signal_connect( 'clicked' => \&about_this_ingles);
 
        $boton_ayuda->set_size_request(100, 30);
        $boton_cancelar->set_size_request(100, 30);
 
        $hbox2->pack_start($boton_ayuda, FALSE, FALSE, 2);
        $hbox2->pack_start($boton_cancelar, FALSE, FALSE, 2);
        
 
        #$opciones=&create_option_bar();
 
        my $togglebutton1 = Gtk2::ToggleButton->new_with_label('Free summary');
        my $togglebutton2 = Gtk2::ToggleButton->new_with_label('Most important paragraph');
        my $togglebutton3 = Gtk2::ToggleButton->new_with_label('10 lines');
 
        $togglebutton1->signal_connect('clicked' => sub { &abrir_resumen_libre_ingles() });
 
        $togglebutton2->signal_connect('clicked' => sub { &abrir_parrafo_mas_ingles() });       
 
        $togglebutton3->signal_connect('clicked' => sub { &abrir_10_lineas_ingles()});
 
        my $vbox1 = Gtk2::VBox->new( FALSE, 0 );
        $vbox1->pack_start( $togglebutton1, FALSE, FALSE, 3 );
        $vbox1->pack_start( $togglebutton2, FALSE, FALSE, 3 );
        $vbox1->pack_start( $togglebutton3, FALSE, FALSE, 3 );
 
        my $separador = Gtk2::HSeparator->new();
        $separador->set_size_request(400, 30);
 
                        
        my $vbox = Gtk2::VBox->new( FALSE, 0 );
        $vbox->pack_start( $footer, FALSE, FALSE, 3 );
        $vbox->pack_start( Gtk2::HSeparator->new, FALSE, FALSE, 3 );
        $vbox->pack_start( $imagen, FALSE, FALSE, 3 );
        $vbox->pack_start( $vbox1, FALSE, FALSE, 3 );
        $vbox->pack_start( $separador, FALSE, FALSE, 3 );
        $vbox->pack_start( $hbox2, FALSE, FALSE, 3 );
        
 
 
        $ventana->add($vbox);
        $ventana->set_position('center');
        $ventana->show_all;
        return;
}
Coloreado en 0.004 segundos,  usando GeSHi 1.0.8.4

Como ves, cada vez que pulsas te abre una subrutina, que es una nueva interfaz. Aquí me faltaría el botón de atrás, que es el que quiero agregar, pero de momento imagínate que en la interfaz principal, el de Cancelar es el de atrás.

por **explorer** » 2010-06-08 07:25 @350

Claro... llamar a main_quit() siempre termina la aplicación actual.

Lo que debes hacer es cerrar la ventana. Lo que no me acuerdo es si es con un destroy() o con otra función que tenga un nombre parecido. Vamos, sustituir main_quit() por la llamada que se encarga de cerrar la ventana.

Actualización: en la página de Gtk2::Window, pone que para destruir una ventana (sin salir de la aplicación), se puede llamar, efectivamente, a destroy(): $ventana->destroy(); .

Pero... hay algo aún más interesante: en vez de crear/destruir las ventanas, puedes, simplemente crearlas todas en el arranque (como tienes en el init()), pero haciendo que estén ocultas (hidden). Mostrarlas cuando haga falta, y, para ocultarlas

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

$dialog->signal_connect
(delete_event =>\&Gtk2::Widget::hide_on_deleteColoreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Así no son destruidas, solo ocultas, por lo que no hay que crearlas de nuevo.

por **ccorrales001** » 2010-06-08 09:33 @440

Gracias, explorer, lo probaré y te comento.
Un saludo.

por **explorer** » 2010-06-08 12:33 @564

Este es un ejemplo que muestra dos ventanas, en la que la segunda solo aparece a partir de la primera.

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use strict;
use warnings;
use diagnostics;
 
use Gtk2 '-init';
use Glib qw/TRUE FALSE/;
 
# Creamos el aspecto gráfico
our $ventana_secundaria;
 
sub salir_aplicacion {
    Gtk2->main_quit();
    exit;
}
 
sub esconde_ventana {
    $ventana_secundaria->hide();
    TRUE;
}
 
 
### Ventanas
 
## Primera ventana
my $ventana_principal = Gtk2::Window->new ('toplevel');
 
$ventana_principal->set_border_width(20);
$ventana_principal->set_title('Principal');
 
$ventana_principal->signal_connect(delete_event => \&salir_aplicacion);
 
$ventana_principal->set_position('center');
 
my $boton_salida = Gtk2::Button->new('Salir');
$boton_salida->signal_connect (clicked => \&salir_aplicacion);
 
my $boton_ventana_secundaria = Gtk2::Button->new('Secundaria');
$boton_ventana_secundaria->signal_connect('clicked' => sub { $ventana_secundaria->present });
 
 
my $hbox2 = Gtk2::HBox->new(0, 0);
$hbox2->set_border_width(5);
 
$hbox2->pack_start($boton_salida, FALSE, FALSE, 2);
$hbox2->pack_start($boton_ventana_secundaria, FALSE, FALSE, 2);
 
$ventana_principal->add($hbox2);
 
# Presentación de la ventana principal
$ventana_principal->show_all;
 
 
## Segunda ventana
$ventana_secundaria = Gtk2::Window->new ('toplevel');
 
$ventana_secundaria->set_border_width(20);
$ventana_secundaria->set_title('Secundaria');
 
$ventana_secundaria->set_position('center');
 
$ventana_secundaria->signal_connect(
    delete_event => \&esconde_ventana,
);
 
my $boton_salida2 = Gtk2::Button->new('Salir a principal');
$boton_salida2->signal_connect (
    clicked      => \&esconde_ventana,
);
 
my $hbox3 = Gtk2::HBox->new(0, 0);
$hbox3->set_border_width(5);
 
$hbox3->pack_start($boton_salida2, FALSE, FALSE, 2);
 
$ventana_secundaria->add ($hbox3);
 
$hbox3->show_all; # mandamos la señal de representar todos los objetos dentro
                  # de la ventana secundaria, antes de verlo en pantalla
 
# ¡Adelante!
Gtk2->main;
 
__END__
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

Lo curioso, y no he encontrado el porqué, es el muy distinto comportamiento que tiene la ventana secundaria si se esconde pulsando con el botón o con cerrándola: en un caso guarda la posición de pantalla, y en otra caso, no.

por **ccorrales001** » 2010-06-10 11:47 @532

Gracias explorer, me han servido tus aclaraciones.
Eres un crack, saludos.

Foro - Perl en Español

Gtk2, volver a una interfaz anterior

Gtk2, volver a una interfaz anterior

Publicidad

Re: Gtk2, volver a una interfaz anterior

Re: Gtk2, volver a una interfaz anterior

Re: Gtk2, volver a una interfaz anterior

Re: Gtk2, volver a una interfaz anterior

Re: Gtk2, volver a una interfaz anterior

Re: Gtk2, volver a una interfaz anterior

Re: Gtk2, volver a una interfaz anterior

Re: Gtk2, volver a una interfaz anterior

¿Quién está conectado?