Foro - Perl en Español

por **coloradito** » 2012-02-11 03:57 @206

Hola:

Tengo este array bidimensional que consigo ordenar por la primera columna,

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

__DATA__
aaaa1,g,20120111-23,1
aaaa3,c,20120110-3,1
aaaa1,f,20120111-2,1
aaaa1,g,20120111-113,1
aaaa2,a,20120109-23,1
aaaa2,h,20120110-3,1
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

si intento ordenarlo por la primera y tercera columna el resultado es

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

row 0:   [ aaaa1 g 20120111-113 1 ], 

row 1:   [ aaaa1 f 20120111-2 1 ], 

...Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

y yo esperaba que me pintase antes 20120111-2 que 20120111-113.
Tengo que hacer la ordenación alfanumérica, de ahí el problema.

¿Cómo puedo aplicar la transformada Schwartziana para la segunda columna¿ O ¿puedo implementar un substr() en el sort()?

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

my @sorted
    = sort {
        $a->[0] cmp $b->[0] || $a->[2] cmp $b->[2]
      }
      @table
    ;
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Gracias

Código completo

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use strict;
use warnings;
 
my ( @row, @table, $n, $rowref );
 
while (<DATA>) {
    chomp;
 
    # regex to separate CSV (use of a cpan module for CSV STRONGLY advised...
    @row = split( /,/, $_ );
 
    push( @table, [@row] );            #Note the [ ] around the list
}
 
my @sorted = sort {
           $a->[0] cmp $b->[0]
        || $a->[2] cmp $b->[2]
 
} @table;
 
print "\n ------------ordenada\n";
 
my $rowcnt = 0;
foreach $rowref (@sorted) {
    print "row $rowcnt: ";
    $rowcnt++;
    print "  [ @$rowref ], \n";
}
 
__DATA__
aaaa1,g,20120111-23,1
aaaa3,c,20120110-3,1
aaaa1,f,20120111-2,1
aaaa1,g,20120111-113,1
aaaa2,a,20120109-23,1
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

#!/usr/bin/perl
use strict;
use warnings;
use diagnostics;
 
my ( @fila, @tabla );
 
while (<DATA>) {                        # leemos la tabla que está en DATA
    chomp;                              # fuera carácter de fin de línea
 
    @fila = split /,/;                  # partimos la línea por las comas
 
    push @tabla, [ @fila ];             # Los corchetes crean un nuevo array anónimo,
                                        # cuyo contenido es la @fila,
                                        # que almacenamos como nueva fila de la @tabla
}
 
my @tabla_ordenada                      # Mi nueva tabla ordenada, será...
    =
    map {
        $_->[2]                         # la línea original extraída del tercer componente del nuevo array
    }
    sort {                              # ordenada...
        $a->[0] <=> $b->[0]             # por el primer componente del nuevo array...
                ||                      # o por
        $a->[1] <=> $b->[1]             # el segundo componente
    }
    map {
        [ (split /-/, $_->[2]), $_ ]    # transformamos las líneas en un nuevo array
                                        # de la forma [ 20120111, 23, [aaaa1,g,20120111-23,1] ]
    }
    @tabla
    ;
 
my $i = 0;
print "------------desordenada\n";
for my $fila_ref (@tabla) {
    print "fila $i: ";
    print "  [ @$fila_ref ], \n";
    $i++;
}
 
print "------------ordenada\n";
$i = 0;
for my $fila_ref (@tabla_ordenada) {
    print "fila $i: ";
    print "  [ @$fila_ref ], \n";
    $i++;
}
 
__DATA__
aaaa1,g,20120111-23,1
aaaa3,c,20120110-3,1
aaaa1,f,20120111-2,1
aaaa1,g,20120111-113,1
aaaa2,a,20120109-23,1
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

Sale:

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

------------desordenada

fila 0:   [ aaaa1 g 20120111-23 1 ], 

fila 1:   [ aaaa3 c 20120110-3 1 ], 

fila 2:   [ aaaa1 f 20120111-2 1 ], 

fila 3:   [ aaaa1 g 20120111-113 1 ], 

fila 4:   [ aaaa2 a 20120109-23 1 ], 

------------ordenada

fila 0:   [ aaaa2 a 20120109-23 1 ], 

fila 1:   [ aaaa3 c 20120110-3 1 ], 

fila 2:   [ aaaa1 f 20120111-2 1 ], 

fila 3:   [ aaaa1 g 20120111-23 1 ], 

fila 4:   [ aaaa1 g 20120111-113 1 ],Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

En este ejemplo, sacamos el tercer elemento de cada fila, y lo partimos por el guion, con split(). Eso nos genera dos componentes, que junto con toda la fila original como tercer componente, formamos un nuevo array de tres elementos (con los corchetes []). Luego hacemos el sort de esos nuevos array, usando comparaciones numéricas ascendentes, con la ayuda de $a, $b y '<=>'. Como son dos componentes los que tenemos que mirar, usamos '||' para unir las condiciones. Finalmente, necesitamos un map{} para "extraer" las filas originales, ahora sí ya ordenadas.

Foro - Perl en Español

Ordenar array bidimensional, transformada Schwartz 2ª col.

Ordenar array bidimensional, transformada Schwartz 2ª col.

Publicidad

Re: Ordenar array bidimensional, transformada Schwartz 2ª co

Re: Ordenar array bidimensional, transformada Schwartz 2ª co

¿Quién está conectado?