Foro - Perl en Español

por **AngelHernandez** » 2012-12-14 18:16 @803

Hola, pues tengo un problema al ejecutar desde mi servidor Apache un script en Windows. El código es el siguiente:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!c:/perl/bin/perl.exe
use Win32::OLE;
 
if ($ENV{'REQUEST_METHOD'} eq 'POST') {
 
    read(STDIN, $buffer, $ENV{'CONTENT_LENGTH'});
 
    @pairs = split(/&/, $buffer);
 
    foreach $pair (@pairs) {
       ($name, $value) = split(/=/, $pair);
       $value =~ tr/+/ /;
       $value =~ s/%([a-fA-F0-9][a-fA-F0-9])/pack("C", hex($1))/eg;
 
    $FORM{$name} = $value;
    }
    
    eval {$ex = Win32::OLE->GetActiveObject('Excel.Application')};
    die "Excel not installed" if $@;
    unless (defined $ex) {
                $ex = Win32::OLE->new('Excel.Application', sub {$_[0]->Quit;})
                or die "Oops, cannot start Excel";
        }
        
        $writeBook = $ex->Workbooks->Open("C:\\Program Files\\Apache Group\\Apache2\\htdocs\\Excel\\credencialMacro.xls");
    $readBook = $ex->Workbooks->Open("C:\\Program Files\\Apache Group\\Apache2\\htdocs\\Excel\\Book2.xls");
 
    $writeSheet = $writeBook->Worksheets("BD");
    $writeSheet->Activate();
        
    $readSheet = $readBook->Worksheets("Sheet2");
    $readSheet->Activate();
        
    my $Tot_Rows = $readSheet->UsedRange->Rows->{'Count'};
        
    my $rows = 1;       
    while($rows <= $Tot_Rows){
                $writeSheet->Cells($rows,2)->{Value} = $readSheet -> Cells($rows,1) -> {Value};
                $rows++;
        }
            
    $ex->{DisplayAlerts} = 0; # alerts Off
    $writeBook->{CheckCompatibility} = "False";
 
    $ex->Run('credencialMacro.xls!creaCredencial'); 
        
        undef $readBook;
    $writeBook->SaveAs( 'C:\\Program Files\\Apache Group\\Apache2\\htdocs\\Excel\\Descargas\\credencialMacro.xls' );
    undef $writeBook;
    undef $ex;
}
 
Coloreado en 0.006 segundos,  usando GeSHi 1.0.8.4

Este código lee dos excel y copia el contenido de uno a otro. Pero me manda el error: Premature end of script headers.

¡¡¡ Auxilio !!!

¿Este programa lo tienes que ejecutar como CGI?

Parece que no...

EDITO: Si lo ejecutas desde la línea de comandos, ¿qué sale en pantalla?

VUELVO A EDITAR: No sé si he hecho la pregunta correcta, así que la haré de otra manera: ¿es necesario que para ejecutar este programa lo hagas usando el Apache y un navegador web? ¿Este programa va a ser ejecutado por parte de un usuario usando el protocolo HTTP? El error que sale es precisamente porque este programa no entrega las cabeceras HTTP que el servidor espera. Y por eso hice la primera pregunta: ¿seguro que este programa no es un programa normal para ser ejecutado desde la línea de comandos? Si es así, sobran todas las líneas que hacen referencia al protocolo CGI.

por **AngelHernandez** » 2012-12-14 19:00 @833

Este código fue hecho en primera instancia para ser ejecutado en línea de comandos, ahí todo funciona como es esperado.

Ahora queremos montarlo en un cgi para que sea llamado dentro de un <form> de un archivo html. Las primeras líneas, en efecto, por el momento no hacen nada, son para asignar los valores que me mandó el <form> a través del POST.

por **explorer** » 2012-12-15 07:44 @363

Bueno, pues entonces, unas consideraciones...

no hace falta que escribas '\\' en cada ocasión. En Windows también se puede usar la barra '/' para crear las rutas:
Sintáxis: [ Descargar ] [ Ocultar ]
Sintáxis: [ Descargar ] [ Mostrar ]
Using perl Syntax Highlighting
1. $readBook = $ex->Workbooks->Open('C:/Program Files/Apache Group/Apache2/htdocs/Excel/Book2.xls');
Coloreado en 0.001 segundos, usando GeSHi 1.0.8.4
estás escribiendo muchas líneas para convertir tu programa en un cgi. Desde hace muchos años, las distribuciones de Perl vienen con el módulo CGI que permite ahorrarte mucho código: en tu programa, las líneas 6 a 16 las hace de forma automática. Mira mi CGI mínimo
para que sea un cgi de verdad, tu programa debe enviar una cabecera HTTP y luego una respuesta HTML, que el servidor web enviará directamente al navegador del usuario.

La operativa del programa está clara: manipular un par de archivos en formato Excel. Lo que no sabemos es qué tiene que salir en la pantalla del usuario. ¿Quizás un mensaje diciendo que el proceso ha terminado bien?

Sería algo así (no probado):

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!C:/perl/bin/perl.exe
use CGI       qw(:standard      );
use CGI::Carp qw(fatalsToBrowser);       # solo para depurado
use Win32::OLE;
 
print header;                              # mandamos la cabecera HTTP
print start_html('Copiado de las hojas');  # inicio de la página HTML
 
## Proceso
my $ex;
eval {                                   # ver si existe el objeto Excel en el sistema
    $ex = Win32::OLE->GetActiveObject('Excel.Application');
};
die "Excel not installed" if $@;         # no, no está
 
unless (defined $ex) {
    $ex = Win32::OLE->new(               # intentamos arrancarlo
            'Excel.Application', sub {$_[0]->Quit;}
        ) or die "Oops, cannot start Excel";
}
 
my $path = 'C:/Program Files/Apache Group/Apache2/htdocs/Excel';
 
my $writeBook = $ex->Workbooks->Open("$path/credencialMacro.xls");
 
my $readBook  = $ex->Workbooks->Open("$path/Book2.xls");
 
my $writeSheet = $writeBook->Worksheets("BD");
$writeSheet->Activate();
       
my $readSheet  = $readBook->Worksheets("Sheet2");
$readSheet->Activate();
       
my $Tot_Rows = $readSheet->UsedRange->Rows->{'Count'};
       
my $rows = 1;      
while ($rows <= $Tot_Rows){
    $writeSheet->Cells($rows,2)->{Value} = $readSheet -> Cells($rows,1) -> {Value};
    $rows++;
}
           
$ex->{DisplayAlerts} = 0;             # alerts Off
$writeBook->{CheckCompatibility} = "False";
 
$ex->Run('credencialMacro.xls!creaCredencial');
       
$writeBook->SaveAs("$path/Descargas/credencialMacro.xls");
 
undef $readBook;
undef $writeBook;
undef $ex;
 
## Salimos
print p('Tarea terminada');           # informamos
print p("$rows filas copiadas");
 
print end_html;                       # fin del HTML
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

P.D.: por motivos de eficiencia, el Excel no debería ser cerrado (Quit), sino estar permanentemente funcionando. Así, la respuesta es mucho más rápida, ya que el sistema operativo no tiene que arrancarlo.

P.P.D.: a la larga, os daréis cuenta de que esto no funcionará de manera confiable (cosas del OLE y Windows... yo ya lo he sufrido... ¿Realmente Windows es un sistema operativo confiable :?:

)

por **AngelHernandez** » 2012-12-16 13:23 @599

Nombre, muchas gracias por tu respuesta, ¡todo ha ido bien!
¡Saludos!

Foro - Perl en Español

CGI con Perl. Problema: Premature end of script headers

CGI con Perl. Problema: Premature end of script headers

Publicidad

Re: CGI con Perl. Problema Premature end of script headers

Re: CGI con Perl. Problema: Premature end of script headers

Re: CGI con Perl. Problema: Premature end of script headers

Re: CGI con Perl. Problema: Premature end of script headers

¿Quién está conectado?