Foro - Perl en Español

por **morago** » 2011-12-07 07:00 @333

Hola.

He creado un proceso en un programilla de perl-gtk2 y Glade con la intención de que los widgets me sigan respondiendo mientras se desarrolla el proceso.

Tengo dos botones. Uno que arranca el proceso y otro que lo detiene. Al arrancar el proceso pongo el botón que lo arranca insensible ($btn_arrancar->sensitive('0')) y el cursor con un reloj de espera.

El caso es que si detengo el proceso con el botón de detener, tanto el cursor como el estado del otro botón vuelven a la normalidad. Sin embargo, cuando el proceso se detiene por sí mismo el estado del botón continúa insensible y el cursor de reloj se mantiene. No doy con el modo de que vuelva a la normalidad tras el fin natural del proceso.

Gracias por la atención.

Este es el código:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
 
use strict;
use Gtk2 'init';
use Gtk2::GladeXML;
 
use vars qw($nproc);
 
my $glade_app      = Gtk2::GladeXML->new("$ENV{'HOME'}/bin/Glade/GtkCNMV/pruebas/gtkfork.xml");
my $cursor_normal  = Gtk2::Gdk::Cursor->new('left_ptr');
my $cursor_ocupado = Gtk2::Gdk::Cursor->new('watch');
 
my $win          = $glade_app->get_widget('window1');
my $btn_arrancar = $glade_app->get_widget('button1');
my $btn_detener  = $glade_app->get_widget('button2');
 
$btn_arrancar->signal_connect( 'clicked' => \&arrancar );
$btn_detener->signal_connect( 'clicked' => \&detener );
$win->signal_connect( 'delete_event' => sub { Gtk2->main_quit; } );
 
$win->show_all;
Gtk2->main;
 
sub arrancar {
    $btn_arrancar->set_sensitive('0');
    $btn_arrancar->window->set_cursor($cursor_ocupado);
 
    my $PID = fork();
    if ($PID) {
        $nproc = $$;
 
        # Mi manera cutre de pasar el número de proceso :)
        open( TMP, ">/tmp/nproc" ) or die "Error: $!\n";
        print TMP $nproc;
        close TMP;
 
        foreach ( 0 .. 3 ) {
            print ">> $_\n";
            sleep 1;
            detener() if ( $_ >= 3 );
        }
    }
    else { return "No hay fork: $!\n"; }
 
    return;
}
 
sub detener {
    $btn_arrancar->set_sensitive('1');
    $btn_arrancar->window->set_cursor($cursor_normal);
 
    open( TMP, "</tmp/nproc" ) or die "Error: $!\n";
    $nproc = $_ while (<TMP>);
    close TMP;
 
    print "Terminando $nproc...\n";
    kill TERM => $nproc;
 
    return;
}
 
Coloreado en 0.004 segundos,  usando GeSHi 1.0.8.4

No lo he mirado mucho, pero veo algunas cosas...

En la línea 28 se hace el fork(). En ese momento se crea un proceso hijo que es idéntico al padre, y los dos siguen en ese mismo punto.

En la línea 29 se pregunta por el valor de $PID.

Si $PID está definido y es positivo, resulta que somos el padre ($PID es el número de proceso del hijo).

Entonces, el padre entra en el bucle de espera de 3 segundos, al final de los cuales, se detiene.

En cambio, el hijo al llegar a la línea 29, recibe un valor 0 (el $PID dentro del hijo vale 0), con lo que salta directamente a la línea 43, donde hace un return y termina el proceso asociado a la pulsación del botón, y se queda esperando. (No es cierto lo que pones en la línea 43, de que no se ha generado el fork(). Para saber si el fork() ha funcionado bien o no, debes comprobar si el valor devuelto por fork() está definido o no (undef).)

Más información en perldoc -f fork .

por **salva** » 2011-12-08 10:29 @478

El problema es que tanto el padre como el hijo están accediendo a la interfaz gráfica y eso no funciona.

La forma correcta de enfocar este tipo de problemas es hacer que un solo proceso (normalmente el padre) se encargue en exclusiva de controlar la interfaz gráfica a la vez que habla con el hijo (habitualmente mediante pipes) que hará otro tipo de tareas (algún cálculo, acceder a algún servicio de red, etc).

Una vez que el hijo termina, tiene que llamar a POSIX::_exit() para salir sin llamar a los métodos DESTROY ni a los bloques END, lo cual también interferiría con el GUI.

por **morago** » 2011-12-11 13:07 @588

Gracias por vuestras respuestas. He encontrado un par de scripts que muestran el uso de threads en Gtk2:
http://code.google.com/p/saaral-soft-search-spider/
http://cpansearch.perl.org/src/FLORA/Gtk2-1.223/examples/thread_usage.pl

El autor del primero dice que Gtk2::GladeXML no se lleva muy bien con los hilos.

por **morago** » 2011-12-13 19:17 @845

Parece que el uso de threads supone una solución muy simple y limpia. Aunque aún no lo he probado con glade, este es el ejemplo que me ha quedado:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/env perl
 
use strict;
use warnings;
use threads;
use LWP::Simple;
use Glib qw(TRUE FALSE);
use Gtk2 qw/-init -threads-init/;
 
 
my $hebra_down;
my $deb = ( 'firefox_8.0+build1-0ubuntu0.11.10.3_amd64.deb' );
my $firefox = ( "http://security.ubuntu.com/ubuntu/pool/main/f/firefox/$deb" );
 
die "Glib::Object thread safetly failed"
        unless Glib::Object->set_threadsafe (TRUE);
 
my $win = Gtk2::Window->new;
$win->signal_connect (destroy => sub { Gtk2->main_quit; });
$win->set_title ($0);
$win->set_border_width (10);
$win->set_default_size (400, 200);
$win->set_position('center');
 
my $hbox = Gtk2::HBox->new (FALSE, 6);
$win->add ($hbox);
 
my $vbox = Gtk2::VBox->new (FALSE, 6);
$hbox->pack_start ($vbox, FALSE, FALSE, 0);
 
my $btn_iniciar = Gtk2::Button->new ('Iniciar');
$vbox->pack_start ($btn_iniciar, FALSE, FALSE, 0);
 
my $btn_parar = Gtk2::Button->new ('Parar');
$vbox->pack_start ($btn_parar, FALSE, FALSE, 0);
$btn_parar->set_sensitive(FALSE);
 
my $pending = Gtk2::Label->new ('Pulsar para iniciar la descarga');
$vbox->pack_start ($pending, FALSE, FALSE, 0);
 
$btn_iniciar->signal_connect (clicked => sub {
                local $SIG{KILL} = sub { threads->exit };
 
                $btn_iniciar->set_sensitive (FALSE);
                $btn_parar->set_sensitive(TRUE);
                $pending->set_label('Descargando');
                
                $hebra_down = threads->create(\&procesa_descarga);
                });
 
$btn_parar->signal_connect (clicked => sub {
                $hebra_down->kill('KILL')->detach;
                
                $btn_iniciar->set_sensitive (TRUE);
                $btn_parar->set_sensitive(FALSE);
                $pending->set_label('Descarga cancelada');
                });
 
$win->show_all;
Gtk2->main;
 
 
sub procesa_descarga
  {
        my $ua = LWP::UserAgent->new();
        $ua->timeout(10);
        my $response = $ua->get( $firefox );
 
        if ($response->is_success)
          {
          open (FF, ">$deb") or return "Error volcando a disco: $!\n";
          print FF $response->decoded_content();
          close FF;
 
          $btn_iniciar->set_sensitive(TRUE);
          $btn_parar->set_sensitive(FALSE);
 
          if ($response->status_line eq '200 OK')
            {
            $pending->set_label("Descarga completa\n" . $response->status_line);
            return $response->status_line;
            }
          else
            {
            $pending->set_label("Se ha producido un error\n" . $response->status_line);
            return $response->status_line;
            }
          }
        else {
            $pending->set_label("Se ha producido un error\n" . $response->status_line);
            return $response->status_line;
            }
  }
 
Coloreado en 0.003 segundos,  usando GeSHi 1.0.8.4

Foro - Perl en Español

Un fork en perl-gtk2

Un fork en perl-gtk2

Publicidad

Re: Un fork en perl-gtk2

Re: Un fork en perl-gtk2

Re: Un fork en perl-gtk2

Re: Un fork en perl-gtk2

¿Quién está conectado?