Foro - Perl en Español

por **enric73** » 2013-05-06 14:47 @658

Hola, gente. Consulta: tengo dos ficheros txt. Los junto. Luego quiero añadir una primera fila en el nuevo fichero con el nombre de Canarias Finisterre. Me parece que el código queda demasiado largo, y tampoco me quedan alienadas las columnas con el nombre que añado en cada una de ellas.

Cada fichero original contiene una columna de 4 números:

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

57

70

90

15Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

El resultado:

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

Canarias Finisterre

87 0.57 

87 0.70 

85 0.90 

80 1.15Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

Realmente me gustaría que la columna de números que corresponde a Finisterre estuviera alineada, debajo justo de Finisterre. En resumen, una columna bien hecha.

El código:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl

open(UN,"<alturaolascanarias.txt");# Abrir...
open(DOS,"<alturaolasFinisterre.txt");
open(OUT,">alturaolas.dat");

while($u=<UN>){# Leemos del primer fichero
$dos=<DOS>;# Leemos del segundo
chomp($u,$dos);
print OUT "$u $dos \n";
}

close(UN);
close(DOS);
close(OUT);

use Tie::File;

tiemy@fichero,'Tie::File','alturaolas.dat'ordie"ERROR: No se pude enlazar con el fichero: $!\n";

splice@fichero,0,0,'Canarias Finisterre';# Insertar una línea al principioColoreado en 0.004 segundos,  usando GeSHi 1.0.8.4

Saludos y gracias

#!/usr/bin/perl
 
open(AOC, "<alturaolascanarias.txt");
open(AOF, "<alturaolasFinisterre.txt");
open(OUT, ">alturaolas.dat");
 
@AOC = <AOC>; #Guardo archivos en Arrays
@AOF = <AOF>;
 
for ($i=0;$i<scalar(@AOC);$i++){ #Hago un for desde 0 hasta el largo del primer archivo
    if ($i==0){
        print OUT "Canarias Finisterre\n"; #Si es la primera línea inserto Canarias Finisterre con un salto de línea
    }
    $AOC[$i] =~ s/\t|\n| //gsi; #Elimino tabulaciones, saltos de linea y espacios de la línea del primer txt
    $AOF[$i] =~ s/\t|\n| //gsi; #Elimino tabulaciones, saltos de linea y espacios de la línea del segundo txt
    print OUT $AOC[$i]." ".$AOF[$i].$/; #Imprimo en archivo de destino con un salto de línea al final
}
close AOC;
close AOF;
close OUT;
Coloreado en 0.002 segundos,  usando GeSHi 1.0.8.4

¡Saludos!

por **explorer** » 2013-05-06 20:18 @887

Recordar que esto también lo puede hacer el comando paste del sistema operativo, desde el shell.

Si suponemos que los archivos de texto tienen el mismo número de líneas, se puede hacer también de esta manera:

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use strict;
use warnings;
use diagnostics;
use autodie;
 
open my $AOC, '<', 'alturaolascanarias.txt';
open my $AOF, '<', 'alturaolasFinisterre.txt';
open my $OUT, '>', 'alturaolas.dat';
 
print $OUT join("\t", qw( Canarias Finisterre)), "\n";   # cabecera
 
while (my $col1 = <$AOC>) {
    chomp $col1;
    my $col2 = <$AOF>;                                   # no quitamos el "\n" de esta columna, por ser la última
 
    print $OUT join("\t", $col1, $col2);
}
 
close $AOC;
close $AOF;
close $OUT;
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Naturalmente, esto es para solo dos columnas. Si es para más, entonces hay que adoptar otra estrategia más general.

por **enric73** » 2013-05-07 10:47 @491

¡Muchas gracias a los dos!

He añadido una columna más, una tercera, adaptando vuestros códigos. Y me ha funcionado también. Mi pregunta es. Si en vez de tener 3 ficheros, tengo 10, ¿hay alguna manera de cogerlos todos a la vez, sabiendo que tienen el mismo número de filas? ¿con un glob()? Y también añadiendo a la primera fila, un nombre para cada columna, 10 nombres.

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
     
open(AOC, "<alturaolascanarias.txt");
open(AOF, "<alturaolasFinisterre.txt");
open(AOCAN, "<alturaolasCantabrico.txt");
open(OUT, ">alturaolas.dat");
     
@AOC = <AOC>; #Guardo archivos en Arrays
@AOF = <AOF>;
@AOCAN = <AOCAN>; 
    
for ($i=0;$i<scalar(@AOC);$i++){ #Hago un for desde 0 hasta el largo del primer archivo
if ($i==0){
print OUT "Canarias Finisterre Cantabrico\n"; #Si es la primera línea inserto Canarias Finisterre con un salto de línea
}
$AOC[$i] =~ s/\t|\n| //gsi; #Elimino tabulaciones, saltos de línea y espacios de la línea del primer txt
$AOF[$i] =~ s/\t|\n| //gsi; #Elimino tabulaciones, saltos de línea y espacios de la línea del segundo txt
$AOCAN[$i] =~ s/\t|\n| //gsi; #Elimino tabulaciones, saltos de línea y espacios de la línea del segundo txt
print OUT $AOC[$i]."     ".$AOF[$i]."     ".$AOCAN[$i].$/; #Imprimo en archivo de destino con un salto de línea al final
}
close AOC;
close AOF;
close AOCAN;
close OUT;
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use strict;
use warnings;
use diagnostics;
use autodie;
     
open my $AOC, '<', 'alturaolascanarias.txt';
open my $AOF, '<', 'alturaolasFinisterre.txt';
open my $AOCAN, '<', 'alturaolasCantabrico.txt';
open my $OUT, '>', 'alturaolas.dat';
     
print $OUT join("\t", qw( Canarias Finisterre Cantabrico)), "\n";   # cabecera
     
while (my $col1 = <$AOC>) {
chomp $col1;
my $col2 = <$AOF>;
chomp $col2; 
my $col3 = <$AOCAN>;                                  # no quitamos el "\n" de esta columna, por ser la última
     
print $OUT join("            ", $col1, $col2, $col3);
}
   
close $AOC;
close $AOF;
close $AOCAN;
close $OUT;
 
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Resultado:

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

Canarias     Finisterre     Cantabrico

87               0.57           0.70

87               0.70           0.67

85               0.90           0.66

80               1.15           0.70Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

Gracias a los dos

por **explorer** » 2013-05-07 11:08 @505

Se podrían indicar el nombre de los archivos a unir como argumentos al programa, que podríamos leer sus nombres a partir de la variable @ARGV.

Solo quedaría hacer los bucles correspondientes.

Pero antes hay que resolver de dónde sacamos los titulares de esos diez archivos. ¿De otro archivo?

por **enric73** » 2013-05-07 12:03 @544

Hola, explorer,

¿Se puede sacar el titular de los 14 archivos del propio nombre de cada archivo? He reducido el nombre de los archivos. Ahora, en vez de alturaolas, etc.,... directamente pongo Finisterre.txt, Cantabrico.txt, Canarias.txt, Azores.txt, SanVicente.txt, Cadiz.txt, Madeira.txt, GranSol.txt, Gibraltar.txt, Alboran.txt, Palos.txt, Baleares.txt, GolfoValencia.txt, Leon.txt.

Cada archivo tiene una columna de 4 números, todos son iguales en ese sentido.

¿O hacer un print más largo?

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

print $OUT join("\t", qw( Canarias Finisterre Cantabrico Azores SanVicente Cadiz Madeira  GranSol Gibraltar Alboran Palos Baleares GolfoValencia Leon)), "\n";   # cabecera
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Gracias.

por **explorer** » 2013-05-07 13:02 @585

Es fácil sacar los nombres de los archivos, usando una expresión regular, o función substr(), por ejemplo.

Sintáxis: [ Descargar ] [ Ocultar ]

Using perl Syntax Highlighting

#!/usr/bin/perl
use strict;
use warnings;
use diagnostics;
use feature 'say';
use autodie;
 
@ARGV or die "Uso: $0 <archivo.txt> [... <archivo.txt>]\n";
 
#my @cabeceras = map { m/^(.+?)[.]...$/ } @ARGV;    # le quitamos la extensión de tres letras
my @cabeceras = map { substr $_, 0, -4 } @ARGV;    # hace lo mismo: quita los últimos 4 caracteres
 
## Abrimos los archivos
my @fh;
for my $i (0 .. $#ARGV) {
    open $fh[$i], '<', $ARGV[$i];
}
 
## Abrimos archivo de salida
open my $OUT, '>', 'alturaolas.dat';
 
## Cabecera
say $OUT join "\t", @cabeceras;
 
## Bucle
while (not eof $fh[0]) {
    my @columnas = map { scalar <$_> } @fh;      # leemos una línea (scalar) por cada archivo en @fh
    chomp @columnas;
 
    say $OUT join "\t", @columnas;
}
 
## Cerramos
close $_ for @fh, $OUT;
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

Esto está probado, y funciona.

Ahora bien, ahora dices que los archivos tienen 4 columnas... Eso es nuevo. ¿Cómo son esas columnas? ¿Hay que separarlas igual que a las otras?

por **enric73** » 2013-05-07 14:14 @635

Gracias, explorer,

Tengo un pequeñito problema, no encuentra feature.pm. ¿Qué librería puedo instalarme con CPAN para que encuentre el feature.pm?
Os copio la salida en la consola, cuando he ejecutado el script perl...

Sintáxis: [ Descargar ] [ Ocultar ]

Using text Syntax Highlighting

bash-3.2$ ./onades3.pl
Can't locate feature.pm in @INC (@INC contains: /usr/lib64/perl5/site_perl/5.8.8/x86_64-linux-thread-multi /usr/lib/perl5/site_perl/5.8.8 /usr/lib/perl5/site_perl /usr/lib64/perl5/vendor_perl/5.8.8/x86_64-linux-thread-multi /usr/lib/perl5/vendor_perl/5.8.8 /usr/lib/perl5/vendor_perl /usr/lib64/perl5/5.8.8/x86_64-linux-thread-multi /usr/lib/perl5/5.8.8 .) at ./onades3.pl line 5.
BEGIN failed--compilation aborted at ./onades3.pl line 5 (#1)
    (F) You said to do (or require, or use) a file that couldn't be
    found. Perl looks for the file in all the locations mentioned in @INC,
    unless the file name included the full path to the file.  Perhaps you
    need to set the PERL5LIB or PERL5OPT environment variable to say where
    the extra library is, or maybe the script needs to add the library name
    to @INC.  Or maybe you just misspelled the name of the file.  See
    perlfunc/require and lib.
    
Uncaught exception from user code:
        Can't locate feature.pm in @INC (@INC contains: /usr/lib64/perl5/site_perl/5.8.8/x86_64-linux-thread-multi /usr/lib/perl5/site_perl/5.8.8 /usr/lib/perl5/site_perl /usr/lib64/perl5/vendor_perl/5.8.8/x86_64-linux-thread-multi /usr/lib/perl5/vendor_perl/5.8.8 /usr/lib/perl5/vendor_perl /usr/lib64/perl5/5.8.8/x86_64-linux-thread-multi /usr/lib/perl5/5.8.8 .) at ./onades3.pl line 5.
BEGIN failed--compilation aborted at ./onades3.pl line 5.
 at ./onades3.pl line 5.
Coloreado en 0.000 segundos,  usando GeSHi 1.0.8.4

por **enric73** » 2013-05-07 18:00 @791

Hola, explorer.

He instalado una versión más actualizada del Perl. La versión que tenía estaba un poco desfasada: perl v5.8, y por esta razón (supongo) no podía instalar feature.pm. Ahora, sí que carga feature "say". Me sale un error, al ejecutar el código que me has preparado anteriormente,

Sintáxis: [ Descargar ] [ Ocultar ]

Using bash Syntax Highlighting

[enric@localhost perl]$ ./onades3.pl
Use of uninitialized value $fh[0] in ref-to-glob cast at ./onades3.pl line 24 (#1)
    (W uninitialized) An undefined value was used as if it were already
    defined.  It was interpreted as a "" or a 0, but maybe it was a mistake.
    To suppress this warning assign a defined value to your variables.
   
    To help you figure out what was undefined, perl will try to tell you the
    name of the variable (if any) that was undefined. In some cases it cannot
    do this, so it also tells you what operation you used the undefined value
    in.  Note, however, that perl optimizes your program and the operation
    displayed in the warning may not necessarily appear literally in your
    program.  For example, "that $foo" is usually optimized into "that "
    . $foo, and the warning will refer to the concatenation (.) operator,
    even though there is no . in your program.
Coloreado en 0.003 segundos,  usando GeSHi 1.0.8.4

¿A que crees que es debido? ¿Dónde se selecciona los ficheros .txt?

Saludos
Gracias

por **explorer** » 2013-05-07 19:48 @867

Efectivamente, el error del 'feature' era por tener una versión de Perl muy antigua.

El error que sale luego es debido a que no has pasado ningún archivo como argumento al programa.

Debes ejecutar tu programa así:

Sintáxis: [ Descargar ] [ Ocultar ]

Using bash Syntax Highlighting

./onades3.pl Canarias.txt Finisterre.txt Cantabrico.txt Azores.txt SanVicente.txt Cadiz.txt Madeira.txt GranSol.txt Gibraltar.txt Alboran.txt Palos.txt Baleares.txt GolfoValencia.txt Leon.txt
Coloreado en 0.001 segundos,  usando GeSHi 1.0.8.4

He reeditado el programa para añadirle la línea 8, con lo que sale un mensaje indicando la forma de usar el programa, en caso de que se vuelva a llamar sin argumentos.

Foro - Perl en Español

Manipulación ficheros planos

Manipulación ficheros planos

Publicidad

Re: manipulacion ficheros planos

Re: Manipulación ficheros planos

Re: Manipulación ficheros planos

Re: Manipulación ficheros planos

Re: Manipulación ficheros planos

Re: Manipulación ficheros planos

Re: Manipulación ficheros planos

Re: Manipulación ficheros planos

Re: Manipulación ficheros planos

¿Quién está conectado?