Foro - Perl en Español

por **Ultrix** » 2005-11-03 09:42 @446

Hola.

Estoy comenzando con Perl y tengo el siguiente problema:

Si tengo la siguiente variable:
$a = "12345678";

y quiero dejarla con separadores de miles, como:

$a = "12,345,678";

¿Cómo puedo hacer esto?

Muchas gracias.

$x = "12345678.344";
$num = int($x);                          # Nos quedamos con la parte entera
$dec = rindex($x,".");                   # Buscamos dónde empieza la parte decimal
$n = join "",reverse split //, $num;     # Damos la vuelta al número
$m = "";                                 # Aquí guardaremos el resultado
while ($n =~ m/(\d{1,3})/g )             # Para todo el número, buscamos bloques de entre 1 y 3 dígitos
{
    $m .= "$1,";                         # Guardamos ese bloque más un separador de miles
}
$m = join "",reverse split //, $m;       # Volvemos a dar la vuelta al calcetín. Perdón, al número
$m = substr( $m,1);                      # Quitamos el último separador de miles, pues sobra
print $m;                                # Pintamos la parte entera, con los separadores
print substr($x,$dec) unless $dec == -1; # Pintamos los decimales si existían
print "\n";
Coloreado en 0.003 segundos,  usando GeSHi 1.0.8.4

Otra forma es utilizando substr() en el lado izquierdo.

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

$x = "56789";
 
# Bucle para toda la longitud del número, empezando en la parte derecha, menos 3 (primer bloque de dígitos)
# y viendo cada 3 dígitos hacia la parte izquierda
for( $i=length($x)-3; $i>0; $i-=3 )
{
    # En esa posición metemos un separador de miles
    substr($x,$i,0) = ",";
}
print "$x\n";
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Otra forma es usando printf() con el modificador ('). Por ejemplo, printf("%'.2f", 1234567.89) con el locale puesto a da_DK genera 1.234.567,89.

Lo malo es que esto no funciona en todos los sistemas.

Otra forma... con un módulo... Number::Format:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

use Number::Format;
my $numero = "123456789";
my $formato = new Number::Format(
    -thousands_sep   => '.',
    -decimal_point   => ',',
);
my $formateado = $formato->format_number($numero);
print $formateado,"\n";
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

por **Ultrix** » 2005-11-03 13:35 @607

Gracias, explorer39... Viendo lo del .pm me decidí por esto... y funciona bien...

Bye...

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl

$num="123456789";
print"El Número que quiero procesar es: $num\n";

$integer='0'x(3 -(length($num)% 3)).$num;

$integer=join(",",grep{$_ne''}split(/(...)/,$integer));

$integer=~s/^0+//;
$integer=~s/^\,//;

print"Resultado: [$integer]\n";Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

por **explorer** » 2014-01-25 15:25 @684

Expresión regular para formatear "a mano" un número agrupando por los millares:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

$pop = 316792343.5678;
$pop =~ s/(?<!\.)(?:\b|\G)\d+?\K(?=(?:\d\d\d)+\b)/ /g;
 
say "[$pop]";    # [316 792 343.5678]
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Sacada del libro "Mastering Perl", 2Ed., O'Reilly, 2º capítulo.

Foro - Perl en Español

Separador de miles

Separador de miles

Publicidad

Separador de miles

Re: Separador de miles

¿Quién está conectado?