Foro - Perl en Español

por **silva** » 2012-09-27 12:09 @548

Estoy trabajando localmente en entorno Windows, Perl y Apache, probando el módulo CGI::Application y Template-Toolkit.

He intentado hacer los ejemplos y tutoriales que presenta CGI::Application pero me tira un error de cabecera en forma permanente:

Mensaje de error:
malformed header from script 'main.pl': Bad header: <head>

main.pl se compone de:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

my $PRIVATE_HOME_DIR;
BEGIN { $PRIVATE_HOME_DIR = '../../MySitePrivate'; }
 
use strict;
use lib $PRIVATE_HOME_DIR.'/MyApp';
use CGI::Carp qw(fatalsToBrowser);
use MyMain;
 
MyMain->new(
         TMPL_PATH              => $PRIVATE_HOME_DIR.'/templates'
        ,-config_file   => $PRIVATE_HOME_DIR.'/config/config.pl'
)->run;
 
Coloreado en 0.004 segundos,  usando GeSHi 1.0.8.4

Si le incorporo la siguiente línea, el error desaparece, la página HTML generada por template_toolkit se muestra bien.

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

print "Content-type: text/html\n\n";
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Pero el problema es que al mostrar la página al final aparece la leyenda:
Content-Type: text/html; charset=ISO-8859-1 1 y no puedo sacarla.

¿Cómo hago para que no me muestre esta línea?

¡¡¡¡Muchísimas gracias!!!!

El problema está en que no debes agregar "a mano" la salida de la cabecera HTTP.

Es el propio CGI::Application el que se debe encargar de estas cosas. Y la prueba es que lo hace: es justo lo que sale al final de la página y lo que tu quieres que no salga.

En realidad, algo debe estar mal en la aplicación que no hace salir la cabecera cuando debe.

El error creo que no está en main.pl, sino en MyMain.pm.

¿Podrías hacer una cosa?

Se trata de que publiques el trozo de código más pequeño de estos dos códigos (main.pl y MyMain.pm, que siga reproduciendo el error. Incluso es posible que puedas quitar la parte del sistema de plantillas de Template-Toolkit.

Lo dicho, mándanos lo más pequeño que puedas hacer, que siga sacando el error.

O si se trata de un ejemplo de un tutorial, mándanos el enlace.

por **silva** » 2012-09-27 14:13 @634

Bueno he dicho anteriormente que estoy trabajando a nivel local, sobre Windows con un Apache implementado con XAMPP, por las dudas.

Código Mymain.pm

Sintáxis: [ Descargar ] [ Ocultar ]

#!c:/perl64/bin/perl -w
package MyMain;
use base 'CGI::Application';
use Template;
use DBI;
use strict;
use CGI::Application::Plugin::ConfigAuto (qw/cfg cfg_file/);
use CGI::Application::Plugin::DBH (qw/dbh_config dbh/);
#-------------------------------------------------------------------------------
sub setup { # called after cgiapp_init()
my $self = shift;
$self->run_modes(
'start' => 'start',
);
$self->start_mode('start');
$self->mode_param('mode');
$self->error_mode('error');
}
sub cgiapp_prerun{
my $self = shift;
$self->cfg_file('../../MySitePrivate/config/config.pl');
$self->dbh_config(
$self->cfg('db_dsn'),
$self->cfg('db_user'),
$self->cfg('db_pw')
) or die "error al conectar";
my $q =$self->query();
}
sub start{
my $self = shift;
my $template = Template->new( {
INCLUDE_PATH => '../../MySitePrivate/templates',
});
my $plantilla ='formulario.html';
#Procesamos la salida de l aplantilla
return $template->process($plantilla) || die $template->error();
}
sub error{
my $self = shift;
my $error = shift;
return "Existe un error: ".$error;
}
1;

Código HTML simple, que también funciona mal. Muestra en la parte inferior:
Content-Type: text/html; charset=ISO-8859-1

Sintáxis: [ Descargar ] [ Ocultar ]

Using html4strict Syntax Highlighting

<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
<html xmlns="http://www.w3.org/1999/xhtml">
<head>
        <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
        <link rel="stylesheet" type="text/css" href="../../MySite/css/estilos.css" />
        <title>Intranet</title>
</head>
<body>
<div id="cabecera">
        <img src="../../MySite/images/header.jpg" width="760" height="90"  title="Header"  border="0">
</div>
<div id="page">
Esto es una prueba, testeo CGI APPLICATION - TEMPLATE TOOLKIT
</div><!-- page -->
<div id='pie'>
                <img src="../../MySite/images/footer.jpg" width="760" height="95"  title="Pie de Pagina"  border="0">
</div><!-- pie -->
</body>
</html>
 
Coloreado en 0.003 segundos,  usando GeSHi 1.0.8.4

He intentado sacar del código HTML, el header. Lo he sacado pero la respuesta continua siendo la misma. Repite en la parte inferior: Content-Type: text/html; charset=ISO-8859-1

¡¡¡¡¡Gracias!!!!!

por **danimera** » 2012-09-27 17:54 @788

Prueba en tu

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

sub start{ 
  my $self = shift; 
  my $template = Template->new( { 
     INCLUDE_PATH => '../../MySitePrivate/templates', 
  }); 
  
  my $plantilla ='formulario.html'; 
  #Procesamos la salida de l aplantilla 
  return $template->process($plantilla) || die $template->error(); 
}
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

exactamente después del my $self = shift; y antes de
my $template = Template->new( {
INCLUDE_PATH => '../../MySitePrivate/templates',
});

poner un

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

return "info de prueba";
 
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Con eso descartamos que sea el código en ese procedimiento.

por **silva** » 2012-09-27 18:52 @827

He insertado la línea como me sugieres. El resultado:

Página en blanco con la leyenda: 'info de prueba'

por **explorer** » 2012-09-27 20:21 @890

¿Qué es lo que hay en /config/config.pl?

por **silva** » 2012-09-28 04:39 @236

El archivo config.pl se compone de:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!c:/perl64/bin/perl -w
use strict;
my %CFG;
 
$CFG{app_name} = "Intranet";
$CFG{site_url} = "http://localhost/";
$CFG{db_typel} = "MYSQL"; 
$CFG{template_name} = "talabary"; #nombre de la plantilla por defecto
$CFG{description} = "MVC Intranet Perl"; #descripción contenidos generales
$CFG{tags} = "cms";
$CFG{db_dsn} = "dbi:mysql:proyecto";
$CFG{db_user} = "root";
$CFG{db_pw} = "admin";
$CFG{upload_dir} = "../../MySitePrivate/uploads";
$CFG{upload_url} = $CFG{site_url}."uploads";
$CFG{log_file} = "../../MySitePrivate/logs/my_errs.txt";
$CFG{system_email} = '[email protected]';
 
return \%CFG;
 
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

¡¡Gracias!!

por **explorer** » 2012-09-29 20:29 @895

[Para evitar que en este foro salgan con marcas las direcciones electrónicas (las direcciones de correo incluidas), solo tienes que marcar la opción «No convertir automáticamente las URLs» que se encuentra debajo de la caja de edición.]

Creo que ya he encontrado el error...

Estás usando Template Toolkit (TT), a través del módulo Template, en la línea 5.

En el método start(), creas un objeto Template, y en la línea 45 llamas a process().

GI::Application (C::A) requiere que lo que retorne de los métodos, es el texto que deberá aparecer como página HTML. Tú lo haces bien con el return(), esperando que $template->process($plantilla), genere el resultado, y con el return, C::A lo tome y lo muestre en la ventana del navegador del usuario.

Y aquí está el fallo: process() NO devuelve el código HTML de la plantilla. Solo devuelve un '1' para indicar el éxito de la llamada. Lo que realmente hace process(), es procesar la $plantilla, y sacar el resultado directamente a la salida estándar.

Y eso es lo que ocurre: estás viendo que sale el contenido de la página primero (por efecto del process()), y luego sale la cabecera HTTP al final (porque es lo que C::A siempre hace antes de la salida del código HTML).

Así que el resultado es que estás generando la salida hacia el navegador en vez de dárselo a C::A, para que éste saque todo en el orden correcto.

Hay dos opciones básicas para resolver esto.

La primera: hacer que TT nos devuelva el resultado a una variable escalar en lugar de a la salida estándar, y eso es lo que regresaremos a C::A:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

  # Procesamos la salida de la plantilla 
  my $salida = '';
  $template->process('formulario.html', {}, \$salida);
 
  return $salida;
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

La segunda opción es mejor: usar CGI::Application::Plugin::TT.

Quitas el 'use Template;' y todo el código de creación de objetos Template, y pones en su lugar 'use CGI::Application::Plugin::TT;' y más tarde, dentro de los métodos

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

  return $self->tt_process('formulario.html');
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Y ya está. Es un módulo muy cómodo. Incluso si llamas a las plantillas con el mismo nombre que los runmode, puedes simplificar la llamada a tt_process(), sin indicarle ningún argumento.

Foro - Perl en Español

No sale bien la cabecera HTTP

No sale bien la cabecera HTTP

Publicidad

Re: No sale bien la cabecera HTTP

Re: No sale bien la cabecera HTTP

Re: No sale bien la cabecera HTTP

Re: No sale bien la cabecera HTTP

Re: No sale bien la cabecera HTTP

Re: No sale bien la cabecera HTTP

Re: No sale bien la cabecera HTTP

¿Quién está conectado?