Foro - Perl en Español

por **Alfumao** » 2013-01-03 04:41 @237

Hola a todos,

Planteo aquí un problema que seguramente será muy básico, pero en el que me he atascado como el tontaina que soy.
Pretendo filtrar una lista donde aparece el mismo nombre varias veces pero con valores diferentes y quiero quedarme con el menor de los valores que aparecen para cada nombre.

Este sería un ejemplo de la lista.

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

IDX2    10

IDX4    11

IDX5    12

IDX7    14

IDX12   15

IDX2    10

IDX4    11

IDX5    12

IDX7    14

IDX5    17

IDX6    2

IDX12   37

IDX6    4

IDX12   5

IDX5    6

IDX5    8

IDX6    9

IDX12   15

IDX2    16

IDX4    17

IDX5    18

IDX6    19

IDX7    20

IDX12   21

IDX2    16

IDX4    17

IDX5    18

IDX6    19

IDX7    20

IDX12   21

IDX5    0.1

IDX6    0.2

IDX12   0.3

IDX2    0.10

IDX4    0.11

IDX7    0.14Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

Escribí un código pero los resultados me salen duplicados (es decir para cada nombre de la lista me sale el menor valor pero también otro...)

Ejemplo de resultado erróneo:

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

IDX12    5

IDX5     6

IDX5     0.1

IDX6     0.2

IDX12    0.3

IDX2     0.10

IDX4     0.11

IDX7     0.14Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

Aquí va el código:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use strict;
use warnings;
use diagnostics;
use Getopt::Long;
 
#usage: perl /path_to/hash_order.pl -t /path_to/file.txt
 
my ( $target);
GetOptions(
    'table=s'     => \$target,
     );
 
open(INFILE,"$target") or die ("ERROR: $!\n");
chomp (my @lineas = <INFILE>);
open  SALIDA,'>/path_to/hash_order.txt' or die "ERROR: $!\n";
my %unique=();
 
for(@lineas){
if (/^\w+/){
 
my ($feat,$pval) = split(/\t/, $_);
    print "$feat\n";
    my $href=\%unique;
    &comphash ($feat,$pval,$href)
    
    }
}
 
sub comphash{
   my($feat,$pval,%{href})=@_;
   
   if(exists $unique{$feat}){
       if($pval< $unique{$feat}){
          $unique{$feat}=$pval;
          print SALIDA "$feat\t $unique{$feat}\n";
       }else{
             next;
            }
    }else{
       $unique{$feat}="$pval";
       #print SALIDA "$feat\t $unique{$feat}\n";
    }
    }
Coloreado en 0.003 segundos,  usando GeSHi 1.0.8.4

¿Me podéis ayudar a encontrar el error?

Mil Gracias

#!/usr/bin/perl
use strict;
use warnings;
use diagnostics;
 
use Getopt::Long;
 
# usage: perl /path_to/hash_order.pl -t /path_to/file.txt
 
my $target;
my %unique;
 
GetOptions( 'table=s' => \$target, );
 
open(INFILE, $target) or die("ERROR: $!\n");
 
while (<INFILE>) {
    chomp;
 
    if (/^\w+/) {
        my($feat, $pval) = split(/\t/, $_ );
        comphash( $feat, $pval, \%unique );
    }
}
 
sub comphash {
    my ( $feat, $pval, $unique_ref ) = @_;
 
    if ( not defined $unique_ref->{$feat}  or  $unique_ref->{$feat} > $pval ) {
        $unique_ref->{$feat} = $pval;
    }
}
 
 
open  SALIDA, '>hash_order.txt' or die "ERROR: $!\n";
for my $feat (sort keys %unique) {
    print SALIDA "$feat\t $unique{$feat}\n";
}
close SALIDA;
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Esta es una versión más corta:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use v5.14;
use autodie;
 
# usage: perl /path_to/hash_order.pl /path_to/file.txt
 
my %unique;
 
while (<>) {
    chomp;
    my($feat, $pval) = split;
 
    $unique{$feat} = $pval
        if  not defined $unique{$feat}
        or  $unique{$feat} > $pval
    ;
}
 
open  SALIDA, '>', 'hash_order.txt';
while (my($feat, $pval) = each %unique) {
    say SALIDA "$feat\t$pval";
}
close SALIDA;
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

por **Alfumao** » 2013-01-04 03:13 @176

Una vez más,

¡Muchas gracias, explorer!
Funciona correctamente.

Foro - Perl en Español

Filtrar lista usando hashes

Filtrar lista usando hashes

Publicidad

Re: Filtrar lista usando hashes

Re: Filtrar lista usando hashes

¿Quién está conectado?