Foro - Perl en Español

por **biovero88** » 2012-06-11 18:41 @820

¡Hola a todos!

Soy un poco nueva con Perl. El script que intento hacer debería contar cuántas veces está repetida una palabra, en una lista y al final imprimir la palabra y el número de veces que aparece.

Lo he intentado de mil formas y no he podido. Estaba revisando otros foros similares e intenté con las recomendaciones pero no me funciona. Por favor, ¡¡¡necesito ayuda!!!

¡¡Gracias!!

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl 
 
my $hits = 'testb.txt';
 
#open file
open( HITS, $hits );
 
#read sequences
my @hits = <HITS>;
close HITS;
 
for ( my $i = 0; $i < scalar @hits; ++$i ) {    #leer cada linea del archivo
 
    my @temp  = split( /\|/, $hits[$i] );       #determino a que corresponde cada campo en la linea actual
    my $query = $temp[0];
    my $exp   = $temp[1];
    my $subj  = $temp[6];
    my $count = 1;
    %x = ( $query => $count );         #creo un array para el contador correspondiente a cada query
 
    my @temp2   = split( /\|/, $hits[ $i - 1 ] );    #determino a que corresponde cada campo en la linea anterior
    my $p_query = $temp2[0];
    my $p_exp   = $temp2[1];
    my $p_subj  = $temp2[6];
 
    #verifico si el query de la linea actual es igual al de la linea anterior, si es así sumo 1 al contador
    if ( $query eq $p_query ) {
        $x{$count}++;
    }
    else {
        $x{$count} = 1;                #si no, el contador continua en 1
    }
}
 
for my $query ( keys %x ) {            #ahora imprimo cada query con su contador
    if ( $x{$count} > 0 ) {
        print "$query\thits:$x{$count}\n";
    }
}
 
Coloreado en 0.005 segundos,  usando GeSHi 1.0.8.4

#!/usr/bin/perl 
 
my $hits = 'testb.txt';
open( HITS, $hits );
my @hits = <HITS>;
close HITS;
 
my %x;                                          # contador de veces que aparece cada query
 
for ( my $i = 0; $i < scalar @hits; ++$i ) {    # leer cada línea del archivo
 
    my @temp  = split( /\|/, $hits[$i] );       # determino a qué corresponde cada campo en la línea actual
    my $query = $temp[0];
 
    $x{ $query }++;                             # aumento en uno las veces que aparece $query
}
 
for my $query ( keys %x ) {                     # ahora imprimo cada query con su contador
    print "$query\thits:$x{$query}\n";
}
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

Esta es otra versión, más corta:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
open my $HITS, '<', 'testb.txt' or die;
my @hits = <$HITS>;
close $HITS;
 
my %veces;
 
for my $hit (@hits) {
    my $query = (split /\|/, $hit)[0];          # la query es el primer campo de la línea $hit
 
    $veces{$query}++;                           # la query la contamos una vez más
}
 
while (my($query, $veces) = each %veces) {
    say $query, "\thits:", $veces;
}
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

De hecho, hasta se puede resolver en la misma línea de comandos, sin escribir ningún programa:

Sintáxis: [ Descargar ] [ Ocultar ]

Using bash Syntax Highlighting

explorer@portatil $ perl -F'\|' -anE '$v{$F[0]}++; END { say "$_\thits:$v{$_}" for keys %v }' testb.txt
ArabidopsisthalianaToll-Interleukin-Resistancedomain-containingprotein(AT2G03030)mRNA,completecdsNM_126355.1    hits:5
Arabidopsisthalianaproteinkinase-likeprotein(AT1G01450)mRNA,completecdsNM_100027.1      hits:19
 
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

por **biovero88** » 2012-06-12 21:51 @952

¡¡¡Muchas gracias, explorer!!!

Me sirvieron muchísimo. Sin embargo, quisiera conocer bien el funcionamiento de los términos empleados en la línea de comandos, te agradecería mucho si me los pudieras explicar.

por **explorer** » 2012-06-13 04:06 @212

Opciones:

-F : define el separador de campos
-a : activar el modo de división de campos cuando -n o -p estén presentes
-n : hacer un bucle por las filas del archivo(s) de entrada, pero sin pintarlas
-E : ejecuta el siguiente programa descrito a continuación, activando además las nuevas características de Perl >v5.10

Y el programa hace:

por acción de -a, sabemos que en @F recibimos los campos, divididos por el delimitador indicado por -F, así que $F[0] contiene el primer campo de la línea
ese campo lo usamos como clave del hash %v, e incrementamos en uno la presencia de esa clave
cuando se terminen de leer todas las líneas, Perl ejecuta la subrutina especial END, que lo que hace es sacar a pantalla todas las claves del hash %v, junto con las veces que aparece cada clave

Finalmente, se indica el archivo a procesar.

Más información en tu propio ordenador en perldoc perlrun, y en la Web (traducido).

por **biovero88** » 2012-06-15 10:36 @483

¡¡¡¡ Muchas gracias !!!! ¡¡¡otra vez!!!

Foro - Perl en Español

Contar palabras repetidas en un archivo

Contar palabras repetidas en un archivo

Publicidad

Re: Contar palabras repetidas en un archivo

Re: Contar palabras repetidas en un archivo

Re: Contar palabras repetidas en un archivo

Re: Contar palabras repetidas en un archivo

¿Quién está conectado?