Foro - Perl en Español

por **akire** » 2012-02-16 12:03 @544

¡¡¡Hola, qué tal, muy lindo día!!!

Tengo algo atorado este programa y necesito su ayuda. Lo que yo necesito es que a partir de unas tablas de entrada
como estas:

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

ENSMUSG00000000001      1488

ENSMUSG00000000028      203

ENSMUSG00000000049      3

ENSMUSG00000000056      192

ENSMUSG00000000058      199

ENSMUSG00000000078      912

ENSMUSG00000000085      150Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

quiero obtener una sola que contenga todos los genes (la primera columna) que correspondan a los archivos y a los que no se encuentren en uno u otro les pongo un 1. Hasta ahorita solo saca un archivo de cada uno duplicando valores y no los he relacionado. Agradecería mucho su apoyo.

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl -w
use lib "$ENV{'HOME'}/perl";
use yo qw(:DEFAULT);
use Data::Dumper;                      # Hint: print Dumper(\@cosa);
 
#use strict;
 
my @entrada_tbl = </data/uuab/adriana/*.tbl>;
foreach my $file_tbl (@entrada_tbl) {
 
    open IN, $file_tbl or die "Cant read $file_tbl\n";
 
    open( OUT, ">$file_tbl.tbl1" );
 
    my ( %in, %exp );
    while (<IN>) {
        next unless /^EN/;
        my ( $gen, $val ) = split;
        $exp{$gen} = $val;
        $exp{$val}++;
        $in{$gen}++;
 
    }
 
    foreach my $gen ( sort keys %in ) {
 
        $exp{$gen} ||= 1;
        $exp{$gen}++;
 
        print OUT "$gen\t$exp{$gen}\t$exp{$gen}\t$exp{$gen}\n";
 
    }
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

Gracias por tu apoyo. Esa línea quería ver si con ello recorría los elementos junto con su valor por cada archivo
pero veo que solo lo hago por cada entrada, y lo que quiero hacer es juntarlo como en la tabla siguiente, donde por ejemplo, el gen ENSMUSG00000000028 está en el primer archivo con un valor de 106, en el segundo archivo está en 16 y en el último no estuvo, pero yo quiero que le ponga un 1.

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

ENSMUSG00000000001      1082    10      182

ENSMUSG00000000028      106     16      1

ENSMUSG00000000037      78      444     7

ENSMUSG00000000049      10      3       30

ENSMUSG00000000056      19      159     1597

ENSMUSG00000000058      247     247     247

ENSMUSG00000000078      687     1       1

ENSMUSG00000000085      93      3       1

ENSMUSG00000000088      7229    7       29Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

Así es como yo necesito la salida

por **explorer** » 2012-02-16 15:48 @700

No es tan sencillo...

No puedes sacar la información por cada línea, hasta que no hayas leído todas las líneas, porque no sabes cuántas columnas tienes.

Entonces... tienes que leer todos los archivos, y guardarlos en una estructura bidimensional, en donde las filas son cada gen, y cada columna, el número de archivo leído. Si un elemento no está definido, entonces sabemos que no fue leído, y le ponemos a '1'. Y lo mismo hay que hacer para las columnas finales, que también pueden haber estado vacías.

Esta es mi solución. Naturalmente, se puede hacer de muchas otras maneras.

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use 5.010;
#use strict;
#use warnings;
#use diagnostics;
 
use autodie;                    # es mejor morir que regresar con deshonor (proverbio Klingon)
 
my %matriz;                     # guardaremos la información aquí
my $col = 0;                    # número de columnas por línea
 
for my $file_tbl (<*.tbl>) {
 
    open my $TBL, '<', $file_tbl;
    while (<$TBL>) {
        next unless /^EN/;
        chomp;
        my($gen, $value) = split;
        $matriz{$gen}[$col] = $value;    # almacenamos el valor, en la fila $gen, y columna $c
    }
    close   $TBL;
    
    $col++;                              # siguiente columna
}
 
for my $gen (sort keys %matriz) {        # impresión de los datos
    print $gen;                          # nombre del gen
 
    for my $item (@{$matriz{$gen}}) {
        $item //= 1;                     # si el elemento no está definido, lo ponemos a '1'
        print "\t$item";
    }
 
    for (@{$matriz{$gen}} .. $col-1) {
        print "\t1";                     # resto de elementos de la fila, también a '1'
    }
 
    print "\n";
}
 
__END__
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Aquí estamos usando el operador // (nuevo en Perl v5.10) para saber si una variable contiene un valor definido, o no.

por **akire** » 2012-02-16 17:30 @771

Muchísimas gracias

, tu ayuda es estupenda, ¡¡¡¡¡¡ten un día fabuloso!!!!!!

Foro - Perl en Español

Obtener tabla consenso de varias tablas anteriores

Obtener tabla consenso de varias tablas anteriores

Publicidad

Re: Obtener tabla consenso de varias tablas anteriores

Re: Obtener tabla consenso de varias tablas anteriores

Re: Obtener tabla consenso de varias tablas anteriores

Re: Obtener tabla consenso de varias tablas anteriores

¿Quién está conectado?