Foro - Perl en Español

por **josele** » 2012-09-11 20:30 @896

Buenas noches.

En primer lugar daros las gracias por existir, mis conocimientos de Perl son muy básicos pero con este foro y el copy-paste de partes de código voy haciendo mis cositas.

A lo que vamos:

Tengo dos ficheros, con varios campos cada uno, quiero comparar el primero con el segundo y generar un tercer fichero con las líneas del primero menos las líneas que contengan el mismo id ($c1) que los id ($c2) del segundo fichero.

Consigo hacer algo parecido el problema es que como hago dos bucles me repite las líneas cada vez que recorre el bucle.

Espero haberme explicado bien, aquí os dejo lo que he intentado hacer ( chapuza ).

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

open( COMISI, "COMISIONES.txt" ) || die "ERROR";
while (<COMISI>) {
    ( $c1, $c2, $c3, $c4, $c5, $c6 ) = split /;/, $_;
    chomp($c6);
    open( TFILE,         ">>SALIDA.txt" )          || die "ERROR";
    open( LINEASFACTURA, "COMISIONESAQUITAR.txt" ) || die "ERROR";
    while (<LINEASFACTURA>) {
        ( $d1, $d2, $d3, $d4, $d5, $d6 ) = split /;/, $_;
        chomp($d6);
        if ( $d1 ne $c1 ) {
            print TFILE"$c1;$c2;$c3;$c4;$c5;$c6\n";
        }
    }
    close(LINEASFACTURA);
    close(TFILE);
}
close(COMISI);
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

Muchas gracias.

--
Josele

open my $COMISI, "<COMISIONES.txt" or die "ERROR: No puedo abrir COMISI.txt: $!\n";
open my $TFILE,  ">SALIDA.txt"     or die "ERROR: No puedo escribir  SALIDA.txt: $!\n";
 
BUCLE:
while (my $linea = <$COMISI>) {
    my @c = split /;/, $linea;
 
    open my $LINEASFACTURA, "<COMISIONESAQUITAR.txt" or die "ERROR: No puedo abrir COMISIONESAQUITAR.txt: $!\n";
    while (<$LINEASFACTURA>) {
        my @d = split /;/;
        if ( $d[0] eq $c[0] ) {      # si encontramos una coincidencia en los primeros campos
            close $LINEASFACTURA;    # cerramos: no necesitamos seguir buscando más
            next BUCLE;              # y saltamos a probar con la siguiente línea
        }
    }
    close $LINEASFACTURA;
 
    print $TFILE $linea;             # si no hemos encontrado ninguna coincidencia, escribimos la $linea
}
 
close $TFILE;
close $COMISI;
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Pero creo que esta es una solución más rápida:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/env perl
use autodie;
 
my %facturas;
open my $LINEASFACTURA, "<COMISIONESAQUITAR.txt";
while (<$LINEASFACTURA>) {                 # leemos la remesa de facturas
    my($id) = split /;/, $_, 2;
    $facturas{$id} = 1;                    # guardamos los códigos de todas las facturas
}
close $LINEASFACTURA;
 
open my $COMISI, "<COMISIONES.txt";
open my $TFILE,  ">SALIDA.txt";
 
while (my $linea = <$COMISI>) {
    my($id) = split /;/, $linea, 2;
 
    if ( not exists $facturas{ $id } ) {   # si no existe alguna factura que tenga ese $id,
        print $TFILE $linea;               # escribimos la $linea
    }
}
 
close $TFILE;
close $COMISI;
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

por **josele** » 2012-12-02 15:16 @678

explorer, aún no te he agradecido la ayuda, no tengo vergüenza.

Pues eso: MUCHÍSIMAS GRACIAS, me has evitado un motón de tiempo perdido y varios dolores de cabeza.

Y aprovechando que el Pisuerga pasa por Valladolid, ciudad donde ambos residimos, me ofrezco a invitarte a unas cervezas, o si lo prefieres a un chuletón cuanto te venga bien.

Mándame un privado.
--
Josele

por **explorer** » 2012-12-25 09:56 @455

Pues mira: estaría bien aprovechar estos días para vernos y comentar sobre Perl

El día 27 estoy en Madrid al mini hackaton del proyecto Perl en Español, así que quizás mejor dejarlo para la semana que viene.

por **sufisavey80** » 2013-02-21 19:03 @836

Buenas tardes, explorer.

En ocasión anterior ya me habías apoyado, ya que me voy iniciando en Perl y agradezco tu apoyo, tengo el siguiente caso:

Tengo 2 archivos llamados "datos.csv" (tiene 21 registros) y "posicion.csv" (tiene 47 registros). Al archivo "datos.csv" quiero copiarle la columna [6] del archivo "posicion.csv" a los que son iguales en la columna [41] de ambos, generando un tercer archivo "SALIDA.txt", o ya sea en el mismo "datos.csv", quedando al final los 21 registros con la nueva información.

Intenté lo siguiente, pero igual no sea la manera:

open my $datos, "<datos.csv" or die "ERROR: No puedo abrir datos.csv: $!\n";
open my $TFILE, ">SALIDA.txt" or die "ERROR: No puedo escribir SALIDA.txt: $!\n";

BUCLE:
while (my $linea = <$datos>) {
my @c = split ',', $linea;

open my $posicion, "<posicion.csv" or die "ERROR: No puedo abrir posicion.csv: $!\n";
while (<$posicion>) {
my @d = split ',';
if ( $d[41] eq $c[41] ) {
$c[6] = $d[6];
print $TFILE $linea;
next BUCLE;
}
}
close $posicion;

}

close $TFILE;
close $datos;

Espero me expliqué bien,

¡Muchas gracias de antemano!

por **explorer** » 2013-02-21 21:36 @942

Casi lo tenías...

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

!/usr/bin/perl
use autodie;                                    # «Es mejor morir que regresar con deshonor» --proverbio Klingon
 
open my $datos,  '<', "datos.csv";
open my $salida, '>', "SALIDA.txt";
 
while (my $linea = <$datos>) {                  # leemos una línea
    chomp $linea;                               # quitamos carácter nueva línea, por si acaso
    my @datos = split /[,]/, $linea;            # partimos en columnas
 
    open my $posicion, '<', "posicion.csv";
    while (<$posicion>) {
        chomp;
        my @posicion = split /[,]/;
 
        if ($datos[41] eq $posicion[41]) {
            $datos[6]  =  $posicion[6];
        }
    }
    close $posicion;
 
    print $salida join(',', @datos), "\n";      # generamos una línea de salida a partir de los @datos modificados
}
 
close $salida;
close $datos;
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Pero... la solución no es nada eficiente: estás leyendo, entero, el archivo "posicion.csv", por cada registro del archivo "datos.csv".

Lo ideal es que solo lo leyeras una vez. Eso se consigue almacenando toda la información en memoria, en un array, por ejemplo.

por **sufisavey80** » 2013-02-22 12:57 @581

Buenas tardes, explorer...

Muchas gracias por tu ayuda, se logró el objetivo de generar el tercer archivo con la nueva información... ¡Eres todo un master!

Saludos cordiales.

Foro - Perl en Español

Comparar 2 ficheros y crear un 3º sin las líneas del 2º

Comparar 2 ficheros y crear un 3º sin las líneas del 2º

Publicidad

Re: Comparar 2 ficheros y crear un 3º sin las líneas del 2º

Re: Comparar 2 ficheros y crear un 3º sin las líneas del 2º

Re: Comparar 2 ficheros y crear un 3º sin las líneas del 2º

Re: Comparar 2 ficheros y crear un 3º sin las líneas del 2º

Re: Comparar 2 ficheros y crear un 3º sin las líneas del 2º

Re: Comparar 2 ficheros y crear un 3º sin las líneas del 2º

¿Quién está conectado?