Foro - Perl en Español

por **samust** » 2012-10-23 04:03 @210

Hola,

Tengo un problema al tratar un fichero. El fichero es del siguiente tipo:

Sintáxis: (cases.txt) [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

1  2  3  1  1  2 

1  2  2  1  1  2 

2  1  2  3  2  2Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

Todo esto separado por tabulaciones, y yo lo que quiero es leerlo y modificar esos números por un texto diferente para cada columna y valor. Es decir, para la columna 2 el valor 1 es Male y para la columna 3 el valor 1 es Present.

El problema lo tengo en que me sustituye cuando encuentra la primera ocurrencia del 1 que es en la primera columna y no sé cómo decirle que me sustituya sólo la de la 2.

El código de forma resumida es el siguiente:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

@lineas;
open FICHERO,, "<:utf8", "cases.txt" or die 'No se puede abrir el fichero cases.txt !';
@lineas = <FICHERO>;
close FICHERO;
 
for ( $j = 0; $j <= $#lineas; $j = $j + 1 ) {
 
    @valores = split( "\t", $lineas[$j] );
    $entra = 0;
 
    # SEX
    if ( $valores[3] eq "1" ) {
        $b = $valores[3];
        $c = "Male";
        $lineas[$j] =~ s/$b/$c/;
        push @aux, $lineas[$j];
        $entra = 1;
    }
    elsif ( $valores[3] eq "2" ) {
        $b = $valores[3];
        $valores[3] = "Female";
        $lineas[$j] =~ s/$b/$c/;
        push @aux, $lineas[$j];
        $entra = 1;
    }
 
    # moonths ill
    if ( $valores[37] eq "0" ) {
        $b = $valores[37];
        $c = "Absent";
        $lineas[$j] =~ s/$b/$c/;
        push @aux, $lineas[$j];
        $entra = 1;
    }
    elsif ( $valores[37] eq "1" ) {
        $b = $valores[37];
        $c = "Present";
        $lineas[$j] =~ s/$b/$c/;
        push @aux, $lineas[$j];
        $entra = 1;
    }
    elsif ( $valores[37] eq "3" ) {
        $b = $valores[37];
        $c = "?";
        $lineas[$j] =~ s/$b/$c/;
        push @aux, $lineas[$j];
        $entra = 1;
    }
    elsif ( $valores[37] eq "2" ) {
        $b = $valores[37];
        $c = "Suspected";
        $lineas[$j] =~ s/$b/$c/;
        push @aux, $lineas[$j];
        $entra = 1;
    }
    if ( !$entra ) {
        push @aux, $lineas[$j];
    }
}
 
Coloreado en 0.004 segundos,  usando GeSHi 1.0.8.4

Hago el push @aux, porque quiero guardar en un fichero el resultado, tanto las columnas que cambio como las que no.

Muchas gracias de antemano y espero haberme explicado bien,
saludos.

#!/usr/bin/perl
use strict;
use warnings;
use diagnostics;
 
## Lectura
open FICHERO, '<:utf8', "cases.txt" or die "No se puede abrir el archivo cases.txt: $!\n";
my @lineas;
while (my $linea = <FICHERO>) {
    chomp $linea;
    
    my @columnas = split " ", $linea;
    
    push @lineas, [ @columnas ];                # creamos una estructura bidimensional
}
close FICHERO;
 
## Proceso
for my $linea (@lineas) {
    my @columnas = @$linea;
    
    if ($columnas[1] == 1) {
        $columnas[1] = 'Male';
    }
    elsif ($columnas[1] == 2) {
           $columnas[1] = 'Female';
    }
    
    if ($columnas[2] == 0) {
        $columnas[2] = 'Absent';
    }
    elsif ($columnas[2] == 1) {
           $columnas[2] = 'Present';
    }
    elsif ($columnas[2] == 2) {
           $columnas[2] = 'Suspected';
    }
    elsif ($columnas[3] == 3) {
           $columnas[3] = '?';
    }    
 
    $linea = [ @columnas ];
}
 
## Escritura
open FICHERO, '>:utf8', "cases_1.txt" or die "No se puede escribir en el archivo cases_1.txt: $!\n";
for my $linea (@lineas) {
    print FICHERO join("\t", @$linea), "\n";
}
close FICHERO;
 
__END__
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

Pero con un poco de ayuda, se puede abreviar:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use v5.14;
use autodie;
 
## Transformaciones
# Es un hash de hashes. La primera clave es el número de columna,
# y su hash correspondiente indica la transformación a realizar
my %trans = (
    1   => {
            1 => 'Male',
            2 => 'Female',
    },
    2   => {
            0 => 'Absent',
            1 => 'Present',
            2 => 'Suspected',
            3 => '?',
    },
);
 
## Lectura/procesado/escritura, línea a línea
open my $ENTRADA, '<:utf8', "cases.txt";
open my $SALIDA , '>:utf8', "cases_1.txt";
 
while (my $linea = <$ENTRADA>) {
    chomp $linea;
    
    my @columnas = split " ", $linea;
 
    for my $columna (keys %trans) {
        $columnas[$columna] = $trans{$columna}{$columnas[$columna]};    # La magia
    }
 
    say $SALIDA join "\t", @columnas;
}
 
close $ENTRADA;
close $SALIDA;
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

por **samust** » 2012-10-24 04:01 @209

Muchísimas gracias, creo que me voy a decantar por la segunda opción, es más elegante y eficiente creo

.

Foro - Perl en Español

Sustituir en fichero números por string

Sustituir en fichero números por string

Publicidad

Re: Sustituir en fichero números por string

Re: Sustituir en fichero números por string

¿Quién está conectado?