Foro - Perl en Español

por **millen** » 2011-11-30 06:15 @302

Buenas, llevo toda la mañana y no me sale, me desespero. Me gusta Perl, pero cuando me salen las cosas, ¡ja,ja!

A ver, tengo este hash de hashes y tengo que sacar de un organismo y de la base que me pida el usuario el porcentaje de la base.

Dadme alguna idea. Gracias.

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

print "¿Que quieres hacer:\n a)Imprimir todos los organismos por pantalla (pulsa a)\n b)Guardar la tabla en un fichero (pulsa b)\n c)Mostrar el porcentaje de bases de un determinado tipo que existen en un determinado organismo (pulsa c)\n" ;
$respuesta = <STDIN>;
chomp $respuesta;
 
if ($respuesta =~ /a/){
        print @organismo;}      
elsif ($respuesta =~ /b/){
        print "¿Como quieres que se llame el fichero?";
        $txt = <STDIN>;
        chomp $txt;
        open (TABLA, ">$txt");
        print TABLA @tabla;
        close TABLA;}
elsif ($respuesta =~ /c/){
        print "¿De qué organismo?";
        $organ = <STDIN>;
        chomp $organ;
        print "¿Y de qué base? (a, c, g o t)";
        $bas = <STDIN>;
        chomp $bas;     
}else {print "Error: vuelva a intentarlo e introduzca bien el caracter"}
 
 
Coloreado en 0.003 segundos,  usando GeSHi 1.0.8.4

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

%org = (
        $organismo  => {
                Adeninas => $a,
                Citosinas => $c,
                Guaninas => $g,
                Timinas => $t,
}
);
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

#!/usr/bin/perl
use strict;
use warnings;
use diagnostics;
use utf8;
use open qw(:utf8 :std);
 
use Data::Dumper;
 
my %organismos = (
    humano => {
        Adeninas  => 12,
        Citosinas => 34,
        Guaninas  => 56,
        Timinas   => 78,
    },
    mosca => {
        Adeninas  => 120,
        Citosinas => 340,
        Guaninas  => 560,
        Timinas   => 780,
    },
);
 
my %abr = ( A => 'Adeninas', C => 'Citosinas', G => 'Guaninas', T => 'Timinas' );
 
my $respuesta;
 
do {
    print '
¿Qué quieres hacer?
    a) Imprimir todos los organismos por pantalla
    b) Guardar la tabla en un fichero
    c) Mostrar el porcentaje de bases de un determinado tipo que existen en un determinado organismo
    0) Terminar
 
[Opción]: ';
 
    chomp($respuesta = <>);
    print "\n";
 
    if ( $respuesta eq 'a' ) {
        print Dumper \%organismos;
    }
    elsif ( $respuesta eq 'b' ) {
        print "¿Cómo quieres que se llame el fichero?";
        chomp(my $txt = <>);
        open( TABLA, ">$txt" );
        print TABLA Dumper \%organismos;
        close TABLA;
        print "Ok\n";
    }
    elsif ( $respuesta eq 'c' ) {
        print "¿De qué organismo? ";
        chomp(my $organismo = <>);
        if (!$organismos{$organismo}) {
            print "ERROR: No tengo ese organismo\n";
        }
        else {
            my $total = 0;
            for my $valor (values %{$organismos{$organismo}}) {
                $total += $valor;
            }
            print "¿Y de qué base? [A/C/G/T]:";
            chomp(my $bas = <>);
            $bas = uc($bas);
            if ($bas =~ /^[ACTG]$/) {
                printf "Porcentaje: %2.2f%%\n", 100 * $organismos{$organismo}{$abr{$bas}} / $total;
            }
        }
    }
} while ($respuesta ne '0');
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

Ejemplo de salida

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

explorer@casa:~/Documentos/Desarrollo> perl code_28838.pl

¿Qué quieres hacer?

    a) Imprimir todos los organismos por pantalla

    b) Guardar la tabla en un fichero

    c) Mostrar el porcentaje de bases de un determinado tipo que existen en un determinado organismo

    0) Terminar

[Opción]: a

$VAR1 = {

          'humano' => {

                        'Guaninas' => 56,

                        'Adeninas' => 12,

                        'Citosinas' => 34,

                        'Timinas' => 78

                      },

          'mosca' => {

                       'Guaninas' => 560,

                       'Adeninas' => 120,

                       'Citosinas' => 340,

                       'Timinas' => 780

                     }

        };

¿Qué quieres hacer?

    a) Imprimir todos los organismos por pantalla

    b) Guardar la tabla en un fichero

    c) Mostrar el porcentaje de bases de un determinado tipo que existen en un determinado organismo

    0) Terminar

[Opción]: c

¿De qué organismo? humano

¿Y de qué base? [A/C/G/T]:g

Porcentaje: 31.11%

¿Qué quieres hacer?

    a) Imprimir todos los organismos por pantalla

    b) Guardar la tabla en un fichero

    c) Mostrar el porcentaje de bases de un determinado tipo que existen en un determinado organismo

    0) Terminar

[Opción]:Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

Foro - Perl en Español

Porcentaje de bases

Porcentaje de bases

Publicidad

Re: Porcentaje de bases

¿Quién está conectado?