Foro - Perl en Español

por **explorer** » 2012-05-23 14:53 @662

Pues abres el archivo (open), lo vas leyendo línea a línea, por cada línea le quitas el carácter de fin de línea (chomp), la divides separando por el carácter ';' (con split), y ya puedes ir sumando '+'. Al final del bucle, print().

Vale, tengo esto pero no me funciona.

print "Los alimentos que ha tomado son: @alimentos\n";

$CAL="ARCHIVO.txt";

open ($CAL,"$CAL")|| die"cannot open file $CAL: $!";
open (OUT, ">OUT.$CAL")|| die"cannot produce file $CAL: $!";

while (my $linea = <$CAL> ) {
chomp $linea;
$suma=0;

for (my $i = 0; $i <@alimentos; $i++) {
if ($linea =~ /^$alimentos[$i]/) {
my @lista = split /;/, $linea;
for my $elemento (@lista) {
print "$elemento\n";

chomp($elemento);
my @lista= split /;/, $linea;

for my $elemento (@lista){
$suma+=$elemento;}

print "$suma\n";

}
}

}

}
close($CAL);
close(OUT);

Consigo que me imprima los alimentos que tomaste y sus calorías al lado, pero me suma las calorías del mismo alimento dos veces en vez de las distintos alimentos. Ayuda por favor...

El archivo en el que se encuentran es un txt como este:

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

pescado;200

fruta;100

vodka;240Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

por **explorer** » 2012-05-24 09:45 @448

Es que... creo que estás liando lo que estás leyendo... Mira:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

my @lista = split /;/, $linea;  # $linea contiene la info. de calorias
for my $elemento (@lista) {     # recorremos los campos de esa línea
print "$elemento\n";
 
chomp($elemento);               # no es necesario porque ya se hizo chomp($linea) antes
my @lista= split /;/, $linea;   # ¿Por qué dividimos cada $elemento de la $linea?
 
for my $elemento (@lista){      # Otro bucle... ¿de @lista? ¿@lista dentro de @lista?
$suma+=$elemento;
}
 
print "$suma\n";
Coloreado en 0.003 segundos,  usando GeSHi 1.0.8.4

Te aconsejo que pongas claro el nombre de cada variable, y así sabes lo que contiene.

Esta es mi versión:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/env perl
# Cálculo de las calorías consumidas
# Joaquín Ferrero, 20120521
use utf8;
use open IO => qw<:utf8 :std>;
use feature qw<say>;
 
 
say 'Ha seleccionado usted el programa contador de calorías.';
 
## Leemos las comidas
say 'Introduce comidas, una por línea (en blanco, para terminar):';
my @comidas;
while (1) {
    my $comida = <>;
 
    chomp $comida;                      # quitar fin de línea
    $comida = lc $comida;               # en minúsculas
    $comida =~ s/^\s+//g;               # quitar espacios de delante
    $comida =~ s/\s+$//g;               # lo mismo, de detrás
    last if $comida eq '';              # si nada, terminamos bucle
 
    push @comidas, $comida;             # almacenamos la $comida
}
 
## Informar o salir
exit if not @comidas;
say 'Los alimentos que ha tomado son: ', join(', ', @comidas[0 .. $#comidas-1]), ' y ', $comidas[-1];
 
## Leemos la tabla de alimentos
my %alimentos;
 
#open my $CALORIAS, '<', 'calorias.txt';        # abrir el archivo o leer desde DATA
#while (my $linea_calorias = <$CALORIAS>) {     # leer desde el archivo o desde DATA
while (my $linea_calorias = <DATA>) {
    chomp $linea_calorias;
    my($alimento, $calorias) = split /;/, $linea_calorias;
 
    $alimentos{$alimento} = $calorias;          # almacenamos las $calorias por cada $alimento
}
#close $CALORIAS;
 
## Cálculo de las calorías
my $total_calorias = 0;
 
for my $comida (@comidas) {
    if ($alimentos{$comida}) {
        $total_calorias += $alimentos{$comida};
    }
    else {
        say "No tengo datos para el alimento [$comida]";
    }
}
 
say "Total de calorías: $total_calorias";
 
__DATA__
fruta;30
pescado;100
carne;200
leche;100
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

Sale

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

explorer@portatil ~/Documents/Desarrollo $ perl code_31231.pl

Ha seleccionado usted el programa contador de calorías.

Introduce comidas, una por línea (en blanco, para terminar):

carne

pescado

fruta

Los alimentos que ha tomado son: carne, pescado y fruta

Total de calorías: 330Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

Foro - Perl en Español

Textos, bucle y elementos de un array

Re: Textos y números

Publicidad

Re: Textos y números

Re: Textos, bucle y elementos de un array

¿Quién está conectado?