Foro - Perl en Español

por **eandres25** » 2010-07-16 18:29 @811

Hola a todos, espero que esto esté bien posteado aquí, tengo un problema con el siguiente código, espero me ayuden.

No sé qué tiene mal mi código, pero hay algo fuera de lo normal. Sé que no es el mejor código del mundo y yo soy muy principiante en esto. Les pego el código:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

$scripts_dir = "/usr/local/bin/doc11";
open (ARCHIVO, "$scripts_dir/Equipos.txt");
 
$cant_equipos = 0;
         
@equipos=0;
 
while(<ARCHIVO>)
{
        chomp;
        my @line = split(/\t/);
 
        $num_args = 0;
        while ($num_args <= 1){
                $equipos[$cant_equipos][$num_args] = $line[$num_args];
                $num_args++;
        }
        $cant_equipos++;
}
close(ARCHIVO);
 
do {
       
        print "\nEscriba el numero del equipo que desea accesar:\n\n";
       
        for ($m = 0; $m < $cant_equipos; $m++){
                print "\t$m. $equipos[$m][0]\n";
        }
 
        print "\nDigite su eleccion y presione enter: ";
        $num_router=<STDIN>;
        chop($num_router);
       
}
while ($num_router < 0 || $num_router >= $cant_equipos);
 
 
if($num_router == 0){
die "Hasta Pronto\n";
}
 
else {
        $router = $equipos[$num_router][1];
        print "El router es: $router";
        print " antes era: $equipos[$num_router][1] \n";
        }
Coloreado en 0.004 segundos,  usando GeSHi 1.0.8.4

En la línea 45, estoy imprimiendo lo mismo, pero es a modo de prueba, pues al ejecutar el código me tira lo siguiente:

Escriba el numero del equipo que desea accesar:

0. Salir
1. Equipo1
2. Equipo2
3. Equipo3
4. Equipo4

Digite su eleccion y presione enter: 1
antes era: 172.16.1.1

Como ven, no está imprimiendo la primera vez, lo cual me parece raro y además no realiza las acciones que debe realizar más adelante, cosa que sí realiza bien con la otra versión del programa que tengo (ahora quiero poner los equipos en un archivo aparte para mayor flexibilidad y no cambiar el código al agregar equipos nuevos). El archivo contiene lo siguiente:

Salir 0
Equipo1 172.16.1.1
Equipo2 172.16.1.2
Equipo3 172.16.1.3
Equipo4 172.16.1.4

Los espacios en realidad son tabuladores.

Si realizo la impresión de manera distinta muestra otra cosa. Ejemplo:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

    else {
        $router = $equipos[$num_router][1];
        print "El router es: $router\nfafafa\n";
        print " antes era: $equipos[$num_router][1] \n";
}
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

El resultado es:

Escriba el numero del equipo que desea accesar:

0. Salir
1. Equipo1
2. Equipo2
3. Equipo3
4. Equipo4

Digite su eleccion y presione enter: 1
El router es: 172.16.1.1
fafafa
antes era: 172.16.1.1

Como ven, esto se aproxima un poco más a lo que quiero, pero no sé por qué no está interpretando bien.
Algo interesante es que absolutamente todo funciona muy bien al elegir la última opción, no sé si me estaré pasando algo por alto.

Digite su eleccion y presione enter: 4
El router es: 172.16.1.4 antes era: 172.16.1.4
Conectando al router...

Espere un momento...

ACTUALIZACION: Otra prueba, al agregar un retorno de carro al último equipo en el archivo externo me doy cuenta de que ya falla el programa y además me imprime el último octeto de la IP nuevamente:

Digite su eleccion y presione enter: 1
antes era: 172.16.1.4.4

Si en el archivo pongo 172.16.1.44 imprime 172.16.1.44.44

Espero haber sido claro. ¡Les agradezco mucho!

P.D.: Mi versión de Perl es: v5.8.4 built for i386-linux-thread-multi

Esto me suena a que hay algún retorno de carro al final del segundo campo de la línea, y eso hace que no lo veamos, ya que queda sobreescrito con el siguiente print().

Una forma de asegurarse de qué es lo que se está imprimiendo, es lo que has hecho: un print() por cada salida. Y además, poniéndolo entre corchetes, para ver hasta dónde llega cada una de ellas. Así no verás salidas mezcladas.

Por ejemplo:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
#use 5.010;
#use strict;
#use warnings;
#use diagnostics;
 
#use autodie;
 
my $scripts_dir = "/usr/local/bin/doc11";
 
## Lectura
my @equipos;
open my $ARCHIVO, q[<], "$scripts_dir/Equipos.txt";
while (<$ARCHIVO>) {
        chomp;
 
        push @equipos, [ split /\t/ ];
}
close   $ARCHIVO;
 
## Menú
my $num_router;
 
do {
    do {
        print "\nEscriba el número del equipo que desea acceder:\n\n";
 
        for my $i ( 0 .. $#equipos ) {
            print "\t$i\t$equipos[$i][0]\n";
        }
 
        print "\nDigite su elección y presione enter: ";
        chomp($num_router = <STDIN>);
 
    } while ($num_router eq ''  or  $num_router < 0  or  $num_router >= @equipos);
 
    if ($num_router) {
        my $router = $equipos[$num_router][1];
        print "El router es: [$router] Antes era: [$equipos[$num_router][1]]\n";
    }
} while ($num_router);
 
print "Hasta pronto\n";
 
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

por **eandres25** » 2010-07-19 17:47 @783

Mmm, me sale esto (con el código exactamente como lo pusiste):
] Antes era:[172.16.1.44

Es más, copié exactamente el mismo código en un archivo nuevo, sin todo lo que viene debajo y es ese resultado.

¡Gracias!

por **explorer** » 2010-07-20 03:05 @170

Entonces está claro... las líneas del fichero Equipos.txt tienen un carácter de retorno de carro, que es lo que hace el efecto de colocar el cursor al principio de la línea.

Si en el código hay un chomp(), entonces resulta que está eliminando un final de línea que no corresponde con el mismo final de línea del fichero.

Si, por ejemplo, edito el fichero Equipos.txt y le pongo finales de línea al estilo MSDOS:

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

explorer@joaquin:~/Documents/Desarrollo> hexdump -C kk.txt

00000000  53 61 6c 69 72 09 30 0d  0a 45 71 75 69 70 6f 31  |Salir.0..Equipo1|

00000010  09 31 37 32 2e 31 36 2e  31 2e 31 0d 0a 45 71 75  |.172.16.1.1..Equ|

00000020  69 70 6f 32 09 31 37 32  2e 31 36 2e 31 2e 32 0d  |ipo2.172.16.1.2.|

00000030  0a 45 71 75 69 70 6f 33  09 31 37 32 2e 31 36 2e  |.Equipo3.172.16.|

00000040  31 2e 33 0d 0a 45 71 75  69 70 6f 34 09 31 37 32  |1.3..Equipo4.172|

00000050  2e 31 36 2e 31 2e 34 0d  0a                       |.16.1.4..|

00000059Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

ves que los finales de línea son del tipo 0x0D, 0x0A (retorno de carro, avanza de línea).
Si este fichero se lo paso al programa, me sale la misma salida que a ti:

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

Digite su elección y presione enter: 1

] Antes era: [172.16.1.11Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

debido a que el chomp() ha eliminado solo los caracteres de avance de línea, ya que yo estoy ejecutando el programa en un ordenador con sistema operativo Linux, donde por defecto, los finales de línea se definen solo con el carácter avance de línea. Los caracteres de retorno de carro siguen estando ahí.

Lo que tenemos que hacer es quitar ese carácter de retorno de carro.

Hay varias soluciones...

1.- Podemos modificar la apertura del fichero para indicar cómo es ese fichero:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

open my $ARCHIVO, q[<:crlf], "kk.txt";
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Ahora Perl sabe que se trata de un fichero con líneas terminadas en crlf. El problema ahora es... ¿estamos seguros de que el fichero Equipos.txt SIEMPRE va a tener esos finales de línea?

2.- Modificamos el indicador de cómo son los finales de línea:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

{ local $/="\r\n";
# sigue lo mismo que antes: open(), while(), close()...
} # línea 21
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Aquí es necesario que modifiquemos el valor de $/ de forma local. Por eso hay que meter toda la operación entre llaves, para que no afecte luego a la operación de lectura del menú. Lo malo de esta operación es que tiene el mismo problema que el anterior.

3.- Quitar explícitamente el carácter que sobra:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

        chop;
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

También tenemos el mismo problema de antes.

4.- Quitar los caracteres finales mediante una expresión regular. Cambiamos la línea 15 por

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

        s/[\r\n]//g;
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Así, no nos importará cuáles sean los caracteres de final de línea que traigan las líneas de Equipos.txt, pues serán eliminados.

por **eandres25** » 2010-07-20 09:53 @453

Claro, ese fue el problema: también ejecuto el código en Linux, pero como en mi empresa se usa Windows entonces creé el documento de texto con Notepad++ en Windows y lo copié por sftp. Lo que hice ahora fue editar el archivo en Linux y el problema se solucionó. Es increíble los problemas que da el trabajar con Windows. Y claro, mi falta de experiencia en esto.

¡Muchas gracias nuevamente, Explorer!

Foro - Perl en Español

Problemas con código

Problemas con código

Publicidad

Re: Problemas con código

Re: Problemas con código

Re: Problemas con código

Re: Problemas con código

¿Quién está conectado?