Foro - Perl en Español

por **animal collective** » 2012-07-25 17:08 @756

Estimados,

Estoy presentando problemas en un script al comparar si una variable es igual a cero. El código me deja algunas variable con un valor null; las variables null entran en el if() siendo que éste tiene la siguiente sentencia: if ($variable == 0 ).

Adjunto código, desde ya agradezco el apoyo.

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#! /usr/bin/perl
#Transacciones
 
use MIME::Lite;
use strict;
use POSIX 'strftime';
my $fecha = strftime "%d-%m-%Y %H:%M:%S", localtime;
my $var_0;
my $var_1;
my $var_2;
my $var_3;
my $var_4;
my $var0;
my $var1;
my $var2;
my $var3;
my $var4;
 
$var0=`perl -ne 'print if /0/' /u01/home/apli/admmon/mon/data/motorAirMiddleware.txt`;
$var1=`perl -ne 'print if /1/' /u01/home/apli/admmon/mon/data/motorAirMiddleware.txt`;
$var2=`perl -ne 'print if /2/' /u01/home/apli/admmon/mon/data/motorAirMiddleware.txt`;
$var3=`perl -ne 'print if /3/' /u01/home/apli/admmon/mon/data/motorAirMiddleware.txt`;
$var4=`perl -ne 'print if /4/' /u01/home/apli/admmon/mon/data/motorAirMiddleware.txt`;
 
$var_0= 0 + $var0;
$var_1= 0 + $var1;
$var_2= 0 + $var2;
$var_3= 0 + $var3;
$var_4= 0 + $var4;
 
 
my $correo_0 = MIME::Lite->new(
        From    => '[email protected]',
        To      => '[email protected]',
        Subject => "OK (M0004-01-01) (".$var_0.")"  ,
        Data    => "Todo a resultado correctamente",
);
 
my $correo_1 = MIME::Lite->new(
        From    => '[email protected]',
        To      => '[email protected]',
        Subject => "ERROR 1 (M0004-01-01E) (".$var_1.")",
        Data    => "Error en la llamada del ws",
);
 
my $correo_2 = MIME::Lite->new(
        From    => '[email protected]',
        To      => '[email protected]',
        Subject => "ERROR 2 (M0004-01-01E) (".$var_2.")",
        Data    => "Error en respuesta (no se encuentra el string ok)",
);
 
my $correo_3 = MIME::Lite->new(
        From    => '[email protected]',
        To      => '[email protected]',
        Subject => "ERROR 3 (M0004-01-01E) (".$var_3.")",
        Data    => "Error al incluir el archivo de parametros",
);
 
my $correo_4 = MIME::Lite->new(
        From    => '[email protected]',
        To      => '[email protected]',
        Subject => "ERROR 4 (M0004-01-01E) (".$var_4.")",
        Data    => "Error al ejecutar el archivo de parametros",
);
 
MIME::Lite->send('smtp','smtpa',Timeout=>60);
 
if($var_0 == 0)
{
   $correo_0->send();
   open(LECTURA,">>/u01/home/apli/admmon/mon/data/DATA_TRX/motorAi.csv");
   print LECTURA $fecha." ; ".$var_0." ; OK \n";
   close(LECTURA);
}
 
if($var_1 == 1)
{
  $correo_1->send();
  open(LECTURA,">>/u01/home/apli/admmon/mon/data/DATA_TRX/motorAi.csv");
  print LECTURA $fecha." ; ".$var_1." ; ERROR \n";
  close(LECTURA);
}
 
if($var_2 == 2)
{
  $correo_2->send();
  open(LECTURA,">>/u01/home/apli/admmon/mon/data/DATA_TRX/motorAi.csv");
  print LECTURA $fecha." ; ".$var_2." ; ERROR \n";
  close(LECTURA);
}
 
if($var_3 == 3)
{
  $correo_3->send();
  open(LECTURA,">>/u01/home/apli/admmon/mon/data/DATA_TRX/motorAi.csv");
  print LECTURA $fecha." ; ".$var_3." ; ERROR \n";
  close(LECTURA);
}
 
if($var_4 == 4)
{
  $correo_4->send();
  open(LECTURA,">>/u01/home/apli/admmon/mon/data/DATA_TRX/motorAi.csv");
  print LECTURA $fecha." ; ".$var_4." ; ERROR \n";
  close(LECTURA);
}
 
Coloreado en 0.004 segundos,  usando GeSHi 1.0.8.4

No sale mensaje de error, el código está correcto, el problema es que siempre entra en el if(var == 0).

Te entrego más datos:

Lo que realiza el script es buscar en un log 4 números:
0, 1, 2, 3, 4

En el log solo estará uno de estos números, pero en mi caso la variable entra siempre en dos if(): en el if(var == 0) y en if(var == X).

La idea es que solo entre en el if(var == 0) cuando efectivamente la variable encuentre un 0 en el log.

por **explorer** » 2012-07-25 19:53 @870

Esto es lo que ocurre: cuando en la línea 19 buscas por un /0/, y no lo encuentra (porque en ese momento es otro valor), el valor que obtiene $var0 es 'undef'. Al llegar a la línea 25, $var_0 hace la operación matemática 0+undef, con lo que el resultado es 0. Por eso, cuando en el log no aparece un 0, siempre va a entrar en el if() del == 0: porque $var_0 siempre valdrá cero, independientemente de lo que valgan las otras variables.

Dices que en el log solo aparecerá un número. Bueno, pues la solución es usar solo una variable para almacenar ese número.

Es más... podemos usar ese valor numérico para que nos indexe los mensajes que vamos a usar en la composición del correo y en el mensaje que guardaremos en el .csv... así que... no nos hacen falta los if() (no probado):

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

open my $LOG, '<', '/u01/home/apli/admmon/mon/data/motorAirMiddleware.txt';
my $registro = <$LOG>;                    # suponemos que el registro solo tiene una línea
close $LOG;
 
my($valor) = $registro =~ m/([01234])/;   # $valor almacena el número capturado
die "ERROR: no encontré ningún valor.\n" if not defined $valor;
 
my @condicion_de_error = qw( OK ERROR ERROR ERROR ERROR );
my @mensajes_asunto = (
    'OK (M0004-01-01)',
    'ERROR 1 (M0004-01-01E)',
    'ERROR 2 (M0004-01-01E)',
    'ERROR 3 (M0004-01-01E)',
    'ERROR 4 (M0004-01-01E)',
);
my @mensajes_data = (
    'Todo ha resultado correctamente',
    'Error en la llamada del ws',
    'Error en respuesta (no se encuentra la cadena ok)',
    'Error al incluir el archivo de parámetros',
    'Error al ejecutar el archivo de parámetros',
);
 
## Confeccionamos el correo
my $correo = MIME::Lite->new(
        From    => '[email protected]',
        To      => '[email protected]',
        Subject => "$mensajes_asunto[$valor] ($valor)",
        Data    =>  $mensajes_data[$valor],
);
 
## y lo enviamos
$correo->send('smtp','smtp.correoxxx.com',Timeout => 60);
 
## Registro de lo ocurrido
open my $REGISTRO, '>>', '/u01/home/apli/admmon/mon/data/DATA_TRX/motorAi.csv';
print   $REGISTRO join(';', $fecha, $valor, $condicion_de_error[$valor]), "\n";
close   $REGISTRO;
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

Queda un poco más corto. Y más fácil de mantener.

Foro - Perl en Español

Problema para comparar variables = 0

Problema para comparar variables = 0

Publicidad

Re: Problema para comparar variables = 0

Re: Problema para comparar variables = 0

Re: Problema para comparar variables = 0

¿Quién está conectado?