Foro - Perl en Español

por **haganex** » 2012-10-17 16:42 @737

Chicos, recurro a ustedes nuevamente ya que tengo que hacer una tarea en la universidad y estoy algo complicado. Dejo escrito lo que tengo que hacer:

Escriba un programa en Perl que reciba dos parámetros:
- un nombre de usuario
- un pid (opcional)

El sistema debe mostrar la cantidad de memoria total que ocupan los procesos que le pertenecen al usuario.

Si es ingresando el pid, solo se debe mostrar la memoria total de los procesos que son hijos del pid ingresado.

He recorrido el archivo passwd para ver primero si existe el usuario y ver su pid pero el tema es que no sé de dónde obtener la información o peso de cada archivo en ejecución perteneciente al usuario que llegó por parámetro.

Espero me puedan ayudar.

¡ Saludos !

#!/usr/bin/env perl
use v5.14;
#use strict;             # solo para desarrollo
#use warnings;           # solo para desarrollo
#use diagnostics;        # solo para desarrollo
 
## Constantes
my @tamanos  = qw(reservado total virtual);    # los tamaños que vamos a informar
my $ps_sizes = 'rss,size,vsize';               # sus correspondientes nombres para 'ps'
 
## Argumentos
@ARGV > 0
    or die "Uso: $0 <nombre de usuario> [<pid proceso padre>]\n";
 
## Nombre de usuario
my $usuario = shift;
 
## Obtenemos la lista de procesos del usuario
my @procesos = qx(ps h --User $usuario -o pid,$ps_sizes);
 
## Transformamos los @procesos, de cadenas de caracteres,
## a un hash de arrays, siendo
##    clave: el PID de cada proceso
##    valor: un array con los tamaños
my %procesos
    = map {
        my @c = split;
        $c[0] => [ @c[1..3] ];
    } @procesos;
 
## ppid que tenemos que analizar
my $ppid = shift // '';                                 # el pid del proceso padre,
                                                        # indicado por el usuario
## ver qué pids tenemos que analizar
my @pids = keys %procesos;                              # por defecto, todos
 
if ($ppid) {                                            # si tenemos un pid padre
    my @procesos_ppid = qx(ps h --ppid $ppid -o pid);   # vemos sus procesos hijo
 
    @procesos_ppid = map { split } @procesos_ppid;      # quitamos los posibles espacios en blanco
 
    @pids = grep { $_ ~~ @procesos_ppid } @pids;        # filtramos: nos quedamos solo con los pid
                                                        # que sean hijos del proceso padre
}
 
## Hacemos las sumas
my @sizes;
 
for my $pid (@pids) {
    $sizes[$_] += $procesos{$pid}[$_] for 0 .. $#tamanos;
}
 
## Informamos
say "El usuario [$usuario] tiene ", scalar(@procesos), " procesos.";
if ($ppid) {
    say "Filtrando los procesos hijos del proceso [$ppid], quedan ", scalar(@pids), " procesos.";
}
say "Ocupación de espacio de los procesos:";
 
while (my($i, $v) = each @tamanos) {
    printf "Espacio %-10s: %d Kb\n", $v, $sizes[$i];
}
 
__END__
Coloreado en 0.004 segundos,  usando GeSHi 1.0.8.4

Ejemplo de salida:

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

explorer@hs-1509:~/Desarrollo$ ./kk.pl explorer

El usuario [explorer] tiene 18 procesos.

Ocupación de espacio de los procesos:

Espacio reservado : 37252 Kb

Espacio total     : 56656 Kb

Espacio virtual   : 523808 KbColoreado en 0.000 segundos,  usando GeSHi 1.0.8.4

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

explorer@hs-1509:~/Desarrollo$ ./kk.pl explorer 28476

El usuario [explorer] tiene 18 procesos.

Filtrando los procesos hijos del proceso [28476], quedan 10 procesos.

Ocupación de espacio de los procesos:

Espacio reservado : 12680 Kb

Espacio total     : 29056 Kb

Espacio virtual   : 240816 KbColoreado en 0.000 segundos,  usando GeSHi 1.0.8.4

Foro - Perl en Español

Contador de peso de archivos en ejecución

Contador de peso de archivos en ejecución

Publicidad

Re: Contador de peso de archivos en ejecución

¿Quién está conectado?