Foro - Perl en Español

por **dzavallo** » 2013-01-09 11:51 @535

Hola a todos, soy bastante nuevo en programación en Perl y quiero hacer un script que me haga lo siguiente:

Tengo una lista de genes con números:

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

AT1G01073 18,5

AT1G02470 20

AT1G02590 5

AT1G02590 6,5

AT1G02740 5,5

AT1G03600 5,5

AT1G03600 9

AT1G03600 4,5

AT1G03600 8

AT1G03600 6

AT1G03600 11,5

AT1G03600 4

AT1G04410 4,5Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

Lo que quiero hacer es sumar los números correspondientes a cada gen, pero como verán, algunas son únicas, y otros tienen más de una fila por gen.

Tengo que hacer un script para que me sume las que están repetidas y me deje una única, y obviamente las que están únicas las deje igual y que quede algo así:

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

AT1G01073 18,5

AT1G02470 20

AT1G02590 11,5

AT1G02740 5,5

AT1G03600 48,5

AT1G04410 15,5Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

Empecé a escribir el script pero no puedo sumar los elementos (números) que puse dentro en un array, para luego exportarlos junto con su id.

¿Existe una función para sumar escalares numéricos?

Agradecería su ayuda
Muchas gracias

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/local/bin/perl
use strict;
use warnings;
 
my $input2
    = "/home/diego-ubuntu/0-archivos_deep_seq/DEEP_SEQ1_4dpi/promedios/TAIR/RPM_mapeables/GO/NI_4dpi_genes_sin_sumar";
my $input1 = "/home/diego-ubuntu/0-archivos_deep_seq/DEEP_SEQ1_4dpi/promedios/TAIR/RPM_mapeables/GO/NI_4dpi_ids";
my $output
    = "/home/diego-ubuntu/0-archivos_deep_seq/DEEP_SEQ1_4dpi/promedios/TAIR/RPM_mapeables/GO/NI_4dpi_genes_sumados";
open( FILE1,      "<$input1.txt" )  or die "could not open $input1 file";
open( OUTPUTFILE, ">>$output.txt" ) or die "could not open $output file";
while (<FILE1>) {                      # AT1G01073
    my @split1 = split( /\s+/, $_ );
    chomp $_;                          # borra las lineas vacias
    my $id1 = $_;
    my @array;                         # defino el array que va a contener las cuentas de id repetidos
    open( FILE2, "<$input2.txt" ) or die "could not open $input2 file";
    while (<FILE2>) {                  # AT1G01073 6
        my @split2 = split( /\s+/, $_ );
        my $id2    = $split2[0];
        my $counts = $split2[1];
        chomp $_;
        if ( $id1 eq $id2 ) {
            push( @array, $counts );   #como sumo $counts para luego imprimirlos?
 
            print OUTPUTFILE "$id1\t$counts\n"
 
        }
    }
}
 
Coloreado en 0.004 segundos,  usando GeSHi 1.0.8.4

Soy yo de nuevo, una cosa que se me ocurrió pero que no funciona, es crear una nueva variable $total, y que esa sume los elementos dentro del @array

Puede ser así:

push (@array, $counts);
my $total +=$counts ;
print OUTPUTFILE "$id1\t$total\n"

De todos modos no me funciona y sigue exportándome el mismo archivo inicial.

¿alguna sugerencia?

Muchas gracias

por **explorer** » 2013-01-09 12:59 @582

Bienvenido a los foros de Perl en Español, dzavallo.

Este es un problema típico que se puede resolver muy fácilmente con un hash.

Solo tienes que guardar como claves del hash el nombre de los genes, y como valores, vas acumulando los valores que vas leyendo.

Así, al final, tendrás la suma separada por cada gen, tanto si ha aparecido una sola vez, o cien.

Un detalle: para que Perl haga las sumas correctas, los números, deben tener notación anglosajona: debes cambiar las comas separadoras de la parte fraccionaria por puntos.

por **dzavallo** » 2013-01-09 13:42 @612

explorer, muchas gracias por tu respuesta.

Mientras esperaba se me ocurrió otra manera para solucionarlo y funcionó, pero seguramente con la que tu dices es mucho más rápida.

Entiendo que al asignar las keys al %hash ¿automáticamente me va a sumar las cuentas?
¿O tu respuesta era para resolver la última parte del script?

Te muestro el script con mi solución final, probablemente sea muy redundante y frente a archivos enormes tarde mucho, ¿no es así?

Muchas gracias nuevamente, muy bueno el foro.

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

use strict;
use warnings;
 
 
my $input2 = "/home/diego-ubuntu/0-archivos_deep_seq/DEEP_SEQ1_4dpi/promedios/TAIR/RPM_mapeables/GO/NI_4dpi_genes_sin_sumar";
my $input1 = "/home/diego-ubuntu/0-archivos_deep_seq/DEEP_SEQ1_4dpi/promedios/TAIR/RPM_mapeables/GO/NI_4dpi_ids";
my $output = "/home/diego-ubuntu/0-archivos_deep_seq/DEEP_SEQ1_4dpi/promedios/TAIR/RPM_mapeables/GO/NI_4dpi_genes_sumados1";
open(FILE1, "<$input1.txt") or die "could not open $input1 file";
open(OUTPUTFILE, ">>$output.txt") or die "could not open $output file";
while (<FILE1>) {       # AT1G01073 (lee de a una las lineas del file1)
        my @split1 = split (/\s+/, $_); # spliteo por espacios las columnas
        chomp $_; # borra las lineas vacías
        my $id1 = $_; # defino la columna id1
        my @array; # defino el array que va a contener las cuentas de id repetidos
        open(FILE2, "<$input2.txt") or die "could not open $input2 file"; 
        while (<FILE2>) { # AT1G01073 6 (este es otro loop dentro del primer loop y también lee de a una las lineas del file2
                my @split2= split (/\s+/, $_); 
                my $id2 = $split2[0]; # defino el id2
                my $counts = $split2[1]; # defino las cuentas
                chomp $_;
                if ($id1 eq $id2) { 
                        push (@array, $counts); # si id1= id2 mete en un array las cuentas (esto puede ser uno solo o varios números)
                } #cierro el loop if
        } #cierro el loop while del file2
        my $total = 0; #defino la variable total con un 0 para que sepa que es numérica
        foreach (@array) { # para cada elemento del array 
                $total = $total + $_; # sumo la variable total=0 al primer elemento del array, y luego ese total lo suma al siguiente elemento y así hasta que se terminen los elementos del array
        } #cierro el lop foreach
        print OUTPUTFILE "$id1\t$total\n"
}
Coloreado en 0.003 segundos,  usando GeSHi 1.0.8.4

por **explorer** » 2013-01-09 18:28 @811

Pues sí, puede ser muy lento si los archivos son muy grandes.

No, los hash no suman de forma predeterminada. Solo guardan los valores que le indiquemos. Si es una suma, pues el resultado de la suma.

Esta es la versión más pequeña.

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use v5.14;
use autodie;                    # «Es mejor morir que regresar con deshonor» --proverbio Klingon
 
my $ruta = '/home/diego-ubuntu/0-archivos_deep_seq/DEEP_SEQ1_4dpi/promedios/TAIR/RPM_mapeables/GO';
my $archivo_a_procesar = "$ruta/NI_4dpi_genes_sin_sumar";
my $archivo_resultado  = "$ruta/NI_4dpi_genes_sumados1";
 
my %genes;
 
open my $GENES, '<', $archivo_a_procesar;
while (<$GENES>) {              # leemos una línea, mientras no lleguemos al final
    chomp;                      # quitamos el carácter de nueva línea
 
    my($gen, $valor) = split;   # partimos
 
    $valor =~ s/[,]/./;         # pasamos a notación anglosajona
 
    $genes{$gen} += $valor;     # acumulamos
}
close $GENES;
 
open my $SALIDA, '>', $archivo_resultado;
while (my($gen, $valor) = each %genes) {       # para cada par clave/valor
    say $SALIDA "$gen $valor";                 # los mandamos a la $SALIDA
}
close $SALIDA;
 
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Sale:

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

AT1G04410 4.5

AT1G02470 20

AT1G01073 18.5

AT1G03600 48.5

AT1G02740 5.5

AT1G02590 11.5Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

Como ves, toda la operación se reduce a la línea 19, donde vamos acumulando los valores según el $gen que hayamos leído.

Imagínate un archivador que tiene un cajón por cada gen. Por cada línea que leemos, buscamos el cajón del gen, lo abrimos, y acumulamos el valor que tenía con el nuevo valor leído.

por **dzavallo** » 2013-01-10 09:45 @448

explorer, ¡muchas gracias por tu ayuda!
Probé el script y efectivamente corre mucho más rápido.
Muy bueno el foro, lo seguiré consultando.

Foro - Perl en Español

Cómo sumar elementos escalares numéricos dentro de un array

Cómo sumar elementos escalares numéricos dentro de un array

Publicidad

Re: Cómo sumar elementos escalares numéricos dentro de un ar

Re: Cómo sumar elementos escalares numéricos dentro de un ar

Re: Cómo sumar elementos escalares numéricos dentro de un ar

Re: Cómo sumar elementos escalares numéricos dentro de un ar

Re: Cómo sumar elementos escalares numéricos dentro de un ar

¿Quién está conectado?