Foro - Perl en Español

por **Eowyn** » 2013-03-11 06:26 @309

Hola, tengo un problema con esta parte de un programa. No me da ningún error, pero no hace lo que pretendo que haga:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

my $fitxkopia;
open( my $FITX, $fitxategia );
{
    local $/;
    $fitxkopia = <$FITX>;
 
    #    $fitxkopia;
}
close $FITX;
&Hash_Taula_Kargatu($fitxkopia);
 
sub Hash_Taula_Kargatu {
    my @term_arraya1;
    my @term_arraya2;
 
    my %Moten_Hash_Taula = (
        "N.IZE-ARR" => \@term_arraya1,
        "G.ADJ-ARR" => \@term_arraya2
    );
    my $fitxategia2 = $fitxkopia;
    chomp($fitxategia2);
    my $FITXkop = XML::XPath->new( filename => $fitxategia2 );    #irakurri fitxategia;
 
    my $nodeset = $FITXkop->find('/KAF/terms/term');              # bilatu "term" paragrafoak kaf fitxategian.
    my $gakoa;
 
    foreach my $node ( $nodeset->get_nodelist ) {
        my $term = XML::XPath::XMLParser::as_string($node);       #Nodo horren informazioa string moduan gorde.
 
        ($gakoa) = $term =~ /pos="(.*?)"/;
        push( @{ $Moten_Hash_Taula{"$gakoa"} }, $term );
        my @array = @{ $Moten_Hash_Taula{"N.IZE-ARR"} };
 
        #
        print(@array);
    }
 
}
 
 
Coloreado en 0.003 segundos,  usando GeSHi 1.0.8.4

Quiero que coja el archivo, lo lea y cargue algunas partes (las que tienen N.IZE-ARR) en una tabla hash en la clave "N.IZE_ARR". Para comprobar si lo carga hago print(@array), pero en lugar de eso lo que hace es sacarme por pantalla todo el archivo. He probado quitando el "print" pero no afecta. Si ejecuto la subrutina por su lado (es decir, de la línea 16 en adelante), lo hace bien, es decir, sólo imprime lo que quiero, pero no para nunca (bucle infinito). ¡Qué lío! :oops:

si no es necesario que existan las claves por adelantado. En tu caso, en la línea 31 estás poblando el hash, así que las claves se van creando de forma automática.

El bucle infinito debe ser por otra razón. El bucle está gobernado por lo que devuelve $nodeset->get_nodelist().

¿Esto es también un bucle infinito?

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

my $i = 0;
for my $node ( $nodeset->get_nodelist ) {
    $i++;
}
print "$i nodos\n";
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

por **Eowyn** » 2013-03-12 16:59 @749

¡Muchas gracias! Eres como un angelillo de Perl :wink:

Los valores de $gakoa son correctos, incluso lo que devuelve el array es correcto y he podido arreglarlo en el subprograma. Es decir, el subprograma en sí funciona bien.

El problema viene en el main: en lugar de devolverme lo mismo que el subprograma (ya que el main sólo hace de nuevo coger el archivo, copiarlo a otro sitio y ejecutar el subprograma) me devuelve el archivo entero. Y lo más paranormal de todo es que incluso quitando el "print" me devuelve el archivo entero. Seguro que esto tiene sentido para ti, pero para mí... :oops:

por **explorer** » 2013-03-12 18:03 @794

Lo que hace leer todo el archivo de golpe es la línea

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

    local $/;
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

que hace que la línea siguiente lea todo el archivo y lo meta dentro de $fitxkopia.

Lo curioso es:

en la línea 10 pasas $fitxkopia a la función, pero luego ella no lo lee como argumento, si no que lees en la línea 20 de forma directa
en la línea 20 copiamos el contenido de $fitxkopia a $fitxategia2, por lo que esta última contendrá todo el archivo leído antes
en la línea 22 mandamos leer un archivo cuyo nombre es el contenido en $fitxategia2. Se supone entonces que el primer archivo contenía solo el nombre de otro archivo, que es el que queremos realmente interpretar

Cuando hablas del main creo que te refieres a las líneas 1 a 10 que has publicado. Yo no veo problemas ahí. Son líneas muy claras.

Debes poner print() en cada fase del programa, para saber qué está haciendo. Y sacar los valores principales. Por ejemplo: no hace falta sacar el contenido de los nodos, sino solo cuántos nodos son. Y los valores que leemos desde archivos, sacarlos con corchetes:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

print "[$fitxkopia]\n";
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

así sabremos si hay algún carácter extra que no debiera.

En último caso, habrá que usar el depurador para ir paso a paso y ver qué está haciendo.

por **Eowyn** » 2013-03-19 18:05 @795

Lo siento pero esta vez no he entendido muy bien qué debo hacer.

Mi intención es esta:

Meto el nombre del archivo por teclado.
Cojo ese archivo y lo copio entero en la variable $fitxkopia
Paso el archivo en $fitxkopia como parámetro a la subrutina Hash_Taula_Kargatu()
Se ejecuta la subrutina
Me saca en pantalla los nodos de la tabla hash que ha cargado con ese archivo y cuya clave sea $gakoa.

Como digo, funciona bien si ejecuto sólo la subrutina, el problema parece venir de o bien no saber pasar el parámetro, o bien no saber hacer la copia. :cry:

por **explorer** » 2013-03-19 18:54 @829

Con tu explicación, ya queda más claro todo.

Y ahora vienen los problemas

¿Para qué necesitas leer todo el archivo en las líneas 2 a 8 si en la línea 28 el propio módulo XML::XPath ya se encarga de ello? (línea 22). Fíjate que estás pasando un argumento a new() en esa línea con la clave 'filename'. Según la página de manual: The filename parameter specifies an XML file to parse. Así que no necesitas leer el archivo XML porque ya se encarga de eso el propio new().

El programa quedaría así (no probado):

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
 
# Meto el nombre del archivo por teclado.
print "Sartu fitxategiaren izena: ";
my $fitxategia = <STDIN>;
chomp $fitxategia;
 
-f $fitxategia  or  die "ERROREA: Ezin da fitxategi $fitxategia hori aurkitu";
 
 
# Paso el nombre del archivo como parámetro a la subrutina Hash_Taula_Kargatu()
Hash_Taula_Kargatu($fitxategia);
 
 
# Me saca en pantalla los nodos de la tabla hash que ha cargado con ese archivo y cuya clave sea $gakoa.
sub Hash_Taula_Kargatu {
    my $fitxategi = shift;                                      # irakurri parametroa
 
    my %Moten_Hash_Taula = (
        'N.IZE-ARR' => [],
        'G.ADJ-ARR' => [],
    );
 
    my $xpath = XML::XPath->new( filename => $fitxategi );      # irakurri fitxategia
 
    my $nodeset = $xpath->find('/KAF/terms/term');              # bilatu "term" paragrafoa KAF fitxategian
 
    foreach my $node ( $nodeset->get_nodelist ) {
 
        my $term = XML::XPath::XMLParser::as_string($node);     # Nodo horren informazioa string moduan gorde
 
        my($gakoa) =  $term =~ /pos="(.*?)"/;
 
        if (defined $gakoa) {
            push @{  $Moten_Hash_Taula{ $gakoa }  }, $term;
        }
    }
 
    print "@{ $Moten_Hash_Taula{'N.IZE-ARR'} }\n";
 
    #use Data::Dumper;
    #print Dumper \%Moten_Hash_Taula;
}
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

por **Eowyn** » 2013-03-21 04:42 @237

Ahora ya me aclaro. ¡Muchísimas gracias! :oops:

Foro - Perl en Español

Bucle infinito

Bucle infinito

Publicidad

Re: Bucle infinito

Re: Bucle infinito

Re: Bucle infinito

Re: Bucle infinito

Re: Bucle infinito

Re: Bucle infinito

¿Quién está conectado?