Foro - Perl en Español

por **Alfumao** » 2012-05-14 04:42 @237

Buenos días a todos.

He escrito un programa de Perl que llama a un "one-liner" para llevar a cabo una operación (eliminar todas las lineas que empiecen por "@" de un fichero de texto de un tamaño muy grande, varios Gigabytes).
Pero me dá el siguiente error al llamar al "one-liner":

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

Use of uninitialized value in concatenation (.) or string at samcleanser.pl line 23.

syntax error at -e line 1, near "="

Execution of -e aborted due to compilation errors.
Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

Este es el código:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!usr/bin/perl -w
use strict;
 
#usage samcleanser.pl [full dir path]
#print "Enter your directory path:\n"; #carpeta
#chomp(my $path = <STDIN>);
 
my $path = shift @ARGV;
print "$path\n";
chdir $path or die "ERROR: Unable to enter $path: $!\n";
opendir( TEMP, "." );
my @files = readdir(TEMP);
closedir TEMP;
 
for my $file (@files) {
 
    if ( $file =~ /(\w+\.\w+).sam/ ) {
 
        my $name = $1;
 
        print "cleaning $name\.sam\n";
 
        my $clean = `perl -pi -e '$_="" if (/^@/)' $name`;
    }
}
 
Coloreado en 0.004 segundos,  usando GeSHi 1.0.8.4

¿Se puede hacer la llamada que yo he intentado, en Perl?

Una pregunta más: ¿podría hacerse más rápido usando bash?

Gracias de antemano por vuestra atención.

No sé muy bien dónde puede estar el error... podrían ser los últimos paréntesis, o la mezcla de comillas en el one-liner.

De todas maneras... ¿por qué haces eso? Estás ejecutando un proceso Perl por cada archivo que quieres modificar... eso es muy ineficiente...

Mira... con unos pequeños cambios, lo tienes resuelto:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!usr/bin/perl
# usage samcleanser.pl [full dir path]
# Alfumao, 2012.
 
use v5.10;
use strict;
use warnings;
use autodie;    # «Mejor morir que regresar con deshonor» --Proberbio Kinglon
 
# print "Enter your directory path:\n"; #carpeta
# chomp(my $path = <STDIN>);
 
my $path = shift @ARGV;
say $path;
 
chdir $path;
 
opendir(TEMP, "." );
 
while (my $file = readdir TEMP) {
 
    if (my($name) = $file =~ /(\w+[.]\w+[.]sam)/ ) {
 
        say "cleaning $name";
 
        open my $FI, '<',  $name;
        open my $FO, '>', "$name.part";
 
        while (my $linea = <$FI>) {
            next if '@' eq substr $linea, 0, 1; # no ponemos la línea si el primer carácter es '@'
            print $FO $linea;
        }
        
        close $FI;
        close $FO;
        
        rename "$name.part", $name;             # rename cambia el nombre y sobreescribe el original
    }
}
 
closedir TEMP;
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Este programa realiza la misma función, pero es mucho más rápido, ya que no ejecuta un nuevo proceso por cada archivo. Y las operaciones que realiza son las mismas que con el operador -i: abre un archivo nuevo donde va guardando los cambios y al final hace un rename() para dejar solo con el nombre original (bueno, no es exactamente así el orden en que -i funciona, pero las operaciones son las mismas).

En cuanto a si es más rápido hacerlo con Bash... pues yo sospecho que los tiempos serán los mismos, ya que las operaciones serán las mismas, y dependemos del cuello de botella que marca el sistema de ficheros.

Eso sí, el programa en Bash quedará más largo (mucho más) si intentas imitar las operaciones que hace este programa. Solo fíjate en la cantidad de código que autodie nos ahorra...

por **Alfumao** » 2012-05-14 07:45 @364

Muchísimas gracias, explorer.

Lo probaré en cuanto pueda. El único problema es que estoy trabajando sobre servidores remotos (no tengo permisos allí) y la versión de Perl que tienen es 5.8... Además no sé si tienen instalados los módulos que requiere tu código.

De todas formas merece la pena probarlo, porque estoy seguro que es muy rápido.

por **explorer** » 2012-05-14 10:14 @468

Quita las líneas 5 y 8.
Sustituye los say() por print() más un retorno de carro al final.
Agrega ' or die "ERROR: No se pudo abrir el archivo: $!\n"; ' al lado de cada open() y chdir()
(incluso habría que hacerlo con los print() y close(), que es lo que hace autodie, pero no hace falta tanto miramiento).

Y ya está.

por **Alfumao** » 2012-05-29 09:47 @449

Muchas gracias, explorer, por la respuesta.

Tengo una pregunta, ¿cómo podría hacer funcionar este "one-liner" (que posteaste en su día) en varios archivos a la vez?

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

perl -p -i -e 's/\r//' script.pl
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Así funciona sobre por ejemplo un script de Perl, ¿cómo se escribiría para modificar todos los archivos Perl de un mismo directorio?

¿Así?

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

perl -p -i -e 's/\r//' *.pl
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

¿Y si queremos incluir un directorio diferente del que estamos al escribir el "one-liner", ¿cómo se introduce el directorio en el "one-liner"?

Gracias de nuevo.

por **explorer** » 2012-05-29 11:53 @536

Sí, se haría de esa manera, con *.pl

Y para indicar un subdirectorio, pues en la parte de argumentos:

/ruta/al/directorio/*.pl

Más ejemplos, en perldoc perlrun

por **Alfumao** » 2012-05-30 08:17 @386

¡¡¡Muchas gracias, explorer!!!

Foro - Perl en Español

Llamar un Perl one-liner desde un programa en Perl

Llamar un Perl one-liner desde un programa en Perl

Publicidad

Re: Llamar un Perl one-liner desde un programa en Perl

Re: Llamar un Perl one-liner desde un programa en Perl

Re: Llamar un Perl one-liner desde un programa en Perl

Re: Llamar un Perl one-liner desde un programa en Perl

Re: Llamar un Perl one-liner desde un programa en Perl

Re: Llamar un Perl one-liner desde un programa en Perl

¿Quién está conectado?