Foro - Perl en Español

por **tutoki** » 2012-11-20 11:48 @533

Hola

Tengo para un mismo proyecto varios programas en Perl que quiero modular (pm). Aparte tengo la intención de que sean accesibles vía un menú muy simple.

Os pego un prototipo muy simple:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl 
use v5.14;
use autodie;    
use lib('/home/cpb/Dropbox/WEB/workspace/PreSPA/montaje');
    #modifica este path para tu uso personal
#use buskeitor; # lo remarco
my $opcion;
 
say qq(#####################################
# Introduce 1 para Procesar imágenes
# Introduce 2 para mostrar enlaces
# Introduce 3 para copiar contenido
#####################################);
 
chop( $opcion = <STDIN> );
 
if ( $opcion == "1" ) {
        print "descargando imágenes...\n";
        descargar_imagenes(); # del módulo pm buskeitor
 
}
elsif ( $opcion == "2" ) {
        print "descargando enlaces...\n";
        descargar_enlaces(); # del módulo pm buskeitor
}
elsif ( $opcion == "3" ) {
        print "descargando contenido a 'mitexto.txt'...\n";
        descargar_contenido(); # del módulo pm buskeitor
}
else { print " te has colado bacalado, entre 1 y 3....\n" }
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

¿Este tipo de programas con opciones se suele hacer así?

¿Se utiliza el módulo getopt?

SALUD...

Bueno, se suele hacer si el número de opciones es bajo o muy bajo, pero a partir de una cierta cantidad, es mejor usar un módulo de despacho de opciones o de menú.

El módulo Getopt es para pasar y leer opciones desde la línea de comandos. Entonces, no estamos hablando de un menú que se le presenta al usuario.

Si el programa queremos hacerlo lo más completo, se podrían dar al usuario las dos opciones: si el programa se arranca sin argumentos que implican una selección, se le muestra el menú y esperamos su elección. En cambio, si el programa se arranca con argumentos, se ejecutan y se termina el programa.

Una forma esquemática de hacer una tabla de despacho, sería así (no probado):

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

my %opciones = (
    1 => \&descargar_imagenes,
    2 => \&descargar_enlaces,
    3 => \&descargar_contenido,
);
 
print "Escoja [1/2/3]: "; chomp(my $opcion = <STDIN>);
 
$opciones{$opcion}->();   # ejecutamos
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Lo tienes más simplificado en un montón de módulos que existen en CPAN que se llaman 'dispatch'. Por ejemplo, Dispatch::Declare.

por **tutoki** » 2012-11-22 18:20 @805

Hola

He estado practicando con el módulo de CPAN que me recomendaste. Desde luego hace lo que dices, muy fácil de implementar, aunque le encuentro un pero, aunque es más sobre de la idea que yo tenía en mente.

¿Hay algún modo de que el programa vuelva al principio como en un bucle?, es decir: yo elijo la opción y cuando acaba la ejecución de esa opción, no se acaba el programa sino que vuelvo al principio.

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl 
# dispatcher.pl
use v5.14;
use autodie;
 
use Dispatch::Declare;
 
say 'elija la opción : COPIAR / BORRAR / SALIR';
chop( my $action = <STDIN> );
 
declare COPIAR => sub {
        say 'Esto es un test COPIAR';
};
 
declare BORRAR => sub {
        say 'Esto es un test BORRAR';
};
declare SALIR => sub {
        say 'Esto es un test SALIR';
};
declare DEFAULT => sub {
        say 'has introducido mal la opción';
        system("./dispatcher.pl"); 
};
run $action;
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

La última opción se ejecuta cuando no se ejecutan ninguna de las anteriores y vuelve a llamar al programa.

No me parece muy elegante, pero funciona.
¿Qué te parece?

SALUD...

por **explorer** » 2012-11-23 07:02 @335

Si quieres un bucle, solo tienes que ponerlo. Por ejemplo, sería así:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
# dispatcher.pl
use v5.14;
use autodie;
     
use Dispatch::Declare;
 
## Declaración de despachos
declare COPIAR => sub {
    say 'Esto es un test COPIAR';
};
     
declare BORRAR => sub {
    say 'Esto es un test BORRAR';
};
 
declare SALIR => sub {
    say 'Esto es un test SALIR';
};
 
declare DEFAULT => sub {
    say 'has introducido mal la opción';
};
 
## Bucle
my $action;
do {
    print "Escoja [COPIAR / BORRAR / SALIR]: "; chomp($action = <STDIN>);
     
    run $action;
 
} while $action ne 'SALIR';             # repetir mientras $action "No Es igual a" 'SALIR'
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

En cuanto a la forma de programar, este módulo no es más que un pequeño apaño de la solución que te comenté del hash. No hay problema si el número de opciones es más o menos pequeño. Y si el cuerpo de las subrutinas también es bajo.

En cambio, si el tamaño de las subrutinas crece mucho, es mejor ponerlo de esta manera (esquemática):

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

# Al principio del programa, hacemos las declaraciones
declare ACCION1 => \&accion1;       # aquí, resumen de lo que es accion1
declare ACCION2 => \&accion2;       # lo mismo para accion2
declare ACCION3 => \&accion3;       # ...
# ...
declare ACCION9 => \&accion9;
 
# Bucle y procesamiento
# ...
 
# Subrutinas
sub accion1 {                       # declaración y definición de accion1
 
}
 
sub accion2 {                       # declaración y definición de accion2
 
}
 
sub accion3 {                       # declaración y definición de accion3
 
}
 
# ...
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Si el número de líneas sigue creciendo, pues a lo mejor hay que pensar en otras posibilidades, como en la de modularizar las subrutinas, en archivos pm aparte.

por **tutoki** » 2012-11-23 19:19 @847

Hola,

Me he atrevido con los módulos (pm) que era mi objetivo inicial

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl 
use v5.14;
use autodie; 
use Dispatch::Declare;   
use lib('/home/cpb/Dropbox/WEB/workspace/PreSPA/montaje/enconstruccion/');
    #modifica este path para tu uso personal
use borrar;
use convertir;
use montar;
 
my $action; # variable global, me daba error en el condicional WHILE
 
# declaraciones
declare BORRAR => \&borrador;      
declare CONVERTIR => \&convertidor;    
declare MONTAR => \&montador;       
 
 
 
## Bucle
do {
    print "Escoja [BORRAR / CONVERTIR / MONTAR / SALIR]: "; chomp($action = <STDIN>);
     
    run $action;
 
} while $action ne 'SALIR';             # repetir mientras $action "No Es igual a" 'SALIR'
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Y un módulo de los tres:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

package borrar;
use v5.14;
use autodie; 
 
use Exporter;
our @ISA    = qw(Exporter);
our @EXPORT = qw( borrador ); # si pongo @EXPORT_OK, no funciona
 
sub borrador{
        
        say 'borrando';
}
1;
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Bueno, no sé qué te parece el prototipo, yo estoy bastante contento, Gracias por todo.

SALUD...

Foro - Perl en Español

Trabajando con módulos y un menú

Trabajando con módulos y un menú

Publicidad

Re: Trabajando con módulos y un menú

Re: Trabajando con módulos y un menú

Re: Trabajando con módulos y un menú

Re: Trabajando con módulos y un menú

¿Quién está conectado?