Foro - Perl en Español

por **BigBear** » 2013-03-15 20:25 @892

No entiendo la segunda expresión regular porque es la que me falta. El código quedó así:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

my $valor = "GET http://localhost/shell.php?upload= HTTP/1.1 dsadsad";
 
#[ver] : GET
#[url] : http://localhost/shell.php?upload=
#[version] : 1.1
 
#verb = request_line[/^\w+/]
#url = request_line[/^\w+\s+(\S+)/, 1]
#version = request_line[/HTTP\/(1\.\d)\s*$/, 1]
 
if($valor=~/^(.*?) (.*?)/) {
print "[+] Metodo : ".$1."\n";
}
 
if($valor=~/^\w+\s+(\S+)/) {
#print $2;
}
 
if($valor=~/HTTP\/1\.(.*) (.*)/) {
print "[+] version : HTTP/1.".$1;
}
 
Coloreado en 0.004 segundos,  usando GeSHi 1.0.8.4

¿ Cómo hago la segunda expresión regular en Perl ?

  GET http://localhost/shell.php

Host: localhost

User-Agent: Mozilla/5.0 (Windows NT 5.1; rv:19.0) Gecko/20100101 Firefox/19.0

Accept: text/html,application/xhtml+xml,application/xml;q=0.9,*/*;q=0.8

Accept-Language: es-ar,es;q=0.8,en-us;q=0.5,en;q=0.3

Accept-Encoding: gzip, deflate

Cookie: __utma=111872281.314525818.1360496478.1360496478.1360759913.2; __utmz=11

1872281.1360496478.1.1.utmccn=(direct)|utmcsr=(direct)|utmcmd=(none); PHPSESSID=

ue0okrcmjmb6r80mbbkletg866Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

¿ hay otra forma que no sea con sockets ?

por **explorer** » 2013-03-16 12:23 @557

Si la información la has obtenido mediante una petición HTTP, pues sí, puedes usar esos módulos para obtener todas las cabeceras de la respuesta.

Pero... ¿qué tiene esto que ver con un proxy?

por **BigBear** » 2013-03-16 13:31 @605

nada, solo una pregunta al aire, mira este código :

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

my $valor = "GET http://localhost/sql.php HTTP/1.1";
 
use IO::Socket;
 
my $socket = IO::Socket::INET->new(Proto => "tcp",PeerAddr=>"localhost",PeerPort =>"80") or die("error");
 
print $socket $valor."\r\n";
 
read $socket,$total,"1000";
 
print $total."\r\n";
 
$socket->close;
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

Se supone que debe devolver esa petición pero se queda tildado eternamente sin mostrar nada , ¿ hice algo mal ?

por **explorer** » 2013-03-16 17:10 @757

Seguramente porque le estás pidiendo que lea 1000 bytes, y a lo peor la respuesta que recibes no llega a esa cifra. Y se queda esperando más.

Se puede hacer mucho más sencillo:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

use LWP::UserAgent;
$ua = LWP::UserAgent->new;
$req = HTTP::Request->new(
    GET => 'http://localhost/sql.php',
);
$res = $ua->request($req);
if ($res->is_success) {
    print $res->as_string;
}
else {
    print "Error: " . $res->status_line . "\n";
}
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Ejemplo sacado del principio de la página de manual lwpcook (en tu ordenador, ejecuta man lwpcook).

por **BigBear** » 2013-03-16 19:29 @854

Tengo que hacerlo con sockets para hacer el proxy, por suerte ya avance en algo:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

my $valor = "GET http://localhost/sql.php HTTP/1.0";
 
use IO::Socket;
 
my $socket = IO::Socket::INET->new(Proto => "tcp",PeerAddr=>"localhost",PeerPort =>"80") or die("error");
 
print $socket $valor."\r\n\r\n";
 
read $socket,$total,"9999";
 
print $total;
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Lo raro es que si le cambio el 1.0 a 1.1 deja de andar, pero el proxy que te mostré hecho en Ruby usa 1.1 para cargar la misma página de ejemplo, ¿ qué tendría que hacer ?

Quería preguntarte cómo se tendría que cambiar el contenido de la respuesta por un "hola mundo" en este código:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#############################
# proxy-adkiller
# Mike Schilli, 2012
#   ([email protected])
#############################
use strict;
use HTTP::Proxy;
use HTTP::Proxy::HeaderFilter::simple;
use HTTP::Request::Common;
 
my $proxy = HTTP::Proxy->new(
    host => "192.168.1.123",
    port => 9999
);
 
my $repl = "http://perlmeister.com/test/" . "sandy-beach.jpg";
 
$proxy->push_filter(
    request => HTTP::Proxy::HeaderFilter::simple->new(
        sub {
            my ( $self, $headers, $req ) = @_;
 
            if ( $req->uri() =~ /eviladserver\.com/ ) {
                $_[2] = GET $repl;
            }
        }
    )
);
 
$proxy->start;
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Intenté con

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

$_[2] = "hola mundo";
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

pero no funciona.

¿ Cómo se tendría que hacer ?

por **explorer** » 2013-04-02 20:03 @877

En la carpeta de ejemplos de la distribución HTTP-Proxy hay uno que se llama adblock.pl, que copio y comento aquí:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl -w
use strict;
use HTTP::Proxy qw( :log );
use HTTP::Proxy::HeaderFilter::simple;
use vars qw( $re );
 
# this is a very simple ad blocker
# a full-fledged ad blocker should be a module
 
# this dot is *not* a web bug ;-)                    # en estas líneas creamos la modificación o respuesta del proxy
my $no = HTTP::Response->new( 200 );                 # Creamos un objeto HTTP::Response, con código 200 (todo ha ido bien)
$no->content_type('text/plain');                     # El contenido será texto
$no->content('.');                                   # Ese texto (un simple punto)
 
my $filter = HTTP::Proxy::HeaderFilter::simple->new( sub {     # Definimos el filtro a poner en el proxy
   my ( $self, $headers, $message ) = @_;                      # Siempre recibimos tres argumentos
   $self->proxy->response( $no )                               # Respondemos con la respuesta creada antes...
       if $message->uri->host =~ /$re/o;                       #  si el host en la petición es alguno de los
                                                               #   definidos más abajo
} );
 
my $proxy = HTTP::Proxy->new( @ARGV );                         # Aquí creamos el objeto Proxy
$proxy->push_filter( request => $filter );                     # y le añadimos nuestro filtro
$proxy->start;                                                 # y lo ponemos en marcha
 
# a short and basic list
BEGIN {                                                        # lista de direcciones a filtrar
    $re = join '|',
      map { quotemeta } qw(
        ads.wanadooregie.com
        cybermonitor.com
        doubleclick.com
        adfu.blockstackers.com
        bannerswap.com
        click2net.com
        clickxchange.com
        dimeclicks.com
        fastclick.net
        mediacharger.com
        mediaplex.com
        myaffiliateprogram.com
        netads.hotwired.com
        valueclick.com
    );
}
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

Lo que hace el programa es lanzar un proxy, que cuando recibe alguna petición para conectarse a alguno de los sitios listados, sustituye la petición por una respuesta prefabricada: un mísero punto.

por **BigBear** » 2013-04-03 15:37 @692

Ok, gracias por el ejemplo. Ya sé capturar la respuesta, ahora me falta capturar las cabeceras. Mira el código:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!usr/bin/perl
#A simple Proxy Server
#Coded By Doddy H
#ppm install http://theoryx5.uwinnipeg.ca/ppms/HTTP-Proxy.ppd
 
use HTTP::Proxy;
use HTTP::Proxy::BodyFilter::simple;
use HTTP::Proxy::BodyFilter::complete;
use Data::Dumper;
 
my $port = "8080"; 
my $logs = "logs.txt";
 
print "\n\n[+] Proxy server Online in port $port\n\n";
 
my $server = HTTP::Proxy->new(port=>$port);
$server->host();
 
$server->push_filter(mime=>undef,response => HTTP::Proxy::BodyFilter::complete->new());
 
$server->push_filter(
mime=>undef,
request=>HTTP::Proxy::BodyFilter::simple->new(\&enable),
response => HTTP::Proxy::BodyFilter::simple->new(\&enable2));
 
$server->start();
 
sub enable {
 
my @logs;
my($a,$b,$c,$d,$e) = @_;
my ($f,$g)=($c->header("cookie"),$c->header("x-requested-with"));
my ($h,$i)=($c->header("content-type"),$c->header("content"));
 
#print Dumper $c;
 
print $c->header("user-agent");
 
savefile($logs,"\n[Peticion] : ".$c->method." ".$c->uri);
savefile($logs,"[Cookie] : ".$f) if $f;
savefile($logs,"[x-requested-with] : ".$g) if $g;
savefile($logs,"[Content Type] : ".$h) if $h;
savefile($logs,"[Content] : ".$i) if $i;
savefile($logs,"");
 
}
 
sub enable2 {
my ($j,$k,$l,$m,$n) = @_;
savefile($logs,"\n\n[START]\n\n".$$k."\n\n[END]\n") if $$k ne "";
}
 
sub savefile {
open (SAVE,">>".$_[0]);
print SAVE $_[1]."\n";
close SAVE; 
}
 
# ¿ The End ?
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

El problema es que no muestra el User-Agent pero cuando vuelvo $c me muestra varias veces user-agent al contrario de cuando lo hago sin volcar. El volcado es así:

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

$VAR1 = bless( {

                 '_protocol' => 'HTTP/1.1',

                 '_content' => '',

                 '_uri' => bless( do{\(my $o = 'http://localhost/shell.php')}, 'URI::http' ),

                 '_headers' => bless( {

                                        'user-agent' => 'Mozilla/5.0 (Windows NT 5.1; rv:19.0) Gecko/20100101 Firefox/19.0',

                                        'accept' => 'text/html,application/xhtml+xml,application/xml;q=0.9,*/*;q=0.8',

                                        'accept-language' => 'es-ar,es;q=0.8,en-us;q=0.5,en;q=0.3',

                                        'cookie' => 'PHPSESSID=g6p3jjfb34qcl4kjmpg1833th7',

                                        'host' => 'localhost',

                                        'via' => '1.1 doddy-701c8cb49 (HTTP::Proxy/0.20)',

                                        'x-forwarded-for' => '127.0.0.1'

                                      }, 'HTTP::Headers' ),

                 '_method' => 'GET'

               }, 'HTTP::Request' );
Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

¿ Qué estoy haciendo mal ?

por **explorer** » 2013-04-03 19:52 @869

¿Has probado a sacar un volcado de $b?

Debería salir un objeto HTTP::Headers.

Según el manual de HTTP::Proxy::HeaderFilter , $b guarda un objeto HTTP::Headers, que son las cabeceras que el filtro enviará al cliente en caso de que el proxy esté en el lado de la respuesta, o lo enviará al servidor, si está en el lado de la consulta (como creo que es tu caso). Entonces, el proxy puede modificar esas cabeceras cuando pasan a través de él.

En cambio, $c contiene un objeto HTTP::Response (si estamos filtrando la respuesta) o un objeto HTTP::Request (si estamos filtrando la consulta). De este último, quieres obtener el 'user-agent'. Bueno, no sé el porqué no te funciona el método header(). Según el manual de HTTP::Request, debería ser así. Y se ve en el volcado que sí que está.

Con este programa de una línea, se demuestra que sí se puede acceder a esa cabecera:

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

perl -MData::Dumper -MHTTP::Request::Common -E '$req = GET "http://perlenespanol.com", User_Agent => "Mi Agente"; say Dumper $req; say $req->header("user-agent")'

$VAR1 = bless( {

                 '_content' => '',

                 '_uri' => bless( do{\(my $o = 'http://perlenespanol.com')}, 'URI::http' ),

                 '_headers' => bless( {

                                        'user-agent' => 'Mi Agente'

                                      }, 'HTTP::Headers' ),

                 '_method' => 'GET'

               }, 'HTTP::Request' );

Mi AgenteColoreado en 0.000 segundos,  usando GeSHi 1.0.8.4

Lo que hacemos es crear un objeto HTTP::Request, con solo la URL y una cabecera User-Agent inventada. Luego hacemos un volcado para ver el contenido, y luego accedemos directamente al valor de esa cabecera.

(Nota: si te fijas, da igual escribirlo en minúsculas/mayúsculas o si el guión es bajo o medio. HTTP::Headers se ocupa de eso)

Así que no sé qué es lo que te pasa...

Foro - Perl en Español

Duda con módulo HTTP::Proxy

Re: Duda con módulo HTTP::Proxy

Publicidad

Re: Duda con módulo HTTP::Proxy

Re: Duda con módulo HTTP::Proxy

Re: Duda con módulo HTTP::Proxy

Re: Duda con módulo HTTP::Proxy

Re: Duda con módulo HTTP::Proxy

Re: Duda con módulo HTTP::Proxy

Re: Duda con módulo HTTP::Proxy

Re: Duda con módulo HTTP::Proxy

Re: Duda con módulo HTTP::Proxy

¿Quién está conectado?