Foro - Perl en Español

por **AUAtom4** » 2010-08-12 05:11 @257

Hola a todos, estoy intentando modificar un archivo de Fortran e imprimirlo en el orden que yo quiera.

El archivo es el siguiente:

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

simul_type : 1=Gibbs NVT, 2=NPT

 Molecular Weight

 Temperature

 step_init and step_final

 filename containing input data ? (Aopti.res...) (liquid before vapour)

 number of optimised force centres

  number of iterations =       85450

 centre de force :   1  Drho/Deps =  0.81097D+00

 centre de force :   1  Drho/Dsig = -0.24736D+03

 centre de force :   1  Drho/Ddelta = -0.13209D+03

 centre de force :   1  DdeltaH/Deps =  0.76866D+02

 centre de force :   1  DdeltaH/Dsig = -0.19117D+05

 centre de force :   1  DdeltaH/Ddelta = -0.10594D+05

 centre de force :   1  Dln(Psat)/Deps = -0.11212D-01

 centre de force :   1  Dln(Psat)/Dsig =  0.15036D+01

 centre de force :   1  Dln(Psat)/Ddelta =  0.11080D+01

 Drho/DalphaCharge =  0.00000D+00

 DdeltaH/DalphaCharge =  0.00000D+00

 Dln(Psat)/DalphaCharge =  0.00000D+00Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

La forma como debería quedar es la siguiente:

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

-0.11212D-01 !Dln(Psat)/Deps-Ethyl375K

0.15036D+01 !Dln(Psat)/Dsig-Ethyl375K

0.11080D+01 !Dln(Psat)/Ddelta-Ethyl375K

0.076866 !DdeltaH/Deps-Ethyl375K 

-19.117 !DdeltaH/Dsig-Ethyl375K 

-10.594 !DdeltaH/Ddelta-Ethyl375K 

0.81097D+00 !Drho/Deps-Ethyl375K

-0.24736D+03 !Drho/Dsig-Ethyl375K

-0.13209D+03 !Drho/Ddelta-Ethyl375KColoreado en 0.000 segundos,  usando GeSHi 1.0.8.4

Sin embargo mi script (que no es muy eficiente que digamos) me hace lo siguiente, es decir lo imprime en este orden:

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

0.81097D+00 !Drho/Deps-Ethyl375K

-0.24736D+03 !Drho/Dsig-Ethyl375K

-0.13209D+03 !Drho/Ddelta-Ethyl375K

0.076866 !DdeltaH/Deps-Ethyl375K 

-19.117 !DdeltaH/Dsig-Ethyl375K 

-10.594 !DdeltaH/Ddelta-Ethyl375K 

-0.11212D-01 !Dln(Psat)/Deps-Ethyl375K

0.15036D+01 !Dln(Psat)/Dsig-Ethyl375K

0.11080D+01 !Dln(Psat)/Ddelta-Ethyl375KColoreado en 0.000 segundos,  usando GeSHi 1.0.8.4

He intentado de varias formas pero no lo he logrado por eso decidí ingresarlo al foro. Mi código es el siguiente, ¿ alguna idea ?

Muchas gracias.

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

use Switch;
 
open(FILE,"deriv_pot_fin.dat") or die("Impossible to open the file");
open(OUT,">deriv_pot_fin.out") or die("Impossible to open the file");
$cont=0;
 
while($line=<FILE>){
    $line=~s/ //g; 
    $line=~s/^D//; 
    $line =~s/^centredeforce:1//;
    #@lin=<FILE>;
    if($line=~/^Dln/){    
        ($cadena, $numero)= split /=/, $line, 2; 
        chomp($numero);
        print OUT  "$numero !$cadena-Ethyl375K\n";    
    }
    
    if($line=~/^Dr/){    
        ($cadena, $numero)= split /=/, $line, 2; 
        chomp($numero);
        print OUT "$numero !$cadena-Ethyl375K\n";    
    }
    
    if($line=~/^DdeltaH/){    
        ($cadena, $numero)= split /=/, $line, 2; 
        $numero=~s/D/E/; 
        $numero/=1000; 
        chomp($numero);
        print OUT "$numero !$cadena-Ethyl375K \n";  
    }
    
    $cont ++;
 
}
 
close(FILE);
close(OUT);
Coloreado en 0.003 segundos,  usando GeSHi 1.0.8.4

Bienvenido a los foros de Perl en Español, AUAtom4.

Primero: no uses el módulo Switch. Se sabe que tiene errores. Lo más probable es que nunca sean corregidos, ya que existe una alternativa nativa desde Perl v5.10, con given/when.

Segundo. Por lo que veo en las salidas, consiste en cambiar el orden de la información que traen las líneas. La solución es que no imprimas las líneas a medida de que las vayas leyendo del fichero (que ese es el orden en que las estás pintando ahora), sino que las vas almacenando en memoria (por ejemplo en varios arrays, uno por cada sección de información). Y una vez terminado de leer y procesar el fichero, recorres los arrays y los imprimes según el orden en que quieres que salga la información.

Prueba, y si te atascas, pues déjanos otro mensaje.

por **AUAtom4** » 2010-08-24 03:30 @187

Gracias por responder explorer. En efecto, ya había intentado guardar las variables en un arreglo y al final imprimirlo, para lo cual cambiaba la variable $cadena a @cadena y lo mismo con la de número, y al final del programa le daba por ejemplo, un print(@cadena), pero lo que resulta es que solo está guardando la última línea en cada if().

Gracias de todas formas por la colaboración.

por **explorer** » 2010-08-24 04:50 @243

No es tan complicado...

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use 5.010;
 
### Almacenes
my @Drho;
my @DdeltaH;
my @Dln;
 
### Leemos fichero de entrada
open(FILE,"<deriv_pot_fin.dat") or die("Impossible to open the file\n");
 
while (my $line = <FILE>) {
 
    next if not $line =~ m/centre de force/;
 
    chomp $line;
 
    my ($tag, $value) = $line =~ m/(\S+) \s+ = \s+ (\S+)/x;
 
    given($tag) {
        when(/Drho/) {
            push @Drho,    [ $tag, $value ];
        }
        when(/DdeltaH/) {
            $value =~ s/D/E/;
            $value /= 1_000;
            push @DdeltaH, [ $tag, $value ];
        }
        when(/Dln/) {
            push @Dln,     [ $tag, $value ];
        }
    }
}
 
close FILE;
 
### Abrimos fichero de salida
open(OUT, ">deriv_pot_fin.out") or die("Impossible to open the file\n");
 
for my $item (@Dln) {
    say OUT $item->[1], ' !', $item->[0], '-Ethyl375K';
}
for my $item (@DdeltaH) {
    say OUT $item->[1], ' !', $item->[0], '-Ethyl375K';
}
for my $item (@Drho) {
    say OUT $item->[1], ' !', $item->[0], '-Ethyl375K';
}
 
close OUT;
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

que incluso puede quedar en

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use strict;
use warnings;
 
### Almacen
## Es un hash, cuyas claves son las distintas etiquetas,
## y los valores son arrays con las distintas líneas:
##
##  $lineas{Drho}[0] = [ 'Drho/Deps', '0.81097D+00' ];
##
my %lineas;
 
### Leemos fichero de entrada
open(FILE,"<deriv_pot_fin.dat") or die("Impossible to open the file\n");
 
while (my $line = <FILE>) {
 
    next if not $line =~ /centre de force/;
 
    chomp $line;
 
    my ($tag, $value) = $line =~ /(\S+) \s+ = \s+ (\S+)/x;
 
    if ($tag =~ m/(Drho|DdeltaH|Dln)/) {
        my $clave = $1;
 
        if ($clave eq 'DdeltaH') {      # caso especial
            $value =~ s/D/E/;
            $value /= 1_000;
        }
 
        push @{$lineas{$clave}}, [ $tag, $value ];
    }
}
 
close FILE;
 
### Abrimos fichero de salida
open(OUT, ">deriv_pot_fin.out") or die("Impossible to open the file\n");
 
for my $clave (qw(Dln DdeltaH Drho)) {
    for my $item (@{$lineas{$clave}}) {
        print OUT $item->[1], ' !', $item->[0], '-Ethyl375K', "\n";
    }
}
 
close OUT;
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

Foro - Perl en Español

Problemas imprimir orden de archivo script Perl

Problemas imprimir orden de archivo script Perl

Publicidad

Re: Problemas imprimir orden de archivo script Perl

Re: Problemas imprimir orden de archivo script Perl

Re: Problemas imprimir orden de archivo script Perl

¿Quién está conectado?